tmplinshi

@echo off
setlocal enabledelayedexpansion

for /f "delims=" %%a in ('findstr "<Target>.*</Target>" 1.txt') do (
    set Target=%%a
)

for /f %%n in (' find /c /v "" ^< 2.txt ') do (
    for /l %%a in (1 1 %%n) do (
        set str=
        set /p str=
        if not defined str (
            echo,
        ) else if "!str:</Target>=!" neq "!str!" (
            echo !Target!
        ) else (
            echo,!str!
        )
    )
) <2.txt >2.new

move 2.new 2.txt

pause
复制代码

tmplinshi

sed 下载地址: http://bathome.net/thread-15605-1-4.html

@echo off
set sed=sed -n "s|^.*\(<Target>.*</Target>\).*$|\1|ip" 1.txt
for /f "delims=" %%a in ('%sed%') do set t1=%%a
sed -i "s|<Target>.*</Target>|%t1%|i" 2.txt
pause
复制代码

tmplinshi

多谢老大。。。都试过了，可以。
如果只替换2.txt中 adsdasdsadsadsa  的前两位，后面的保留呢？
weww000 发表于 2012-11-21 18:39

    是否是这个意思？

1.txt

<Target>123456</Target>

2.txt

<Target>abcdefg</Target>

结果为：
2.txt

<Target>123456cdefg</Target>

如果是这个意思的话，代码如下：

@echo off
set sed=sed -n "s|^.*<Target>\(.*\)</Target>.*$|\1|ip" 1.txt
for /f "delims=" %%a in ('%sed%') do set t1=%%a
sed -i -r "s|(<Target>)..(.*</Target>)|\1%t1%\2|i" 2.txt
复制代码

tmplinshi

创建多个快捷方式为什么只有第一个有效？其他的无效
weww000 发表于 2012-11-21 19:51

    请另外发一个帖子，因为这个问题与这个帖子没有关联。

    另外，你需要把代码贴出来，别人才能分析是什么原因。