批处理获取U盘、可移动硬盘的盘符(2015-01-14更新)

Batcher

我们应该用批处理做些实用的事情，本帖旨在讨论批处理中如何获取可移动磁盘的盘符（以便自动实现一些针对可移动磁盘的文件/文件夹操作），而不是纯粹为了显示一下可移动磁盘的盘符是什么（没有什么意义的事情还是少做为妙）。如果您的代码只是显示了一下findstr的结果或者直接echo了一下，请先尝试一下把结果保存到一个变量里面吧。

本帖讨论的只是方法，对于多于1个可移动磁盘情况，我们在这里不予过多讨论，如果您觉得有必要，请到相应版块单独发帖。

【方案一】fsutil

1. @echo off
   
2. for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do (
   
3.     for /f %%h in ('fsutil fsinfo drivetype %%a:^|findstr "Removable.* 可移动"') do (
   
4.         set DriveU=%%h
   
5.     )
   
6. )
   
7. echo,%DriveU%
   
8. pause

复制代码

【方案二】WMIC

1. @echo off
   
2. for /f "tokens=2 delims==" %%a in ('wmic LogicalDisk where "DriveType='2'" get DeviceID /value') do (
   
3.     set DriveU=%%a
   
4. )
   
5. echo,%DriveU%
   
6. pause

复制代码

【方案三】BAT + VBS (优点是可以兼容Win2000系统)

1. @echo off
   
2. for /f "delims=:" %%i in ('findstr /n "^:DynamicScript$" "%~f0"') do (
   
3.     more +%%i "%~f0" > "%temp%\GetU.vbs"
   
4. )
   
5. for /f %%a in ('cscript /nologo "%temp%\GetU.vbs"') do (
   
6.     set "DriveU=%%a"
   
7. )
   
8. echo,%DriveU%
   
9. pause
   
10. goto :eof
    
11. 
    
12. :DynamicScript
    
13. Set Fso = CreateObject("Scripting.FileSystemObject")
    
14. Set B = Fso.Drives
    
15. 
    
16. For Each A in B
    
17.     If A.DriveType = 1 Then
    
18.         aDisk = aDisk & A.DriveLetter & ": "
    
19.     End If
    
20. Next
    
21. aDisk = Replace(aDisk, "A: ","")
    
22. WScript.Echo aDisk
    

复制代码

lianxi

感谢楼主！但是我想问一下，当我插的是两个U盘的时候怎么办？

zqz0012005

set DriveU=%%h
改为
set /a n+=1&call set DriveU%%n%%=%%h

最后用set DriveU显示所有的U盘盘符

fsh6666

'fsutil fsinfo drivetype %%a:^|findstr "Removable 可移动"') do (
    set DriveU=%%h
  不懂  希望解答

Batcher

运行这个命令
fsutil fsinfo drivetype C:
看看结果
思考一下

wangantao

【方案一】fsutil
仅获得盘符

@echo off
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do (

for /f %%h in ('fsutil fsinfo drivetype %%a:^|findstr "可移动"') do (

echo.%%h

)
)

@echo off
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do ( fsutil fsinfo drivetype %%a:|findstr "可移动" )

[ 本帖最后由 wangantao 于 2009-3-15 02:34 编辑 ]

Batcher

请问你想表达什么意思呢？

本帖旨在讨论批处理中如何获取可移动磁盘的盘符（以便自动实现一些针对可移动磁盘的文件/文件夹操作），而不是纯粹为了显示一下可移动磁盘的盘符是什么（没有什么意义的事情还是少做为妙）。如果您的代码只是显示了一下findstr的结果或者直接echo了一下，请先尝试一下把结果保存到一个变量里面吧。

kinsn

正想找这个热处理，谢谢！

BillGates

我的windows home 版怎么提示 wmic不是外部什么什么的。

Batcher

HOME版系统和精简版系统类似，都是不完整的版本，网友戏称“太监版”或者“阉割版”，不仅无法使用WMIC，还有其它很多功能都被砍掉了。

dosz

回复 7楼 的帖子

1. @title 查看可移动盘个数及盘符(当我插的是两个U盘的时候)
   
2. @echo 1楼的代码无显示（去掉“Removable ”后显示一个：显示：m:）改为3楼的代码无显示
   
3. @echo off
   
4. for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do (
   
5.   for /f %%h in ('fsutil fsinfo drivetype %%a:^|findstr "Removable 可移动"') do (
   
6.     set DriveU=%%h
   
7.   )
   
8. )
   
9. echo.%DriveU%
   
10. echo.&pause
    
11. @echo  6楼的代码
    
12. @echo off
    
13. for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do (
    
14. for /f %%h in ('fsutil fsinfo drivetype %%a:^|findstr "可移动"') do (
    
15. echo.%%h
    
16. )
    
17. )
    
18. :: 方案一：fsutil 仅获得盘符
    
19. :: 显示：l:
    
20. :: 显示：m:
    
21. echo.&pause
    
22. @echo off
    
23. for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do ( fsutil fsinfo drivetype %%a:|findstr "可移动" )
    
24. :: 显示：l: - 可移动驱动器
    
25. :: 显示：m: - 可移动驱动器
    
26. echo.&pause

复制代码

dosz

1. @echo off&title 查看可移动盘个数及盘符&for %%i in (c d e f g h i j k l m n o p q r s t u v w x y z) do fsutil fsinfo drivetype %%i:| find "可移动"

复制代码

dosz

1. @echo off&title 可同时打开多个移动盘&for %%i in (c d e f g h i j k l m n o p q r s t u v w x y z) do fsutil fsinfo drivetype %%i: | find "可移动">nul && start %%i:

复制代码

dosz

:: 附：打开最后一个分区

1. 
   
2. @echo off
   
3. for %%i in (Z Y X W V U T S R Q P O N M L K J I H G F E D C) do (
   
4.     if exist %%i:\nul (
   
5.         for /f "tokens=3" %%j in ('dir /-c %%i:\') do set freesize=%%j
   
6.         set last=%%i
   
7.         if not "!freesize!"=="0" goto last_drive
   
8.     )
   
9. )
   
10. goto :eof
    
11. :last_drive
    
12. explorer  %last%:\
    

复制代码

Batcher

1、Removable是为了兼容英文版操作系统，至于你说的中文系统下无法显示的问题，顶楼代码已更新并修复此bug，感谢你的测试。

2、对于多个U盘的情况，3楼的思路是没有问题，至于具体代码如何写，本帖不予过多讨论。

3、本帖主要是为了获取可移动盘符，以便下面自动实现一些针对可移动磁盘的文件/文件夹操作，6楼的代码只是显示了一下可移动盘符而已，偏离了主题，因此你对6楼的代码的修改，我这里也不做过多评论。

4、为了节约论坛空间，如无特殊需要，能用文字描述清楚的时候还是尽量不要贴图吧。