[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

[转贴] VBS脚本显示“选择文件或文件夹”对话框

VBS 显示“选择文件或文件夹”对话框的代码,经测试windows xp下才可以使用,win2000,win2003没有内置这样的方法。

一、显示“选择文件”的对话框

问: 嗨,Scripting Guy!有没有什么方法可以让我使用脚本向用户显示一个对话框,供用户选择文件使用?

答:您好。|
  如果您使用的是 Windows 2000,我们不知道实现此操作的方法,至少操作系统中没有内置这样的方法。
  但如果您使用的是 Windows XP,情况就不同了。在 Windows XP 上,您可以使用"UserAccounts.CommonDialog” 对象向用户显示一个标准的“文件打开”对话框。

可以用类似以下代码的脚本:
  1. Set objDialog = CreateObject("UserAccounts.CommonDialog")
  2. objDialog.Filter = "All Files|*.*"
  3. objDialog.InitialDir = "C:\"
  4. intResult = objDialog.ShowOpen
  5. If intResult = 0 Then
  6. Wscript.Quit
  7. Else
  8. Wscript.Echo objDialog.FileName
  9. End If
复制代码
这是一个小脚本,所以让我们逐行进行解释吧:

1)我们首先创建一个对 UserAccounts.CommonDialog 对象的对象引用(名为“objDialog”)。

2)接着,我们设置对话框的“筛选”属性。我们要显示所有文件,所以我们将筛选设置成这样:
  1. objDialog.Filter = "All Files|*.*"
复制代码
假如我们只想显示文本文件,那该怎么办?在这种情况下,我们将使用以下筛选:
  1. objDialog.Filter = "Text Files|*.txt"
复制代码
您也许能够看出它是如何运行的:我们为文件类型提供说明 (Text Files),然后插入一个竖线分隔符 (|),最后使用标准的通配符来指示所有 .txt 文件 (*.txt)。
是不是想默认显示 .txt 文件,然后为用户提供查看所有文件的选项?那么可以使用以下代码:
  1. objDialog.Filter = "Text Files|*.txt|All Files|*.*"
复制代码
试一试,您就明白我们的意思了。

3)然后,我们指定默认文件夹。
默认情况下,我们希望对话框显示位于驱动器 C 的根文件夹中的文件,所以我们这样设置“InitialDir”属性:
  1. objDialog.InitialDir = "C:\"
复制代码
希望显示 C:\Windows 文件夹中的文件吗?那么可以使用以下代码:
  1. objDialog.InitialDir = "C:\Windows"
复制代码
不必担心:这是一个真正的“文件打开”对话框,所以您可以随意单击,并且可以随时停下来。您从 C:\Windows 开始并不意味着您只能打开该文件夹中的文件。

4)最后,我们使用下面这行代码显示对话框:
  1. intResult = objDialog.ShowOpen
复制代码
现在,我们只需坐下来,等待用户选择文件并单击“确定”(或者等待用户单击“取消”)。
  如果用户单击“取消”,则变量 intResult 将被设置为 0。在我们的脚本中,我们检查 intResult 的值,如果是 0,我们将只需要使用 Wscript.Quit 来终止此脚本。
  但是如果用户实际上选择了文件并单击了“确定”,那该怎么办?在这种情况下,intResult 将被设置为 -1,“FileDialog”属性将被设置为所选文件的路径名。我们的脚本只回显路径名,这意味着我们将得到类似以下内容的输出:

C:\WINDOWS\Prairie Wind.bmp

  不用说,您并不局限于只回显文件路径。实际上,您可以使用 WMI、FileSystemObject 或一些其他技术来绑定该文件,然后对其执行删除、复制、压缩或检索文件属性等操作 — 您对文件能够执行的操作差不多都可以对它执行。

  但无论如何,您都需要使用脚本。

  顺便说一句,使用此方法,您一次只能选择一个文件,而不能按住“Ctrl”键选择多个文件。有一种方法可以选择多个文件,至少在 XP 计算机上可以,但是我们只能将此问题留到以后的专栏中讨论了。

二、显示“选择文件夹”对话框?

问:嗨,脚本专家!在前面的专栏中,您为我们展示了如何给用户显示对话框,使他们能够选择文件。存在给用户显示一个对话框,只让他们选择文件夹的办法吗?

