[注册表类] [已解决]有没什么批处理变量能set获得所在计算机SID？

1139054012

请各位指导

pcl_test

回复 1# 1139054012
没懂你什么意思
批处理获取SID的两种方法

@echo off
for /f "tokens=*" %%a in ('REG QUERY "HKEY_USERS" /s /v USERNAME ^| find /i "Volatile Environment"') do (
    for /f "tokens=*" %%1 in ('REG QUERY "%%a" /v USERNAME ^| find /i "%username%"') do (
    SET "SID=%%a"
    )
)
for /f "tokens=1-4,* delims=\" %%i in ('echo %SID%') do (
SET "SID=%%j"
)
echo %SID%
pause
复制代码

@echo off
for /f "delims=" %%a in ('wmic userAccount where "Name='%userName%'" get SID /value') do call set %%a >nul
echo %sid%
pause
复制代码

1139054012

回复 2# pcl_test


谢谢，正需要这代码。
但是导出时SID后面多出个空格

HKEY_USERS\【SID】  \Software
复制代码

请问怎么办才能导出时没有空格

HKEY_USERS\【SID】 \Software
复制代码

这样呢

pcl_test

回复 3# 1139054012
你是怎么输出的？把完整代码发下，一般末尾有空格的话可以使用截取，如

for /f "delims=" %%a in ('wmic userAccount where "Name='%userName%'" get SID /value') do call set %%a >nul
>1.txt echo %sid:~0,-1%
复制代码

Batcher

@echo off
set "rpath=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList"
for /f "delims=" %%a in ('reg query "%rpath%" ^| findstr "S-1-5-21-"') do (
    reg query "%%a" /v ProfileImagePath | findstr "%username%" >nul 2>&1 && set RegPath=%%a
)
set SID=%RegPath:*ProfileList\=%
echo,%SID%
pause
复制代码

@echo off
for /f "delims=" %%i in ('reg query "HKEY_USERS" /s /v USERNAME ^| find /i "Volatile Environment"') do (
    for /f "tokens=*" %%j in ('reg query "%%i" /v USERNAME ^| find /i "%username%"') do (
        set "SID=%%i"
    )
)
for /f "tokens=2 delims=\" %%i in ("%SID%") do (
    set "SID=%%i"
)
echo,%SID%
pause
复制代码

1139054012

回复 4# pcl_test


    谢谢了，问题已自行解决。已经好了。第二个会输出时默认SID后面会添加空格，第一个就没有了。