[文件操作] [已解决]批处理文件复制操作--谢谢朋友们无私帮助！

3Q3Q

用COPY 命令从X1文件夹每隔一分钟向X2文件夹复制文件，X1文件夹不停的有新文件传入，请问怎么才可以防止X1已经复制到X2的文件再次被执行复制操作？只写出判断部分就好。3Q3Q

[ 本帖最后由 3Q3Q 于 2009-12-9 16:38 编辑 ]

pumahxh

光写判断部分恐怕不一定行，我用这个方法，经测试合格，如果文件名含空格，则必须将代码再处理下，我想你自己应该会吧。假设两个文件夹都在C:\下。

@echo off
cd/d c:\X2
:loop
for /r c:\X2 %%i in (*.*) do  if not exist c:\X1\%%~nxi copy %%~nxi c:\X1
ping -n 61 127.1>nul
goto loop
复制代码

Batcher

给路径加上双引号不就可以兼容空格了？

pumahxh

开始也是这么想的，还有一种方法
如果将copy %%~nxi c:\X1中改成copy %%~si c:\X1好像也不错，而且还可以删去cd/d c:\X2，简化了些代码

@echo off
:loop
for /r c:\X2 %%i in (*.*) do  if not exist c:\X1\%%~nxi copy %%~si c:\X1
ping -n 61 127.1>nul
goto loop
复制代码

[ 本帖最后由 pumahxh 于 2009-12-7 23:56 编辑 ]

netbenton

xcopy 有自动文件更新复制功能，

@echo off
set n=3
set /p n=输入几秒检测一次：
set /a n=n+1
if %n% leq 1 goto :eof
:loop
xcopy x1\*.* x2\ /d
ping -n %n% 127.1 >nul
goto :loop
复制代码

3Q3Q

谢谢楼上各位朋友的回答，十分感激！这里有个问题还要麻烦大家（怪我没说清楚，不好意思呵呵）：
1.X2文件夹将被定时执行操作，操作结束后将被清空，这样就无法对比出哪些文件已经被复制过。是否有其他的方法可以进行判断文件是否已被复制？
2.用文件的创建时间进行判断是否可行（精确到秒）？比如用一个变量记录下每次复制的一批文件中时间最新的一个，当下次执行复制操作时就可以以此时间变量为基准，只复制比这个时间更新的然后再次记录文件创建时间，这样循环下去...
希望您能给出代码，期待您的回复...
谢谢！！！

bluewing009

将已经复制的文件名导出为txt（或ini或者其他）即可，  复制时，用for 读取已复制文件名列表，if判断 copy 即可。

neorobin

干脆用 VBS 来做吧, 由于是无限循环, 要终止运行就 结束 WScript.exe 进程.
假设你的两个文件夹分别是 D:\x1  和 D:\x2   不是这样的话,对代码中相应改动就行了, 不然找不到目录会报错
无论用批还是用 vbs, 要适用于定时清空 x2 文件夹, 都需要一个文件列表记录文件(不能用变量, 文件太多会溢出内存)
适用于定时清空 x2 文件夹的
用创建日期和修改日期综合判断的(时间精确到秒), 这样代码还简单多了
PS: 我自己的机器上出现了不能覆盖文件的权限问题, 如果你也同样遇到, 请试试将本楼附件中的权限注册表文件导入

SrcFolder = "D:\x1"
DstFolder = "D:\x2"
DateCOMLast = "0-1-1 00:00:00"
DateCOMMax = DateCOMLast
Do 
  CopyFiles SrcFolder, DstFolder, True, DateCOMLast
  WScript.Sleep 60000 ' 等待时间 单位:ms 60000=1 分钟
Loop Until false

Function CopyFiles(Src, Dst, overwrite, ByRef DateCOMLast)
   Dim fso, f, f1, fc
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set f = fso.GetFolder(Src)
   Set fc = f.Files
   DateCOMMax = DateCOMLast

   For Each f1 in fc ' 对源目录中的每一个文件进行 创建或修改 双重日期检测, 并确定是否复制
     If DateDiff("s", DateCOMLast, f1.DateCreated) > 0 Or DateDiff("s", DateCOMLast, f1.DateLastModified) > 0 Then
       f1.Copy Dst & "\" & f1.Name, overwrite
       If  DateDiff("s", DateCOMMax, f1.DateCreated) > 0 Then DateCOMMax = f1.DateCreated            ' 计算一批文件中最新的创建日期
       If  DateDiff("s", DateCOMMax, f1.DateLastModified) > 0 Then DateCOMMax = f1.DateLastModified  ' 或最新的修改日期
     End If
   Next
   DateCOMLast = DateCOMMax ' WScript.Echo "DateCOMLast:" & DateCOMLast  完成一批新文件的复制后, 设置最新的创建或修改日期