答:您好。

  实际上,我们有 BrowseForFolder 方法,它是 Windows Shell 对象的一部分。

  让我给您一个脚本示例,然后讲一下它的工作方式:
  1. Const WINDOW_HANDLE = 0
  2. Const OPTIONS = 0
  3. Set objShell = CreateObject("Shell.Application")
  4. Set objFolder = objShell.BrowseForFolder _
  5. (WINDOW_HANDLE, "Select a folder:", OPTIONS, "C:\")
  6. If objFolder Is Nothing Then
  7. Wscript.Quit
  8. End If
  9. Set objFolderItem = objFolder.Self
  10. objPath = objFolderItem.Path
  11. Wscript.Echo objPath
复制代码
首先,我们定义一对常量:WINDOW_HANDLE 和 OPTIONS。
  WINDOW_HANDLE 常量表示需要指定给要显示的对话框的数字 ID;对于脚本,此值应始终为 0。
  将 OPTIONS 设置为 0 表示我们将显示一个非常简单的对话框,一个限制用户只从文件夹列表进行选择的对话框。或者,我们可以将 OPTIONS 设置成 &H10&。这种情况下,我们的对话框将包括文本区,用户可以在此键入文件夹路径。

  定义完常量后,我们创建 Shell.Application 对象的实例,然后使用以下代码显示“浏览文件夹”对话框:
  1. Set objFolder = objShell.BrowseForFolder _
  2. (WINDOW_HANDLE, "Select a folder:", OPTIONS, "C:\")
复制代码
您可以看到,我们只是调用 BrowseForFolder 方法,传递了四个参数:
    WINDOW_HANDLE,正如我们所说明的,是分配给对话框窗口的数字 ID。
    文本字符串 Select a folder:,将作为显示在对话框中的说明性消息。
    OPTIONS,表示构造对话框所用选项的常量。
    C:\,将作为对话框的根文件夹。对话框将打开 C:\,但不允许您选择树视图中较上方的文件位置(例如,您不能选择“我的电脑”)。如果将根文件夹设置为 C:\Scripts,则将只允许用户选择文件夹 C:\Scripts 及其所有子文件夹。

  该代码将产生一个类似屏幕上显示的对话框。
  (您是否有疑问,是的,您以前曾见过此对话框。许多 Windows 应用程序使用同样的方法,同样的对话框。)

  此时,我们的脚本暂停,等候用户选择文件夹并单击确定,或者单击取消。当用户进行了这两个操作之一,对话框将被清除,操作将存储在对象引用 objFolder 中。

  那么我们如何知道用户是否选择了一个文件夹并单击了确定,或者只单击了取消?以下代码块就用来解决这个问题:
  1. If objFolder Is Nothing Then
  2. Wscript.Quit
  3. End If
复制代码
该代码检查我们的对象引用 (objFolder) 是否等于一个真正对象(这是关键字 Nothing 的用途)。如果 objFolder 等于 Nothing,则意味着用户单击了取消;如果是那样的话,我们只简单用 Wscript.Quit 退出脚本。如果 objFolder 不等于 Nothing,那么 objFolder 一定指向一个真正的对象;于是脚本将继续运行。

  由于 Shell 对象的特点,以下两行代码是必要的:
  1. Set objFolderItem = objFolder.Self
  2. objPath = objFolderItem.Path
复制代码
当用户选择文件夹并单击确定,他们将得到 Shell Folder 对象的实例。然而,由于某些原因您不能使用 Shell Folder 对象;如果我们要检索选定文件夹的路径,我们得用 FolderItem 对象来代替。(为什么是这样呢?我们不知道。)于是,我们的第一行代码使用 Self 方法返回一个 FolderItem 对象,该对象正与我们的 Folder 对象相同。第二行代码将到此 FolderItem 对象的路径存储到变量 objPath 中。看上去有点笨拙,但它确实能够工作。

  最后我们回显到选定文件夹的路径,到此工作既已完成。

  正如我们说明的,示例对话框使用 C:\ 作为根文件夹,不允许您选择位于计算机其他地方的文件夹。有时这样做很好;这样会迫使用户从一组特定文件夹中进行选择。但有时,想使用户能够选择文件系统中任意位置的文件夹。这可能吗?

  当然可以。我们不详述这个修改后的脚本,但该脚本会将“我的电脑”设置为根文件夹:
  1. Const MY_COMPUTER = &H11&
  2. Const WINDOW_HANDLE = 0
  3. Const OPTIONS = 0
  4. Set objShell = CreateObject("Shell.Application")
  5. Set objFolder = objShell.Namespace(MY_COMPUTER)
  6. Set objFolderItem = objFolder.Self
  7. strPath = objFolderItem.Path
  8. Set objShell = CreateObject("Shell.Application")
  9. Set objFolder = objShell.BrowseForFolder _
  10. (WINDOW_HANDLE, "Select a folder:", OPTIONS, strPath)
  11. If objFolder Is Nothing Then
  12. Wscript.Quit
  13. End If
  14. Set objFolderItem = objFolder.Self
  15. objPath = objFolderItem.Path
  16. Wscript.Echo objPath
复制代码
如您所料,所得到的对话框提供了很多选择。这正是您所需要的。

对VBS不太熟悉,学习了

TOP

返回列表