zhouyongjun

支持每行字符数不同

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (set/a n+=1&set "_!n!=%%a")
:loop
for /l %%i in (1,1,%n%) do (
    if defined _%%i (<nul set/p=!_%%i:~,1!&set _%%i=!_%%i:~1!) else (set/p= <nul)
)
echo/&for /l %%i in (1,1,%n%) do if defined _%%i goto loop
pause
复制代码

CrLf

看错题意，算了...

[ 本帖最后由 zm900612 于 2011-3-12 13:01 编辑 ]

CrLf

哈哈，这题么，全是单字节字符，正好用上cmd /u

@echo off&setlocal enabledelayedexpansion
find /v "" a.txt
echo 以下为纵横转换结果：
for /f "skip=1 delims=:" %%a in ('(type a.txt^&echo;^)^|findstr /o .*') do (
        set /a ho=%%a-2,l=ho-last-2,last=ho,"max+=(max-l)*((max-l)>>31)"
        set o=!o!!ho! 
)
set n=1
for /f "delims=" %%a in ('cmd /u /c type a.txt^|more') do (
        for /f "tokens=1,2" %%x in ("!n! !o!") do (
                set .!n!=!.%%x!%%a
                set /a n+=1,m+=1
                if !m!==%%y (
                        for /l %%z in (!n! 1 %max%) do set ".%%z=!.%%z! "
                        set o=!o:* =!&set /a n=1,m+=2
                )
        )
)
for /l %%a in (1 1 %max%) do echo [!.%%a!]
pause
复制代码

[ 本帖最后由 zm900612 于 2011-3-13 12:31 编辑 ]

qzwqzw

贴一个正统的解法
用到了临时文件
得亏事先造好了声势
可以不用偷偷摸摸了

楼主号称5句代码能够解题
等待瞻仰中……

@echo off & setlocal EnableDelayedExpansion
rem 重置可能影响程序的环境变量为空
for %%e in (lines context sizes cols) do set %%e=

rem 将所有文本行拼成一行，并统计行数
for /f "delims=" %%l in (a.txt) do set /a lines+=1&set "context=!context!%%l"

rem 获取文本总字节数，并依此计算列数和列边界
(echo %context%)>b.txt
for %%f in (b.txt) do set /a sizes=%%~zf-2,cols=sizes/lines,collimit=cols-1

rem 依照字符坐标转换，依次输出各列字符
for /l %%i in (0,1,%collimit%) do (
	for /l %%j in (%%i,%cols%,%sizes%) do set/p=!context:~%%j,1!<nul
	echo.
)
pause
复制代码

qixiaobin0715

@echo off
set /p char=<a.txt
set n=0
:o
if not "%char%"=="" (
    set /a n+=1
    set char=%char:~1%
    goto :o
)
set /a n-=1
setlocal enabledelayedexpansion
for /l %%b in (0,1,%n%) do (
    for /f "delims=" %%a in (a.txt) do (
        set "str=%%a"
        set str%%b=!str%%b!!str:~%%b,1!
    )
    echo !str%%b!
)
pause
复制代码

lengmoke

@echo off
Setlocal EnableDelayedExpansion
set maxlength=0
for /f "delims=" %%i in (a.txt) do ( 
    call :len "%%i" length
    set "number=!number! !length!" 
    set "list=!list!%%i"
)
for /l %%i in (1,1,%maxlength%) do (
    set /a x=0
    set "temp="
    for %%j in (%number%) do (
        set /a m=!x!+%%i-1
        call set temp=!temp!%%list:~!m!,1%%
        set /a x+=%%j
    )
    echo !temp!
)
exit
:len
set "strs=%~1" & set /a n=0
:loop
if defined strs (
    set strs=%strs:~1%
    set /a n+=1 
    goto:loop
)
if %maxlength% lss %n% (
    set maxlength=%n% 
)
set %2=%n%
复制代码