netbenton

来个快速的！
更改变量 sleep的值来改变速度

下载mach.exe： http://bbs.bathome.net/attachment.php?aid=1958

@echo off&setlocal enabledelayedexpansion
for /f %%a in ('set') do set %%a=
set a=
for /l %%a in (1,1,23) do (
        set b=
        for /l %%b in (1,1,78) do (set b= !b!)
        set a=!a!#!b!#
)
set a=#!b: =#!#!a!#!b: =#!
set #=00
title BatHome

start "贪吃蛇控制窗口" cmd /c mode con:cols=26 lines=2^&set/p=方向键[a s d w],退出Ctrl+c^<NUL^&MACH.EXE

set a61=-1
set a64=1
set a77=-80
set a73=80
set o0=1
set o24=1
set oo0=1
set oo79=1
set dai=  BEGIN  
set b=!a!


:begin
cls&set/p=!b:~,913!!dai!!b:~922!<NUL

set/a sleep=1500,d=915,dois=915,fen=0

:lp
if not defined r (
        set/a r=!random!%%23*80+!random!%%79+81
        set "a=!a:@= !"
        for %%a in (!r!) do (
                set /a v=%%a+1
                for /f %%b in ("!v!") do set a=!a:~,%%a!@!a:~%%b!
        )

)

if !#! neq 00 (
        set dai=Pause
        if defined a%#% set g=!a%#%!&set #=00&set dai=
        if !#! equ 03 exit/b
)

if defined dai goto :pause

if defined g (
        set/a "d+=g,n=d%%80,m=d/80"
    for /f "tokens=1-3" %%a in ("!d! !n! !m!") do (
        if "!dois: %%a =!" neq "!dois!" set dai=GAME OVER
        if "!oo%%b!!o%%c!" neq "" set dai=GAME OVER
        if defined dai goto :begin
    )
    if !r! equ !d! (
        set r=
        set v=%dois: =&rem %
        set "dois=!v! !dois!"
        set/a sleep-=10,fen+=1
    )
    set dois=!dois:* =!!d! 
    call :_print
)

:pause
for /l %%a in (1,1,%sleep%) do (ver>nul)

goto :lp


:_print
set b=!a!
for %%a in (%dois%) do (
        set /a v=%%a+1
        for /f %%b in ("!v!") do (set b=!b:~,%%a!*!b:~%%b!)
)
cls&set /p=!b!<NUL
title  得分：!fen!
goto :eof
复制代码

[ 本帖最后由 netbenton 于 2009-11-5 12:55 编辑 ]