[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

[转贴] 批处理文章:预处理、变量延迟、call

原始出处:http://bbs.verybat.org/viewthread.php?tid=9292
原始标题:讨论帖:预处理究竟是如何进行的
————————namejm补注————————————————

一、预处理究竟要做什么?


    根据我的经验,预处理要做的是变量值的替换和特殊符号的处理。究竟先执行哪个操作呢,我认为要先进行变量值的替换。理由有三:

1 从逻辑上看

set var=2&echo %var%
类似于这样的语句,如果说先进行特殊符号处理的话,势必要先处理符号“&”,而“&”是用来连接两条命令的,这样一来该行就理所应当的被理解为两句,那么我们还要变量延迟干嘛。这里应该是先对变量var赋值,然后处理特殊符号“&”。

2、从运行结果看


@echo off



set var=^^^>


echo %var%


pause


这句“set var=^^^>”首先也会被预处理,预处理之后var的值为“^>”。本例的输出结果是“>”,因此可以证明系统先将变量的值替换为“^>”然后再处理特殊符号“^”。

3、从变量替换上看


@echo off


set ^&var=hero


echo %&var%


pause


结果:显示“hero”这也说明变量的替换先于特殊符号的处理。

二、启动了变量延迟之后预处理又是如何进行呢?

    我的看法是这样的:如果语句中存在英文叹号“!”则会被预处理两次,其它情况仍然是预处理一次。由于脱字字符比较特殊,,因此在此借助该符号写几个例子说明一下。

(一)

@echo off


echo !^^^^^>


setlocal enabledelayedexpansion


echo !^^^^^>


pause

两个echo语句的结果不同。下面做一下分析:对于第一个echo语句,变量延迟没有开启,进行预处理的时候该句就被预处理为“echo !^^>”,这也就是输出的结果。由此可见预
处理只进行了一次。

对于第二个echo语句,此时变量延迟开启,由于有“!”存在,首先进行一次预处理得到“echo !^^>”,再进行一次得到“echo ^>”,结果也是如此。之所以没有输出叹号,是因为开启了变量延迟,叹号就变为了特殊符号。

(二)

@echo off


setlocal enabledelayedexpansion


set var=hero


echo !var!


pause

像这里的“echo !var!”不是没有被预处理,而是被预处理了两次。看下面的这段代码就可以理解了。

@echo off


setlocal enabledelayedexpansion


set var=hero


echo !var!^^^^^>


pause

运行的结果为:“hero^>”。我们来分析一下,进行第一次预处理时,由于“!var!”,因此先不替换变量值而进行特殊符号的处理,处理完后就成了“echo !var!^^>”;之后再进行一次预处理,此时就要替换“!var!”了,处理完后就成了“echo hero^>”。

(三)
我们再来看看当变量延迟开启时语句中不存在英文叹号的情况。

@echo off


echo ^^^^^>


setlocal enabledelayedexpansion


echo ^^^^^>


pause



@echo off


set var=hero


echo %var%^^^^^>


setlocal enabledelayedexpansion


echo %var%^^^^^>


pause

怎么样,也就是说如果没有“!”就不会进行第二次处理。

(四)
对于!!型,特殊符号的处理是在变量替换之前进行的。
例、

@echo off


setlocal enabledelayedexpansion


set ^&var=hero


echo !&var!


pause

这段代码运行结果是错误的。

例、

@echo off


setlocal enabledelayedexpansion


set var=^&


echo !var!


pause

这段代码运行结果是正确的。


(五)
既然都要处理符号,那么%%型和!!型的符号处理会不会是同一个过程?

(一)中的例子已经可以说明问题,不过我还有例子可以证明。

例、

@echo off


echo "^^^^^^^^"!!


setlocal enabledelayedexpansion


echo "^^^^^^^^"!!


pause


对于%%型,在符号处理时,不处理双引号间的脱字字符;而对于!!型则相反。


转篇文章(2)

三、call引出的一些问题

(一)
call与脱字字符

例、

@echo off


set /p var=<hero.txt



echo "%var%"


call echo "%var%"


pause


其中hero.txt中的内容为8个脱字字符:^^^^^^^^

结果是:
"^^^^^^^^"
"^^^^^^^^^^^^^^^^"
请按任意键继续. . .

结果是否有些出乎意料?我们知道,系统在预处理时不会处理双引号间的脱字字符,那就意味着是call命令将其后的脱字字符数量加了倍。看来call命令和脱字字符还真有点“暧昧”。

例、

@echo off


set /p var=<hero.txt


echo %var%


call echo %var%


pause


本例中变量var的值为8个“^”,运行“call echo %var%”时,首先进行变量替换把%var%替换为^^^^^^^^,再经一次符号的处理变为^^^^,此时由于call命令使得脱字字符数目增加一倍变为8个,然后再进行call本身的预处理,这样结果就为4个“^”。
这样就能解释下面的代码为什么会显示4个“^”。


@echo off



call call call call echo ^^^^^^^^


pause



(二)
call与其它特殊字符
这里所说的“其它特殊字符”主要指&>|等。这里请允许我自定义两个名词:
主预处理过程:系统本身预处理过程的总称,其中包括了%%型和!!型。
次预处理过程:由于call命令引起的预处理过程的总称。

“其它特殊字符”是在主预处理过程中被系统识别的,而在次预处理
过程中对这些符号的识别是有问题的。

例、


@echo off


call echo hero!^&pause


pause


本例中,经过主预处理过程,&被识别为普通字符,而在次预处理过程中符号&的识别将产生问题。正如《命令行参考》中提到的--不要在 call 命令中使用管道和重定向符号。(这倒不是说call语句中不能使用那些符号,而是这些符号不能作为参数传递给call命令。)
这也从某种程度上说明某行语句的句子结构(一条还是多条)和功能(是从定向输出还是其它)是在主预处理过程中确定的。


以上所有内容,只是我个人的看法,由于没有官方文档的支持,因
此仅供参考。


那么我们学了以上种种内容又有什么实际用途呢?我想,懂得了以上
道理就可以写出更加个性化的代码,同时也可以作为一种伪装术在实
际中应用。



@echo off


set ^&=setlocal enabledelayedexpansion


set ^^^^^hero=^^^^^&p


set ^au=^^^au


set ^^^^^^^^^=
障眼法

%&%


set ^^^^^se=^^^se!


echo %^^^^%!%^^hero%!au%^se%


怎么样,这段代码能看明白吗?
1

评分人数

    • lxzzr: 欢迎继续转载这样的好文章!PB + 2

TOP

返回列表