Batcher

如果文件夹名称都是 20090403 这种格式的日期，可以试试这样：

@echo off
rem 指定FTP用户名
set ftpUser=asx
rem 指定FTP密码
set ftpPass=asx-asx
rem 指定FTP服务器地址
set ftpIP=172.19.103.7
rem 指定待下载的文件位于FTP服务器的什么位置
set ftpFolder=/export/home/PROD/ntcdata
rem 指定从FTP下载下来的文件存放到什么地方
set LocalFolder=E:\Temp
rem 指定下载几天前的文件
set DaysAgo=1

for /f %%i in ('PowerShell -Command "&{Get-Date (Get-Date).AddDays(-%DaysAgo%) -uformat "%%Y%%m%%d"}"') do (
    set "DstDate=%%i"
)

set ftpFolder=%ftpFolder%/%DstDate%
set ftpFile=%temp%\TempFTP.txt
>"%ftpFile%" echo,%ftpUser%
>>"%ftpFile%" echo,%ftpPass%
>>"%ftpFile%" echo cd "%ftpFolder%"
>>"%ftpFile%" echo lcd "%LocalFolder%"
>>"%ftpFile%" echo bin
>>"%ftpFile%" echo mget *.*
>>"%ftpFile%" echo bye
start ftp -v -i -s:"%ftpFile%" %ftpIP%
复制代码

Batcher

那是网络编程实现的
批处理没有这功能

Batcher

你可以参照4楼的方法，在dir命令的返回结果中获取日期信息。
不过，日期信息所在列是不确定的，而且格式也是不同的。
你可以先看看自己连上的FTP服务器后，dir命令的返回结果如何。

Batcher

先把英文月份转换成数字
再计算日期

Batcher

在动手写代码之前，还有一点需要确认，那就是倒数第二列的时间。
大于某个时间（比如6个月之前）的文件，倒数第二列会显示年；小于某个时间（比如6个月之内）的文件，倒数第二列会显示时间。
你需要问问服务器管理员这里是如何设置的。

Batcher

你能确定它们都是2009年？万一有些是2008年咋办？

Batcher

好，你把10楼的结果以文本的形式贴出来，我帮你写代码。
可以用这个ftp命令：
dir * a.txt

Batcher

10楼

Batcher

是生成在本机的命令行解释器当前目录下
我得去看电影了
你先把结果贴出来
如果没有其他人帮你写
我待会回来写

Batcher

@echo off
for /f "tokens=1-9 delims= " %%a in (a.txt) do (
  if /i "%%~xi" equ ".SWM" (
    echo %%i %%f %%g %%h
  ) else if /i "%%~xi" equ ".TWM" (
    echo %%i %%f %%g %%h
  ) else if /i "%%~xi" equ ".XWM" (
    echo %%i %%f %%g %%h
  )
)
pause
复制代码

Batcher

@echo off
rem 指定FTP用户名
set ftpUser=BatHome
rem 指定FTP密码
set ftpPass=Batcher
rem 指定FTP服务器地址
set ftpIP=192.168.0.2

set ftpFile=%temp%\TempAcc.txt
>"%ftpFile%" echo %ftpUser%
>>"%ftpFile%" echo %ftpPass%
>>"%ftpFile%" echo bin
>>"%ftpFile%" echo dir * a.txt
>>"%ftpFile%" echo bye
start ftp -v -i -s:"%ftpFile%" %ftpIP%
复制代码

Batcher

@echo off
rem 指定FTP用户名
set ftpUser=USERNAME
rem 指定FTP密码
set ftpPass=PASSWORD
rem 指定FTP服务器地址
set ftpIP=192.168.0.2
set ftpFile=%temp%\TempAcc.txt

>"%ftpFile%" echo.%ftpUser%
>>"%ftpFile%" echo.%ftpPass%
>>"%ftpFile%" echo bin
>>"%ftpFile%" echo dir * C:\BatHome.txt
>>"%ftpFile%" echo bye
start ftp -v -i -s:"%ftpFile%" %ftpIP%

