caruko

=.=
发表对别人的看法的同时，也看看自己。
你可以坚持自己的想法，但不能强迫别人也有兴趣。
不依自己的想法就是"XX主义"?

caruko

不用CALL的办法，但目前不支持重复字符，因为用到字符替换，数字比如“2 12” “a  ab  bf”就会出错。
去重复也可以，但是需要增加一些代码，把字符改成"_2_  _12_"，效率有降低。
纯数字的话，稍改一下效率更快。

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set "str=a b c d e f"
for %%i in (%str%) do (
    set /a n+=1,_%%i=n
)
echo, !str!
for /l %%a in (1,1,10000000) do (
    set "last="&set "flag="&set "pos=0"
    for %%b in (!str!) do (
        set /a pos+=1
        if defined last (
            set /a n1=_%%b,n2=_!last!
            if !n1! gtr !n2! set flag=!last! !pos!
            set "last=%%b"
        ) else (
            set "last=%%b"
        )
    )
    if not defined flag call :end %%a
    for /f %%b in ("!flag!") do for %%c in (!str!) do if !_%%c! gtr !_%%b! set "th=%%c"
    for /f "tokens=1,3" %%b in ("!flag! !th!") do (
        set "temp=!str:%%b=#!"
        set "temp=!temp:%%c=%%b!"
        set "str=!temp:#=%%c!"
    )
    set "ppos="&set "cut1="&set "cut2="&set "array="
    for %%b in (!str!) do (
        set /a ppos+=1
        for /f "tokens=2" %%c in ("!flag!") do (
            if !ppos! geq %%c (
                set "cut2=!cut2! %%b"
            ) else (
                set "cut1=!cut1! %%b"
            )
        )
    )
    for %%i in (!cut2!) do (
        set "array=%%i !array!"
        for %%j in (!array!) do (
            if %%i gtr %%j (
                set "array=!array:%%i=#!"
                set "array=!array:%%j=%%i!"
                set "array=!array:#=%%j!"
            )
        )
    )
    set str=!cut1! !array!
    echo,!str!
)
:end
echo,一共%1个排列.
pause>nul&exit
复制代码

caruko

不用递归的算法，对字符位置敏感，去重复有点麻烦。

caruko

不用CALL，不用递归的办法，应该是批处理最快的方法之一吧，比CALL 递归速度要快3倍以上吧。
但是跳出FOR还是没有好的办法，目前用CALL EXIT退出循环。
不支持重复字符，因为对字符的位置敏感，重复字符的原位置值判断麻烦。

稍作修改，在原字符前后各加一个@，以保证不会意外的替换掉字符的一部分，只要字符不带@以及特殊字符即可。

代码可以得到任意字符的一个排列的下一个排列，或者得到第N个排列，比如排列字符为abcdef，现求 abdfec 的下一个排列，只要在初始化位置值后，替换STR为abdfec，计算一次以后即得到 abecdf。

支持多字符元素的组合，如代码：

@echo off&SETLOCAL ENABLEDELAYEDEXPANSION
set "str=1 11 12 a ab acd"
set time1=!time!
for %%i in (%str%) do (
    set /a n+=1,_@%%i@=n
    set "tstr=!tstr! @%%i@"
)
set "str=!tstr!"
echo,!str:@=!
for /l %%a in (1,1,10000000) do (
    set "last="&set "flag="&set "pos=0"
    for %%b in (!str!) do (
        set /a pos+=1
        if defined last (
            set /a n1=_%%b,n2=_!last!
            if !n1! gtr !n2! set flag=!last! !pos!
            set "last=%%b"
        ) else (
            set "last=%%b"
        )
    )
    if not defined flag call :end %%a
    for /f %%b in ("!flag!") do for %%c in (!str!) do if !_%%c! gtr !_%%b! set "th=%%c"
    for /f "tokens=1,3" %%b in ("!flag! !th!") do (
        set "temp=!str:%%b=#!"
        set "temp=!temp:%%c=%%b!"
        set "str=!temp:#=%%c!"
    )
    set "ppos="&set "cut1="&set "cut2="&set "array="
    for %%b in (!str!) do (
        set /a ppos+=1
        for /f "tokens=2" %%c in ("!flag!") do (
            if !ppos! geq %%c (
                set "cut2=!cut2! %%b"
            ) else (
                set "cut1=!cut1! %%b"
            )
        )
    )
    for %%i in (!cut2!) do (
        set "array=%%i !array!"
        for %%j in (!array!) do (
            if %%i gtr %%j (
                set "array=!array:%%i=#!"
                set "array=!array:%%j=%%i!"
                set "array=!array:#=%%j!"
            )
        )
    )
    set str=!cut1! !array!
    echo,!str:@=!
)
:end
echo,一共%1个排列. !time1!--^>!time!
pause>nul&exit
复制代码

caruko

23# 523066680

@echo off
set a=%%a&set b=%%b&set c=%%c
set "fo=for %a% in (a b c) do for %b% in (a b c) do for %c% in (a b c) do if not %a%==%b% if not %b%==%c% if not %a%==%c% echo %a%%b%%c%"
%fo%
复制代码

caruko

=.=
好高明的算法，看了半天还没弄明白