powerbat

@echo off
set "file=jpg,mpg"
set "fileD=%~d0" & set "fileP=%~p0"
for /f "tokens=1,3* delims=.+ " %%a in ('wmic datafile where "drive='%fileD%' and path='%fileP:\=\\%' and (extension='%file:,=' or extension='%')" get name^,LastModified') do (
    set "t=%%a"
    rem 用for过滤掉wmic结果中的不可见字符
    for /f "delims=" %%i in ("%%c") do (
        setlocal enableDelayedExpansion
        set "t=!t:~,4!-!t:~4,2!-!t:~6,2! !t:~8,2!.!t:~10,2!.!t:~12!"
        for %%t in ("!t!") do (
            endlocal
            if not exist "%%~dpi%%~t%%~xi" (
                ren "%%~fi" "%%~t%%~xi"
            ) else (
                set n=1
                for %%u in ("%%~dpi%%~t_*%%~xi") do set /a n+=1
                setlocal enableDelayedExpansion
                for %%u in (!n!) do endlocal& ren "%%~fi" "%%~t_%%~u%%~xi"
            )
        )
    )
)
pause
复制代码

powerbat

回复 13# fyubo


    本机测试后代码有个地方没改到，已更新。

powerbat

回复 14# find


    不是wmic本身的效率问题，而是他的用法不恰当，对每个文件都要调用3个外部命令（for /f内部调用cmd、cmd调用wmic、findstr），你想效率会高吗？

powerbat

回复 20# fyubo

@echo off
set "file=jpg,mpg"

set "Ext=*.%file:,= *.%"
rem 先重命名一次，加一段文件名中不会出现的字符串，防止可能的文件名重复问题。
for /f "delims=" %%a in ('dir /b %Ext%') do (
    ren "%%~fa" "powerbat@bathome_%%~nxa"
)

set "FileD=%~d0" & set "FileP=%~p0"
set "Ext=and (extension='%file:,=' or extension='%')"
set "Filter=drive='%FileD%' and path='%FileP:\=\\%' %Ext%"
for /f "tokens=1,3* delims=.+ " %%a in ('wmic datafile where "%Filter%" get name^,LastModified') do (
    set "t=%%a"
    rem 用for过滤掉wmic结果中的不可见字符
    for /f "delims=" %%i in ("%%c") do (
        set "f=%%~fi"
        set "p=%%~dpi"
        set "n=%%~ni"
        set "x=%%~xi"
        setlocal enableDelayedExpansion
        set "t=!t:~,4!-!t:~4,2!-!t:~6,2! !t:~8,2!.!t:~10,2!.!t:~12!"
        if not exist "!p!!t!!x!" (
            ren "!f!" "!t!!x!"
        ) else  if "!t!" neq "!n!" (
            set n=1
            for %%u in ("!p!!t!_*!x!") do set /a n+=1
            ren "!f!" "!t!_!n!!x!"
        )
        endlocal
    )
)
pause
复制代码

powerbat

批处理将文件重命名为文件修改时间(精确到秒)
http://www.bathome.net/thread-15792-1-1.html

powerbat

回复 28# fyubo

是有可能wmic分配的内存不够用了。
看来wmic也太矬了。。。
vbs版
http://www.bathome.net/thread-15803-1-1.html