[文件操作] 批处理怎样把MP3的持续时间（win7显示长度）提取？

some2356

我现在有一个小的程序，可以把当前目录下的MP3文件名成提取到某个TXT文件中，但是名称的后面没有，该歌曲持续的时间！！
我想做到歌曲名称和持续长度都提取出来，上图：：



1要处理的文件（示例）

2批处理内容

3.运行过后，多出来的一个文件！！！

4. TXT文件的内容，，，，以及我想要的格式（名称后面紧跟着文本）


例如，第一个“TF Boys-魔法城堡   00：04：17   ”（小时也要统计）


请问，各路大神，这个小程序还要写上点什么才能达到最后一个图上的效果


可以是当前文件夹，也可以是当前文件夹下的所有子文件夹

Batcher

@echo off
setlocal enabledelayedexpansion
(for /f "delims=" %%i in ('dir /b *.mp3') do (
    for /f "tokens=3 delims=," %%j in ('tag.exe "%%i" 2^>^&1 ^| findstr "playtime"') do (
        REM echo %%i %%j
        set pt=%%j
        set pt=!pt: playtime =!
        echo %%i !pt!
    )
))>list.txt
复制代码

命令行工具 tag.exe 下载地址：
http://www.bathome.net/thread-6464-1-1.html

some2356

命令行工具 tag.exe 下载地址：
Batcher 发表于 2015-5-13 18:49

    谢谢，完全可用！但是有没有办法只提取时间！省略前面的文件名，顺序不乱

Batcher

回复 3# some2356


    把第8行的 %%i 删掉

some2356

回复  some2356


    把第8行的 %%i 删掉
Batcher 发表于 2015-5-13 19:17

   完全正确，顺序也是完全挨着，就是得利用第三方，，，谢谢

437153

回复 2# Batcher


    老大，能请教一下这个地方【'tag.exe "%%i" 2^>^&1 ^】中的2^>^&1 是什么意思吗？
    2>&1在tag.exe --help里面没有说是什么意思。

Batcher

回复 6# 437153


大部分命令执行的结果可以直接通过管道传递给后面的命令进行后续操作：
xxx | findstr "playtime"

tag比较特殊，它的输出在2号句柄，所以需要重定向到1号句柄，然后再通过管道传递：
tag.exe "%%i" 2>&1 | findstr "playtime"

for命令里面需要对特殊字符进行转移，所以就变成了：
tag.exe "%%i" 2^>^&1 ^| findstr "playtime"

437153

回复 7# Batcher


    哦，明白了。谢谢老大！

terse

BAT+js 练手
不显示文件名的话 去掉代码15行 处 “f,”

@if(0)==(0) echo off
dir/b *.mp3|cscript -nologo -e:jscript %0
pause & exit
@end
pad = function(tbl) {  
  return function(num, n) {  
    return (0 >= (n = n-num.toString().length)) ? num : (tbl[n] || (tbl[n] = Array(n+1).join(0))) + num;  
  }  
}([]);
WMP = new ActiveXObject("WMPlayer.OCX");
while (!WScript.StdIn.AtEndOfStream) {
    var f = WScript.StdIn.ReadLine();
    var t = WMP.newMedia(f).GetItemInfo("Duration");
    var h = parseInt(t/3600),m = parseInt(t%60),t = parseInt(t%3600/60);
    WSH.Echo(f,[pad(h,2),pad(t,2),pad(m,2)].join(':'))
}
复制代码

some2356

BAT+js 练手
不显示文件名的话 去掉代码15行 处 “f,”
terse 发表于 2015-5-14 14:22

    测试完成，完全一致，速度快，格式美观

yiwuyun

回复 7# Batcher


    虽然我没用过tag.exe.但我感觉老大说错了，因为我用ffmpeg就晓得，2是错误句柄。要把错误定向到1，管道才能起作用。tag.exe 1.mp3，这个写法和ffmpeg -i  1.mp3 应该是一样的。这个写法其实是个
不完整的写法，或者说是错误的写法，因此，它会输出到错误句柄2.但它却又确实获取了1.mp3的正确信息，当然不排除我对tag.exe理解错误。

Batcher

回复 11# yiwuyun


tag不是我开发的，所以那只是我自己的理解。当然你也可以有自己的理解。知道如何使用就好。
类似的命令还有好几个，因为看不到源代码，所以不知道它是“执行错误”，还是作者故意把 exit code 设置成了2