defanive

利用位运算是否可以简化一下呢？

或者生成VBS。。。

rat

@set/ps=Plz input:&for /f "tokens=2" %%a in ('^(call echo e114 '%%s%%',0^&more /e +1 "%~f0"^)^|debug^|find "AX "') do @set/an=0x%%a&call echo %%n%%&pause>nul&exit/b
a100
MOV     BX,0114
CMP     BYTE PTR [BX],00
JZ      0112
MOV     CL,[BX]
ADD     AX,CX
SUB     AX,0060
INC     BX
JMP     0103
INT     20
 
g=100 112
rax
 
qCOPY

sjzong

只要在if语句加上/i，就可以忽略大小写了！本代码大小写字母值相等的！

@echo off
setlocal enabledelayedexpansion
set "zmb= abcdefghijklmnopqrstuvwxyz"
:main
cls
set/p var=请输入字符串：
echo %var%|findstr "^[a-zA-Z]*$">nul||goto main
set/p=字符串之和为：<NUL
:a
if not "!var:~%n%,1!"=="" (
for /l %%a in (1 1 26) do (
if /i "!var:~%n%,1!"=="!zmb:~%%a,1!" (
set/a sum+=%%a 
set/p=!var:~%n%,1!+<NUL
goto :b))
:b
set/a n+=1
goto :a
) else (set/p==!sum!<NUL&echo.)
pause>nulCOPY

[ 本帖最后由 sjzong 于 2009-4-22 01:24 编辑 ]

sjzong

@echo off&setlocal enabledelayedexpansion
set "zmb= abcdefghijklmnopqrstuvwxyz"
for /l %%a in (1 1 26) do (set/a !!zmb:~%%a,1!!=%%a)
set/p var=请输入字符串:
set/a n=0,sum=0
set str=
:a 
if not "!var:~%n%,1!"=="" (
set str=!str!+!var:~%n%,1!
set/a sum=!sum!+!!var:~%n%,1!!
set/a n+=1
goto :a
) else (echo !str:~1!=!sum!)
pauseCOPY

aiguozhe

还不会，还得继续努力啊，刚才看了2个题目都没看懂，得加劲了

Seter

果然...我就知道有狂人要用ASM...

zdsg2001

@echo off
setlocal ENABLEDELAYEDEXPANSION
set n=0
for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
                                                                   set/a n+=1
                                                                   set %%i=!n!
)
:sr
cls
echo 请输入你要输入的字母:
set/p xs=
echo !xs!|findstr /i [a-z]||echo 请确认你输入的字母是否正确&&pause>nul&&goto sr
set num=0
:jy
set xsh=!xs:~%num%,1!
if "!xsh!"=="" goto jg
set /a num+=1
echo.&echo !xsh!=!%xsh%!
set /a str=!str!+!%xsh%!
goto jy

:jg
if "!str!"=="" set str=0
echo 你输入的字母计算结果为 !str!
pause>nul
exit

pumahxh

@echo off&setlocal enabledelayedexpansion
rem 以下代码给字母赋值
set "str=a b c d e f g h i j k l m n o p q r s t u v w x y z" 
set "num=0"
for %%i in (%str%) do (
    set/a n+=1
    set %%i=!n!)
rem 查找输入的字母并将其对应数字相加
set/p string=请输入字母：
:loop
call,set s=%%string:~!num!,1%%
set/a num+=1
set/a sum=!sum!+!!s!! 2>nul
if not "!s!"=="" goto loop
echo %sum%
pauseCOPY

honeybat

@echo off
setlocal enabledelayedexpansion
for %%i in (a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z) do (set /a var+=1) &(set %%i=!var!)
set /p inputstr=inputword:
:count
if /i "!inputstr:~%jishu%,1!" neq "" (set /a count+=!inputstr:~%jishu%,1!)&(set /a jishu+=1) else (goto end)
goto count
:end
echo !count!
pause>nulCOPY

634175535

实在是有点难度哦，因为我是新手嘛，哈·····

qq105699129

请问为什么set str=#abcdefghijklmnopqrstuvwxyz这句要加个#，还要那个set zifu=%zifu:~1%
又是什么意思？

defanive

@echo off
for %%a in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do set /a n+=1,%%a=n
set /p input=输入算式：
set /a ans=%input%
echo 结果是：%ans%
pauseCOPY

我也试试吧，看起来不怎么样

poxi

（偶还是新手，一下子给偶这么难的题目，，受不鸟....花了哦1+小时才弄出来...想了老半天，头都快抓破了没在可读性上下功夫....看得我头昏眼花的）

答：

@echo off
setlocal EnableDelayedExpansion
set str=abcdefghijklmnopqrstuvwxyz
set /p word=请输入几个小写字母...
set a=0
:xx
call set word1=%%word:~%a%,1%%
set end=%end%%word1%+
if "%word1%"=="" (goto end)
for /l %%i in (0,1,25) do (
set var=%%i
call set str1=%%str:~!var!,1%%
if !str1!==%word1% (call set /a endword=%endword%+!var!+1))
set /a a+=1
goto xx
:end
echo %end:~0,-2%=%endword%
pauseCOPY

效果：

===================
end;(最后抱怨下楼主...so difficult)

taofan712

回复 6# 随风
随风六楼 call set input=%%input:%%b=+%%b%% oh my god，神之替换！！
为了做这个题，我已经想了1个小时，写了20行。看了前辈的答案，决定重新思考，想好了再来写。

懒虫阿布

@echo off
setlocal enabledelayedexpansion
REM a=1,b=2,c=3 . . . z=26,要计算的任意字母由用户输入,计算它们的总和
REM   如用户输入abcd             那么a+b+c+d=10
 
set /p inputstr=请输入字符串:
set tempstr=!inputstr!
 
set letterall=a b c d e f g h i j k l m n o p q r s t u v w x y z
set letterval=1
for %%i in (%letterall%) do (
	call set tempstr=%%tempstr:%%i= !letterval!%%
	set /a letterval+=1
)
 
set sumval=0
for %%i in (!tempstr!) do (
	set /a sumval+=%%i
)
 
echo !inputstr!=!sumval!COPY