rem 根据实际情况自行调节延迟时间
ping -n 10 127.1 >nul

for /f "tokens=1-9 delims= " %%a in (C:\BatHome.txt) do (
  if /i "%%~xi" equ ".SWM" (
    echo.%%i %%f %%g %%h
  ) else if /i "%%~xi" equ ".TWM" (
    echo.%%i %%f %%g %%h
  ) else if /i "%%~xi" equ ".XWM" (
    echo.%%i %%f %%g %%h
  )
)
pause
复制代码

Batcher

如果不对文件日期信息进行任何比较操作，那还绕个圈干吗？直接mget就行。

mget *.SWM
mget *.TWM
mget *.XWM
复制代码

Batcher

@echo off
rem 指定FTP用户名
set ftpUser=USERNAME
rem 指定FTP密码
set ftpPass=PASSWORD
rem 指定FTP服务器地址
set ftpIP=192.168.0.2
rem 指定待下载的文件位于FTP服务器的什么位置
set ftpFolder=\export\home\PROD\ntcdata\
rem 指定下载几天前的文件
set DaysAgo=1
set ftpDir=%temp%\TempDir.txt
set ftpDown=%temp%\TempDown.txt

rem 假设本机日期格式为yyyy-mm-dd
set FileY=%date:~0,4%
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=DaysAgo
call :DaysToDate %PassDays% DstYear DstMonth DstDay

>"%ftpDir%" echo.%ftpUser%
>>"%ftpDir%" echo.%ftpPass%
>>"%ftpDir%" echo bin
>>"%ftpDir%" echo cd "%ftpFolder%"
>>"%ftpDir%" echo dir * "%temp%\FileList.txt"
>>"%ftpDir%" echo bye
start ftp -v -i -s:"%ftpDir%" %ftpIP%

rem 根据实际情况自行调节延迟时间
ping -n 10 127.1 >nul

findstr /i ":*\.SWM$" "%temp%\FileList.txt">"%temp%\FileDate.txt"
findstr /i ":*\.TWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"
findstr /i ":*\.XWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"

>"%ftpDown%" echo.%ftpUser%
>>"%ftpDown%" echo.%ftpPass%
>>"%ftpDown%" echo bin
>>"%ftpDown%" echo cd "%ftpFolder%"
(for /f "usebackq tokens=1-9 delims= " %%a in ("%temp%\FileDate.txt") do (
  setlocal enabledelayedexpansion
  if "%%f" equ "Jan" (
    set FileM=01
  ) else if "%%f" equ "Feb" (
    set FileM=02
  ) else if "%%f" equ "Mar" (
    set FileM=03
  ) else if "%%f" equ "Apr" (
    set FileM=04
  ) else if "%%f" equ "May" (
    set FileM=05
  ) else if "%%f" equ "Jun" (
    set FileM=06
  ) else if "%%f" equ "Jul" (
    set FileM=07
  ) else if "%%f" equ "Aug" (
    set FileM=08
  ) else if "%%f" equ "Sep" (
    set FileM=09
  ) else if "%%f" equ "Oct" (
    set FileM=10
  ) else if "%%f" equ "Nov" (
    set FileM=11
  ) else if "%%f" equ "Dec" (
    set FileM=12
  )
  set FileD=10%%g
  set FileD=!FileD:~-2!
  if "!FileM!" equ "%DstMonth%" (
    if "!FileD!" equ "%DstDay%" (
      echo get "%%i"
    )
  )
  endlocal
))>>"%ftpDown%"
>>"%ftpDown%" echo bye
start ftp -v -i -s:"%ftpDown%" %ftpIP%
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码

[ 本帖最后由 Batcher 于 2009-4-7 22:50 编辑 ]

Batcher

仅凭一句“获取文件不成功”，我无法给你更多的帮助。