xxpinqz

纯p这样的效率应该很高了吧。
可惜findstr的结果会自动排序，要不效率应该会快点。
m取值为n不是更合理，第8行应该追加吧 ))>>"%%i"

xxpinqz

回复 8# needhelp
纯P处理这么大文件可不行，换个思路试试:

@echo off&setlocal enabledelayedexpansion
findstr /n .* all.txt >tmp
for /l %%a in (1,1,1020) do (
     set/a r=!random!+!random!%%17233+1
     set "var=!var!!r!: "
)
for /f "tokens=1* delims=:" %%a in ('findstr /b "!var!" tmp') do (
    set /a n+=1
    if !n! leq 1000 set "#!n!=%%b"
)
for /f "delims=" %%i in ('dir /b /a-d *.txt ^| findstr /ivx "all\.txt"') do (
    (for /l %%a in (1 1 10) do (
        set /a n=!random!%%1000+1
        for %%b in (!n!) do echo !#%%b!
    ))>>"%%i"
)
del tmp
复制代码

xxpinqz

或者不考虑随机数的顺序，效率会高一点
17233=50000-32767

@echo off&setlocal enabledelayedexpansion
set "fn=all.txt"
for /l %%a in (1,1,1020) do (
     set/a r=!random!+!random!%%17233+1
     set "var=!var!!r!: "
)
findstr /n .* "%fn%"|findstr /b "%var%" >tmp
(for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
    if not "%%i"=="%fn%" (
        (for /l %%a in (1 1 10) do (
             set/p str=
              echo,!str:*:=!
         ))>>"%%i"
    )
))<tmp
del tmp
复制代码