curious

set ram=%random%%random%%random%&set "str="
此ram难道一定就超过11位？

inittab

谢谢楼上指出.这是以前写的.我也是新手有考虑不周之处. 其实这句也是多余的.
修正如下

@echo off&setlocal enabledelayedexpansion

set "var=abdefg ABDEFG kmli KMLI socsd SOCSD pdxy PDXY nq NQ"
set n=0
for %%i in (%var%) do (set !n!=%%i&set/a n+=1)

:begin
set "str="
for /l %%a in (1,1,10) do set/a ran=!random!%%10&set "str=!str! !ran! "
set out=%str: =!!%
echo !out!>>b.txt
set/a n-=1&if !n! gtr 0 (goto :begin)
start b.txt
复制代码

keen

第一题：

@echo off&setlocal enabledelayedexpansion
for %%a in (abdefg kmli socsd pdxy nq ABDEFG KMLI SOCSD PDXY NQ) do set /a n+=1&set !n!=%%a
for /l %%b in (1 1 10) do (
    for /l %%i in (1 1 10) do (
        set /a num=!random!%%10+1
            for %%j in (!num!) do set /p=!%%j!<nul
)
echo\
)
pause>nul
复制代码

jackerloo2009

echo off
:cc
set ee=
setlocal enabledelayedexpansion
set "var=abdefg ABDEFG kmli KMLI socsd SOCSD pdxy PDXY nq NQ"
set num=0
:aa
set /a num+=1
set /a c=%random%%%10+0 
for /f "tokens=1-10 delims= " %%0 in ("%var%") do set "ff=%%%c%"
if !num!==11 goto dd
set "ee=!ee!!ff!"
goto aa
:dd
set /a nm+=1
echo !ee!>>a.txt
if !nm!==10 goto mm
goto cc
:mm
pause
复制代码

keen

楼上是否对自己的代码测试过？

jackerloo2009

我新手，写代码难免有问题的，你是感觉我哪些地方用的不对吗？

jackerloo2009

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in (b.txt) do set "d=%%i" & call :treat
pause>nul
:treat
set m=0
set "y="
:cc
set "e=!d:~%m%,6!"
set "x=!d:~%m%,1!"
set /a m+=1
if "!e!"=="ABDEFG" set /a m-=1 & call set "y=%%d:!d:~%m%,6!=bathome%%" & set /a m+=1
if "!x!"=="" goto dd
goto cc
:dd
if "!y!"=="" (echo !d!>>bb.txt) else echo !y!>>bb.txt
goto :eof
复制代码

jackerloo2009

http://bbs.bathome.net/viewthrea ... amp;page=1#pid29527
当我还是个新手的时候就测试过这个问题了，尽管现在我还是新手，可惜当时就一个人指点明白了我当时的疑惑

作为直接取值如echo %%1 %%2 %%3必须是双%

但是作为变量赋值后的调用，赋值必须是单%

还有一个问题是echo %com% 的双%，尽管开启了变量延迟setlocal enabledelayedexpansion，但是我测试发现echo !com!这样的方式是错误的，只能echo %com%，至于为什么还有待高手指点

zhouyongjun

@echo off&setlocal enabledelayedexpansion
for %%i in (abdefg kmli socsd pdxy nq ABDEFG KMLI SOCSD PDXY NQ) do (
    set/a n+=1&set _!n!=%%i
)
(for /l %%a in (1,1,10) do (
    for /l %%b in (1,1,10) do (
        set/a num=!random!%%10+1
        for %%c in (_!num!) do set/p=!%%c!<nul
    )
    echo/
))>a.txt
(for /f "delims=" %%a in (a.txt) do (
    set str=%%a&set var=!str:abdefg= abdefg !&set "cut="
    for %%b in (!var!) do (
        if /i "%%b" neq "abdefg" (
            set/p=%%b<nul
        ) else (
            if defined cut call,set str=%%str:*!cut!=%%
            if "!str:~,6!" equ "ABDEFG" (set/p=bathome<nul) else (set/p=%%b<nul)
        )
        set cut=%%b
    )
    echo/
))>b.txt
复制代码

keen

显示结果正确，代码中有些细节须注意，我给你的代码稍作改动，你可以跟你的52楼代码做一比较：

@echo off&setlocal enabledelayedexpansion
:cc
set ee=
set "var=abdefg ABDEFG kmli KMLI socsd SOCSD pdxy PDXY nq NQ"
set num=0
:aa
set /a num+=1
set /a c=%random%%%10
for /f "tokens=1-10" %%0 in ("%var%") do set "ff=%%%c%"
if %num%==11 goto dd
set "ee=!ee!!ff!"
goto aa
:dd
set /a nm+=1
echo %ee%>>a.txt
if %nm%==10 goto mm
goto cc
:mm
start a.txt
pause
复制代码

你55楼的代码结果不对吧

[ 本帖最后由 keen 于 2009-6-15 12:46 编辑 ]

jackerloo2009

感谢指正！为什么要省去"delims= "这个呢？恩，还有个概念我有些模糊，就是开启延迟的时候，如何区分用！！还是%%

55楼的我测试的时候，是指定的b.txt    最后生成的是bb.txt    ，应该改成a.txt  生成 b.txt就对了

我是新手还望能多多指点

keen

省去"delims= "是因为默认就是以空格为分割符，所以为了缩小代码量，在单独以空格为分隔符可以省略！

开启延迟的时候，到底改用!!还是%%,请参看http://www.bathome.net/viewthrea ... 4%C1%BF%D1%D3%B3%D9

55楼的代码结果，你应该再仔细对照查看替换前和替换后的文本内容，是否只是替换了ABDEFG。

jackerloo2009

当时测试是没问题的，今天才发现最后重复了最后一行，现在想了半天了，也没想明白原因，我再想想

jackerloo2009

给我的感觉好像for在处理文本的时候总是预读一行，到最后一行它仍然预读下一行，结果下一行是空的，它就终止，可是我这个代码到最后那个if仍然满足条件结果就又重新指定了一遍了，是不是这个原因？

jackerloo2009

请大家给看看，指点一下

@echo off
del b.txt
setlocal enabledelayedexpansion
set var=bathome
for /f "delims=" %%i in (a.txt) do set "d=%%i" & call :treat
pause>nul & goto :eof
:treat
set m=0
:cc
set "f=!d:~%m%,1!"
set "e=!d:~%m%,6!"
if "%f%"=="" echo.>>b.txt & goto :eof
if "%e%"=="ABDEFG" (set/p=%var%<nul>>b.txt & set /a m+=5) else (set/p=%f%<nul>>b.txt)
set /a m+=1
goto cc
复制代码

已经找到原因了，这样就好了 set/p=%var%<nul>>b.txt& set  /a m+=5
但是不明白为什么要把set/p=%var%<nul>>b.txt&这个&前面的空格去了才是对了，我以前总以为什么空开就是对的。。。。