namejm

　　把两个文本的相同行交叉合并，需要考虑以下两种情况：
　　1、两个文本的行数相同；
　　2、两个文本的行数不同。

　　如果两个文本行数相同，则可以省略对文本行数的判断，但考虑到效率高低，需要使用临时文件，则可使用如下代码：

@echo off
findstr .* 1.txt>_1.txt
setlocal enabledelayedexpansion
for /f "delims="  %%i in (2.txt) do (
    set /a num+=1
    echo !num!:%%i
    findstr /b /i "!num!:" _1.txt
)
del /q _1.txt
pause
复制代码

　　如果两个文本行数不同，则需要判断行数谁多谁少，从而减少对比次数，演示代码如下：

@echo off
:: 生成临时文件，主要是为了获得 行数:行内容 格式的文本
findstr /n .* 1.txt>_1.txt
findstr /n .* 2.txt>_2.txt

:: 获取各自的总行数
for /f "delims=:" %%i in (_1.txt) do set num_1=%%i
for /f "delims=:" %%i in (_2.txt) do set num_2=%%i

:: 比较行数谁多谁少
set num=%num_1%
set file_1=_1.txt&set file_2=_2.txt
if %num_1% geq %num_2% (
    set num=%num_2%
    set file_1=_2.txt&set file_2=_1.txt
)

:: 以行数少的文本为标准，交叉输出两文本的同行内容
for /f "tokens=1* delims=:" %%i in (%file_1%) do (
    echo %%i:%%j
    findstr /b /i "%%i:" %file_2%
)

:: 对多出的行内容，一次性输出，减少了对比次数，从而提高效率
more +%num% %file_2%
del /q _1.txt _2.txt
pause
复制代码

　　如果不动用临时文件，要么需要设置大量的变量，严重消耗系统内存；要么需要用 if 语句对行号进行机械对比，严重影响效率；如果使用 set 排序方案，则要求每个文本的总行数不能超过9行，并且不能保证某个文件的行内容总是排在两行中的第一行或第二行。
　　注：以上代码都没有考虑特殊字符。