End Function
复制代码

用复制历史列表和存在性来决定的

SrcFolder = "D:\x1"
DstFolder = "D:\x2"
FnList = "c:\FileList.txt"

Const ForReading = 1, ForWriting = 2, ForAppending = 8
Set fso = CreateObject("Scripting.FileSystemObject")
If Not (fso.FileExists(FnList)) Then
  Set FileList = fso.CreateTextFile(FnList, True)
  FileList.Close
End If

Do 
  CopyFiles SrcFolder, DstFolder, True, FnList
  WScript.Sleep 60000 ' 等待时间 单位:ms 60000=1 分钟
Loop Until false

Function CopyFiles(Src, Dst, overwrite, FList)
   Dim fso, f, f1, fc
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set f = fso.GetFolder(Src)
   Set fc = f.Files

   For Each f1 in fc ' 对源目录中的每一个文件进行 列表记录 和 实际文件 双重存在检测, 并确定是否复制
     If Not FoundFileInList(FList, f1.Name) And Not (fso.FileExists(Dst & "\" & f1.Name)) Then
       f1.Copy Dst & "\" & f1.Name, overwrite
       Set fo = fso.OpenTextFile(FList, ForAppending, False)
       fo.WriteLine f1.Name
       fo.Close
     End If
   Next
End Function

Function FoundFileInList(listspec, filespec)
   Const ForReading = 1
   Dim fso, theFile, retstring
   FoundFileInList = False
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set theFile = fso.OpenTextFile(listspec, ForReading, False)
   Do While theFile.AtEndOfStream <> True
      if theFile.ReadLine = filespec then
        FoundFileInList = True
        theFile.Close
        Exit Function
      End If
   Loop
   theFile.Close
End Function
复制代码

不适用于定时清空 x2 文件夹的

SrcFolder = "D:\x1"
DstFolder = "D:\x2"
Do 
  CopyFiles SrcFolder, DstFolder, false
  WScript.Sleep 60000 ' 等待 1 分钟
Loop Until false

Function CopyFiles(Src, Dst, overwrite)
   Dim fso, f, f1, fc
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set f = fso.GetFolder(Src)
   Set fc = f.Files
   For Each f1 in fc  
      If Not (fso.FileExists(Dst & "\" & f1.Name)) Then
        f1.Copy Dst & "\" & f1.Name, overwrite
      End If   
   Next
End Function
复制代码

[ 本帖最后由 neorobin 于 2009-12-9 14:53 编辑 ]

3Q3Q

If Not FoundFileInList(FList, f1.Name) And Not (fso.FileExists(Dst & "\" & f1.Name)) Then
这一句判断可否改成对文件创建时间的判断？（创建时间最好精确到分钟）  也就是说把每次复制的一批文件的创建时间进行对比，把时间最新的那个记录下来，下次复制操作时，以那个最新时间为标准只复制该时间后的文件，依次循环。。。。
因为源文件夹可能会在不同时间段接收的文件同名但不相同内容，用文件名列表做判断的话，不会对这些文件进行复制。。。
谢谢您了！！万分感激！

[ 本帖最后由 3Q3Q 于 2009-12-9 10:45 编辑 ]

neorobin

事实上, 不管 BAT 还是 VBS 我都是肤浅得很啦, 楼主这样谢我, 我真不好意思. 嗯,我再考虑研究一下, 尽力向楼主所要求的方向改进了.

netbenton

建议楼主好研究下xcopy.exe ，或许它可以简单并高效的完成你的问题。。。

caruko

是哦..
你可以在新添加的文件上设置 存档属性,
然后 xcopy /m 就能判断有没有被复制..
或者 xcopy /d 来让命令自动判断目标文件夹是不是比 x1 里的旧

caruko

其实，还有一个很好用的工具..“公文包”
将X1文件夹拉到公文包里，X1文件夹下的任何改动，按一下更新就可以了
同样，公文包里的改动，也可以更新到X1文件夹下

neorobin

贴在 8 楼的最上面更新了

用创建日期和修改日期综合判断来确定是否复制源目录的每一个文件

不想再更复杂了, 所以有 2 个大的 不足:
1. 源目录中的子目录和子目录中的文件不能被复制;
2. 如果覆盖更新和目标目录中的文件访问(读,写,删除)同时发生, 可能会出错退出脚本

[ 本帖最后由 neorobin 于 2009-12-9 15:13 编辑 ]

3Q3Q

啥也不说，先谢谢您！多谢您的帮助。我去试试。。。