[文本处理] 【挑战】将文本中指定位置的tab替换为普通字符

batman

本人原意是想用批处理将a.txt中各列的数值进行累加计算（计算本身是很容易
的），但问题是a.txt中各列中有的不是数值而是空（实际上是tab），必须要先将这些指
定位置的tab替换为0字符，才能正确计算出结果。如果是在excel表中操作这会是很容易
的，但就是想用批来完成，想破了头终于还是有了些头绪。同时，本人觉得这个问题还
是有拿出来讨论的价值，所以就发了出来，也请大家各显神通，来完成这个批处理对文
本的特殊替换吧。（因论坛无法处理tab，所以上传附件a.txt如下）


[ 本帖最后由 batman 于 2009-6-23 17:24 编辑 ]

batman

提示下：a.txt中各列间也是以tab来分隔的。

随风

确定每行最多的是4例吗？连姓名一起是5例。

batman

总列数可以从第一行中提取，如只想就原文本来解答，那就定为5列吧。

随风

就原文本来解答

@echo off&setlocal enabledelayedexpansion
set "tab=#"&rem 把左边的#号替换为 tab 键
for /f "delims=" %%a in (ss.txt) do (
   set "str=%%a"
   set "str=!str:%tab%%tab%%tab%%tab%=%tab%0%tab%0%tab%0%tab%!"
   set "str=!str:%tab%%tab%%tab%=%tab%0%tab%0%tab%!"
   set "str=!str:%tab%%tab%=%tab%0%tab%!"
   if "!str:~-1!"=="%tab%" set "str=!str:~0,-1!%tab%0"
   echo !str!
)
pause
复制代码

从第一行中提取总列数

@echo off&setlocal enabledelayedexpansion
set "tab= #"&rem 把左边的#号替换为 tab 键
set /p var=<ss.txt
for %%a in (!var!) do (
   set /a n+=1
   for /l %%i in (1 1 !N!) do set t=!t!%tab%&set tt=!tt!%tab%0
   set t!n!=!t!&set t!n!!n!=!tt:~0,-1!
   set t=&set "tt="
)
set /a n-=1
for /f "delims=" %%a in (ss.txt) do (
   set "str=%%a"
   for /l %%i in (!n! -1 2) do (
      for /f "tokens=1,2 delims=/" %%j in ("!t%%i!/!t%%i%%i!") do (
         set "str=!str:%%j=%%k!"
    ))
   if "!str:~-1!"=="%tab%" set "str=!str:~0,-1!%tab%0"
   echo !str!
)
pause
复制代码

netbenton

我也来试试

@echo off&setlocal enabledelayedexpansion
set Tab=        &rem 这个空白换为Tab键
for /f "delims=" %%a in (a.txt) do (
        set var=%%a
        set str=
        for %%b in ("!var:%Tab%=" "!") do (
                set #%%~b=%%~b
                set #=0
                set str=!str!%Tab%!#%%~b!
        )
        echo !str:~1!

)
pause
复制代码

[ 本帖最后由 netbenton 于 2009-6-23 19:24 编辑 ]

pusofalse

@echo off & SetLocal enabledelayedexpansion
:: tab 键
set "tab=	"
For /f "skip=1 delims=" %%a in (a.txt) do (
	set "sString=%%a" & set "sVar="
	set "sString=!sString:%tab%=%tab%#!"
	set /a n = 0 & call :recur !sString:~1!
)
set _ & Pause & exit /b

:recur
set /a n += 1
For /f "tokens=1* delims=%tab%" %%a in ("%*") do (
	set "sVar=%%a" & set "sVar=!sVar:#=!"
	If "!sVar!" equ "" ( set "sVar=0" )
	set /a _!n! += sVar
	If "%%b" neq "" ( call :recur %%b )
)
复制代码

netbenton

