- @ECHO OFF & title Win7虚拟无线路由 & cd /d %~dp0
- if /i not "%1"=="" goto %1
- echo Loading...
- netsh wlan show drivers>nul
- if errorlevel 1 cls & echo 没有无线网卡设备或无线没有开启!
- FOR /F "tokens=3 delims= " %%i in ('netsh wlan show drivers^|find "支持的承载网络"') do (
- cls & echo 支持的承载网络:%%i
- if %%i==是 netsh wlan show drivers|find /i "vwifibus.sys" >nul && goto main || echo 未找到vwifibus.sys文件,请重新安装无线网卡驱动!
- )
- pause >nul & exit
- :main
- cls & echo 正在更新状态...
- FOR /F "tokens=3 delims= " %%i in ('netsh wlan show hostednetwork^|find "状态"') do (cls & echo 虚拟无线路由当前状态为:%%i & set zt=%%i)
- echo.
- echo 1.启用虚拟无线路由
- echo.
- echo 2.关闭虚拟无线路由
- echo.
- echo 3.设置开机自动启用虚拟无线路由
- echo.
- echo 4.取消开机自动启用虚拟无线路由
- echo,
- echo 5.修改无线名称及密码
- echo.
- set choice=
- set /p choice=输入编号,按下回车键=
- if "%choice%"=="1" goto auto
- if "%choice%"=="2" if not "%zt%"=="不可用" cscript //nologo ics.vbs "无线网络连接 2" "本地连接" "off" >nul & netsh wlan set hostednetwork mode=disallow >nul & goto show
- if "%choice%"=="3" reg add HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /v autowifiap /d "mshta vbscript:createobject(\"wscript.shell\").run(\"%~s0 auto\",0)(window.close)" /f >nul 2>nul && echo 设置成功!注:该批处理不能移动、重命名及删除,否则将无法开机自动运行。 || echo 设置失败!
- if "%choice%"=="4" reg delete HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /v autowifiap /f >nul 2>nul && echo 取消成功! || echo 取消失败或还没有设置开机启用。
- if "%choice%"=="5" notepad wifi.ini & echo 修改完成后需重启虚拟无线路由才能生效!
- if "%choice%"=="" cls & goto main
- pause
- cls & goto main
- :auto
- FOR /F "eol=; tokens=2 delims=:" %%i in ('type wifi.ini^|find "无线名称"') do (set "SSIDvalue=%%i")
- FOR /F "eol=; tokens=2 delims=:" %%i in ('type wifi.ini^|find "无线密码"') do (set "PasswordValue=%%i")
- echo 无线名称=%SSIDvalue% 无线密码=%PasswordValue%
- if /i not "%1"=="auto" pause
- cscript //nologo ics.vbs "无线网络连接 2" "本地连接" "off" >nul & netsh wlan set hostednetwork mode=disallow >nul
- sc config MpsSvc start=demand >nul 2>nul
- net start MpsSvc >nul 2>nul
- netsh wlan set hostednetwork mode=allow "ssid=%SSIDvalue%" "key=%PasswordValue%" keyUsage=persistent >nul
- netsh wlan start hostednetwork >nul
- if errorlevel 1 echo 请尝试更新无线网卡驱动或重新安装系统!& netsh wlan set hostednetwork mode=disallow >nul & pause>nul & exit
- if exist ics.vbs (cscript //nologo ics.vbs "无线网络连接 2" "本地连接" "on" >nul) else (echo 未找到ics.vbs文件,可能需要手动设置共享才能访问网络!)
- :show
- if /i "%1"=="auto" exit
- cls & netsh wlan show hostednetwork
- pause & goto main
复制代码
|