CrLf

用一个临时变量不行吗

CrLf

目前有另一种思路，利用单个临时变量循环置换，写了个雏形，但还有些问题没想明白

CrLf

回复 6# aa77dd@163.com


是这个思路，例：

'ArrayShift.vbs
Dim arrStr, sInfo

arrStr = Split("0,1,2,3,4,5,6,7,8,9,10,11,12", ",")

sInfo = "原字符串：" & Join(arrStr, ",") & vbCrLf

For i = -20 To 20
	sInfo = sInfo & "偏移+" & i & "：" & Join(ArrayShift(arrStr, i), ",") & vbCrLf
Next

WSH.Echo sInfo

Function ArrayShift(ByVal arrStr, ByVal nShift)
	Dim arr, nLength, i, s1, s, nOffSet, [起始]
	
	nLength = UBound(arrStr) + 1
	nShift = (nShift Mod nLength + nLength) Mod nLength
	
	For [起始] = 0 To [func最大公约数](nLength,nShift) - 1
		i = (([起始] + nShift) Mod (nLength))
		tmpStr = arrStr(i)
		
		Do While i <> [起始]
			nOffSet = ((i + nShift) Mod (nLength))
			arrStr(i) = arrStr(nOffSet)
			i = nOffSet
		Loop
		
		arrStr(nOffSet) = tmpStr
	Next
	
	ArrayShift = arrStr
End Function

Function [func最大公约数](ByVal a,ByVal b)
	Dim c
	
	If b=0 Then a=0
	
	Do While b <> 0
		c = a Mod b
		a = b
		b = c
	Loop
	
	[func最大公约数] = a
End Function
复制代码

代码逻辑：闭环遍历置换，头尾相衔，回到原点时 +1 继续，一直循环到次数不小于元素个数
如此可实现单表无冗余置换，时间复杂度和空间复杂度比较均衡
事实上顶楼是三数组，因为还要算上函数返回值，如果不想设置临时变量，可以直接使用返回值进行映射，省得最后还要传递一次变量
其实我想说的是，楼主还是投奔 JS 党吧...非 VBS 不娶的话，用 wsf 或者 hta 纳个妾也好啊

CrLf

回复 10# aa77dd@163.com


终于想透彻了
顺便省掉了不必要的 [计数]，已修改

------------------------------------------------------------------------------------------
原理解释：

最大公约数是 nLength 和 nShift 都能整除的数字，那么在多轮循环置换后，作用点一定呈相同的栅栏状分布，区别只在于生成的次序：

nShift=2
@1@3@5@7@9

nShift=4
@1@3@5@7@9

nShift=6
@1@3@5@7@9

以回到原点为一周期，那么 周期总数 = 最大公约数
另一方面，最大公约数=1 的时候，“栅栏” 的间隔为 0，所以用一次循环置换就能搞定

CrLf

回复 13# aa77dd@163.com


   
    其实现在想起来，完全不需要求最大公约数，虽然那是理论支柱，但代码只需要实证结果