再来个更简单的。

 
@echo off&setlocal enabledelayedexpansion
set Tab= &rem 这个空白换为Tab键
for /f "delims=" %%a in (a.txt) do (
set var=%%a
set var=!var:%Tab%=%Tab%#!%Tab%
set var=!var:#%Tab%=0%Tab%!
set var=!var:#=!
echo !var:~,-1!
)
pause
复制代码

改成这样就不畏惧任何字符了：

@echo off
set Tab= &rem 这个空白换为Tab键
for /f "delims=" %%a in (a.txt) do (
set var=%%a
setlocal enabledelayedexpansion
set var=!var:%Tab%=%Tab%#!%Tab%
set var=!var:#%Tab%=0%Tab%!
set var=!var:%Tab%#=%Tab%!
echo !var:~,-1!
endlocal
)
pause
复制代码

[ 本帖最后由 netbenton 于 2009-6-24 07:48 编辑 ]

zqz0012005

也是一个比较经典的问题。

for /f 中两个分隔符之间的空值如何表示？
http://bbs.verybat.org/viewthrea ... romuid=37#pid166173

jackerloo2009

哎！man在群里让我做一下，呵呵，寻思半天还是来看答案了

喜欢8楼的思路

又掌握了一种思路技巧

tireless

@echo off&setlocal enabledelayedexpansion
set "tab=        " 引号里的空格换成 Tab
for /f "delims=" %%a in (a.txt) do (
  set var=%%a
  set var="!var:%tab%="%tab%"!"
  set var=!var:""=0!
  echo !var:"=!
)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
  set var=%%a
  set n=0
  for %%a in ("!var:【Tab】=" "!") do set /a n+=1 , _!n!+=%%~a 2>nul
)
set _
pause
复制代码

[ 本帖最后由 tireless 于 2009-6-24 09:12 编辑 ]

netbenton

楼上第一个代码可以减少一行，"号用得错实妙

第二个代码似乎结果不正确吧？
是不是想做成6楼的样子呢？


再来一个：

 
@echo off
set Tab= &rem 这个空白换为Tab键
for /f "delims=" %%a in (a.txt) do (
set var=%%a%Tab%
setlocal enabledelayedexpansion
set var=!var:%Tab%%tab%=%Tab%0%Tab%!
set var=!var:%Tab%%tab%=%Tab%0%Tab%!
echo !var:~,-1!
endlocal
)
pause
复制代码

[ 本帖最后由 netbenton 于 2009-6-24 07:50 编辑 ]

tireless

正确吧？跟 7楼 的结果一样。

[ 本帖最后由 tireless 于 2009-6-24 09:13 编辑 ]

batman

呵呵，各位都给出了精彩的解答，可能本人在楼顶没有描述清楚，其实最后应该是
要计算出各列的和的，本人代码如下：

@echo off&setlocal enabledelayedexpansion
set "tab=#" rem请将#替换为tab键
for /f "delims=" %%a in (a.txt) do (
     echo %%a&set /a m=0
     set "str=%%a"&set "str=!str:%tab%=%tab%0!"
     for %%b in (!str!) do (
          set /a m+=1
          set "var=%%b"&set "var=!var:~1!"
          if not defined var set /a var=0
          set /a _!m!+=!var!
     )
     
)
set "_1=合计"
for /l %%a in (1,1,%m%) do (
     set /p=!_%%a!<nul
     if %%a neq %m% set /p=%tab%<nul
)
pause>nul
复制代码

[ 本帖最后由 batman 于 2009-6-24 11:44 编辑 ]

tireless

@echo off&setlocal enabledelayedexpansion
set "Tab=#"   把 # 换成 Tab 键
for /f "skip=1 delims=" %%a in (a.txt) do (
  set var=%%a
  set n=0
  for %%a in ("!var:%tab%=" "!") do set /a n+=1 , _!n!+=%%~a 2>nul
)

more a.txt
for /l %%a in (1 1 %n%) do set end=!end!%tab%!_%%a!
echo 合计%end%
pause>nul
复制代码