plp626

这个很短小。

@echo off
call:perm "a b c xy z"
pause

:perm <"c1 c2 ..."> // code by plp
setlocal enabledelayedexpansion&set "s=%~1 "
if "!s: =!" == ""  (echo %~2)else for %%b in (%~1)do call:perm "!s:%%b =!" "%~2 %%b"
endlocal&goto:eof
复制代码

这个代码可精简为：

@echo off&setlocal enabledelayedexpansion
call:perm "a b c xy z"
pause

:perm <"c1 c2 ..."> // code by plp
setlocal&set "s=%~1 "&if "!s: =!" == ""  (echo %~2)else for %%b in (%~1)do call:perm "!s:%%b =!" "%~2 %%b"
复制代码

依据：
setlocal enabledelayedexpansion后，子过程会自动继承变量延迟开启，
call一个子过程，若setlcoal后，在结束该子过程时默认endlocal。。。

plp626

这个兼容特殊字符

@echo off
call:perm "< & > plp |"
pause

:perm <"s1 s2 ..."> 
setlocal enabledelayedexpansion&set "s= %~1"&for /f "tokens=*" %%a in ("%~1")do Set "ss=%%a"
if "!s: =!" == ""  (echo "%~2 ") else for %%b in ("!ss: =" "!")do call:perm "!s: %%~b=!" "%~2 %%~b"
endlocal&goto:eof
复制代码

这个可精简为：

@echo off&setlocal enabledelayedexpansion
call:perm "< & > plp |"
pause

:perm <"s1 s2 ..."> 
setlocal&set "s= %~1"&for /f "tokens=*" %%a in ("%~1")do Set "ss=%%a"
if "!s: =!" == ""  (echo "%~2 ") else for %%b in ("!ss: =" "!")do call:perm "!s: %%~b=!" "%~2 %%~b"
复制代码

依据：
setlocal enabledelayedexpansion后，子过程会自动继承变量延迟开启，
call一个子过程，若setlcoal后，在结束该子过程时默认endlocal。。。

plp626

16# zm900612

你首先得给问题找到一个递归关系(recursion case)，然后确定初始态（base case），比如n!=n*(n-1)!光有这个递归关系还不行，一定得有个出发点，就是所谓的base case, 它是递归函数终止的标志。

再者，批处理的call又不完全同于C语言的函数，它必须加setlocal后才能保证函数内部变量不影响外部变量。。这会带来不少问题。。批处理的call==娱乐。。
=============================

怎么写完一个递归函数，你又怎么知道自己写的函数是正确的呢？
我引用宋劲彬的一段话：

如果你相信你正在写的递归函数是正确的，并调用它，然后在此基础上写完这个递归函数，那么它就会是正确的，从而值得你相信它正确。

看你说的那个整数划归问题，我还真不好找处一个递归关系。。。

plp626

批处理的makefunction 特性：（利用netben版主首创的内敛函数技巧）

@echo off&setlocal EnableDelayedExpansion
call:makefun _perm "a b c d xy"
%_perm%
pause&exit

:makefun <funname> <"charlist">
Set n=-1&Set s0=%~2&Set p=&set f=&for %%a in (%~2)do Set/a n+=1
for /l %%a in (0 1 %n%)do (Set/a m=%%a+1
Set "f=!f!&for %%%%a in (^!s%%a^!)do Set s!m!=^!s%%a:%%%%a=^!"
Set p=!p! %%%%a)
set %1=!f:~1,-15!ECHO !p!&goto:eof
复制代码

plp626

27# zm900612


注意看17楼第三个代码，我的和他的思路基本一致。。。