【已解决】怎样把一个标签的内容复制成一个新的批处理?

nnszuo · 发表于 2014-10-11 11:59:54

本帖最后由 nnszuo 于 2014-10-23 09:40 编辑

在论坛找了下复制自身某段内容到新的批处理文件时都要计算行数的,感觉这样比较麻烦,能不能把一个标签的下的所有内容复制成一个新的批处理
比如把下面标签的内容生成新的批处理

:xin
@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /a-d /b c:\aaa') do (
set str=%%i
for /f "tokens=2 delims=. " %%a in ("%%i") do ren "c:\aaa\!str!" !str: %%a=!
)
pause

复制代码

cjiabing · 发表于 2014-10-11 13:41:27

回复 1# nnszuo

首先你要区分这段内容与其他代码的区别，找到具体的特征标记，找到开始点和结束点，这样批处理才能认识。
笼统地说，只要字符前面有一个冒号都算标签了。
但标签后面的内容从哪里结束？一般标签的结束用的比较多的是goto :eof、pause、exit等，但不是绝对，具体问题具体分析。
所以，答案很简单：
1、直接find到这个标签名“:”——more和for就可以了。
2、将此标签名后面的内容全部写入新建的批处理。FOR处理就可以。
3、根据这段代码的特征判断结束点。比如，以“goto :eof”结束的直接if /i "%%a"=="goto :eof" 跳出写入。

Batcher · 发表于 2014-10-11 16:10:37

@echo off
for /f "delims=:" %%i in ('findstr /n "^:DynamicScript$" "%~f0"') do (
more +%%i "%~f0" > new.bat
)
goto :eof
:DynamicScript
@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /a-d /b c:\aaa') do (
set str=%%i
for /f "tokens=2 delims=. " %%a in ("%%i") do ren "c:\aaa\!str!" !str: %%a=!
)
pause

复制代码

nnszuo · 发表于 2014-10-20 13:32:31

回复 3# Batcher

我是新手不明白 more +%%i "%~f0" 的意思,可以解释一下么

Batcher · 发表于 2014-10-20 14:19:42

回复 4# nnszuo

系统自带的帮助文档里面有讲解
more /?
+n 从第 n 行开始显示第一个文件

%~f0 是指批处理自身这个文件

nnszuo · 发表于 2014-10-20 15:17:56

回复 2# cjiabing
多谢提示,只要做个特定的标记就行
这是我刚做批处理有需要简化的地方没.或者其他类似的批处理,现在学习中需要更多实例

goto :kaishi
::序号1
str="将文字复制到剪贴板我是文本1"
Set ws = wscript.createobject("wscript.shell")
ws.run "mshta vbscript:clipboardData.SetData("+""""+"text"+""""+","+""""&str&""""+")(close)",0,true
createobject("scripting.filesystemobject").getfile(wscript.scriptfullname).delete
::序号2
str="将文字复制到剪贴板我是文本2"
Set ws = wscript.createobject("wscript.shell")
ws.run "mshta vbscript:clipboardData.SetData("+""""+"text"+""""+","+""""&str&""""+")(close)",0,true
createobject("scripting.filesystemobject").getfile(wscript.scriptfullname).delete
::序号3
str="将文字复制到剪贴板我是文本3"
Set ws = wscript.createobject("wscript.shell")
ws.run "mshta vbscript:clipboardData.SetData("+""""+"text"+""""+","+""""&str&""""+")(close)",0,true
createobject("scripting.filesystemobject").getfile(wscript.scriptfullname).delete
::序号4
str="将文字复制到剪贴板我是文本4"
Set ws = wscript.createobject("wscript.shell")
ws.run "mshta vbscript:clipboardData.SetData("+""""+"text"+""""+","+""""&str&""""+")(close)",0,true
createobject("scripting.filesystemobject").getfile(wscript.scriptfullname).delete
::tingzhi
:kaishi
@echo off&setlocal enabledelayedexpansion
set "ming="序号1-文本 1" "序号2-文本2" "序号3-文本3" "序号4-文本4""
set "lu="序号1-%~dp0" "序号2-c:" "序号3-d:" "序号4-e:""
for /f "skip=1 tokens=*" %%i in ('type "%~f0"') do (
set ii=%%i
if "%%i" == "::tingzhi" goto yun
for %%a in (%ming%) do (
set w=%%~a
for %%b in (%lu%) do (
set l=%%~b
if "%%i%%i" == "::!w:~0,3!::!l:~0,3!" (
set "s=!l:~4!!w:~4!.vbs"&&cd.>"!s!"
)
)
)
if not "!ii:~2,2!" == "序号" (@echo %%i>>!s!)
)
:yun
pause>nul

复制代码

nnszuo · 发表于 2014-10-20 15:22:41

回复 5# Batcher
感谢讲解,现正学习中,回去看看帮助

DAIC · 发表于 2014-10-20 17:20:51

回复 6# nnszuo

建议合理的使用缩进，比如：

@echo off
setlocal enabledelayedexpansion
set "ming="序号1-文本 1" "序号2-文本2" "序号3-文本3" "序号4-文本4""
set "lu="序号1-%~dp0" "序号2-c:" "序号3-d:" "序号4-e:""
for /f "skip=1 tokens=*" %%i in ('type "%~f0"') do (
set ii=%%i
if "%%i" == "::tingzhi" goto yun
for %%a in (%ming%) do (
set w=%%~a
for %%b in (%lu%) do (
set l=%%~b
if "%%i%%i" == "::!w:~0,3!::!l:~0,3!" (
set "s=!l:~4!!w:~4!.vbs"
cd.>"!s!"
)
)
)
if not "!ii:~2,2!" == "序号" (
echo %%i>>!s!
)
)

复制代码

nnszuo · 发表于 2014-10-23 09:41:40

嗯.我那看起来太乱

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 【已解决】怎样把一个标签的内容复制成一个新的批处理?

浏览过的版块