[文件操作] 批处理文件删除操作 递归判断怎么搞？

swanseabrian

、

如图所示，
文件夹嵌套，
现在需要把包含
未命名的文件夹里的
文件删除，然后把未命名的文件夹里的内容复制到上层文件夹里
同样，别的文本夹里也有未命名文件夹，如果 有就做同样的操作，如果没有就不操作，这个好弄吗

Fit

@echo off
set ccd=%cd%
for /r /d %%i in (未命名) do (
  if exist %%i (
  for %%j in (%%i\*.*) do move "%%j" "%ccd%\">nul)
)

pause

Fit

bat放在根目录

swanseabrian

回复 3# Fit


    还要删除包含未命名文件夹

的文件夹
里的东西的

移动完了，再把未命名文件夹删除，
谢谢

Fit

@echo off
set ccd=%cd%
for /r /d %%i in (未命名) do (
  if exist %%i (
  for %%j in (%%i\*.*) do move "%%j" "%ccd%\">nul
  rd /q %%i)
)

pause

qixiaobin0715

回复 1# swanseabrian
你的需求是：
删除文件夹“一寸”中的6个jpg文件；
把文件夹“未命名”中的文件移动到文件夹“一寸”中；
最后删除文件夹“未命名”。
对吧？

qixiaobin0715

如果是以上需求的话：

@echo off
for /r /d %%a in (未命名) do (
    del "%%~dpa*.jpg"
    move "%%a\*.*" "%%~dpa"
    rd /a /f "%%a"
)
pause
复制代码

swanseabrian

回复 7# qixiaobin0715


    对

swanseabrian

回复 7# qixiaobin0715


     rd /a /f
这开关你是不是记错了
a,f 都无效
应该是 /s /q吧

swanseabrian

回复 9# swanseabrian

for /r /d %%a in (未命名)
用上面 这个命令，为啥，不带未命名的出来了，我说怎么总出错，这是啥情况

    C:\Users\Administrator\Desktop\bat\7\A\
C:\Users\Administrator\Desktop\bat\7\A\1\
C:\Users\Administrator\Desktop\bat\7\A\1\5寸\
C:\Users\Administrator\Desktop\bat\7\A\1\6寸\
C:\Users\Administrator\Desktop\bat\7\A\1\7寸\
C:\Users\Administrator\Desktop\bat\7\A\A\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\未命名\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\未命名\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\未命名\未命名\未命名\

Batcher

回复 1# swanseabrian

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /s /ad 未命名') do (
    del /f /q "%%i\..\*.*"
    move "%%i\*.*" "%%i\.."
    rd "%%i"
)
复制代码

Batcher

回复 5# Fit


1、路径加上双引号，避免空格或其它特殊字符导致代码出错或误删文件
2、move支持通配符，不需要第二层for循环逐个处理

@echo off
cd /d "%~dp0"
for /r /d %%i in (未命名) do (
    if exist "%%i" (
        del /f /q "%%i\..\*.*"
        move "%%i\*.*" "%%i\.."
        rd /q "%%i"
    )
)
复制代码

Fit

回复 12# Batcher


   谢谢， 明白了
但是del 哪里没看懂 ..是啥

swanseabrian

回复 11# Batcher


    @echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /s /ad 未命名') do (
    del /f /q "%%i\..\*.*"
    move "%%i\*.*" "%%i\.."
    del /f /q "%%i\*.*"
    rd "%%i"
)
这样，要不然rd会提示目录不是空的，for /r /d 这个命令看来不能用啊，太不好用了

swanseabrian

回复 13# Fit


    那是上级目录  /r /d还是不要用了，总出错，还是/f好用