[已解决]批处理如何获取FTP上面下载1天前的文件？ - BAT求助&讨论 - 批处理之家 BAT,CMD,批处理,PowerShell,VBS,DOS

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

16楼 跳转到 »

发表于 2009-4-8 11:34 | 显示全部帖子

回复 34楼的帖子

能指定路径

@echo off
rem 指定FTP用户名
set ftpUser=USERNAME
rem 指定FTP密码
set ftpPass=PASSWORD
rem 指定FTP服务器地址
set ftpIP=192.168.0.2
rem 指定待下载的文件位于FTP服务器的什么位置
set ftpFolder=\export\home\PROD\ntcdata
rem 指定从FTP下载下来的文件存放到什么地方
set DownFolder=C:\temp
rem 指定下载几天前的文件
set DaysAgo=1
set ftpDir=%temp%\TempDir.txt
set ftpDown=%temp%\TempDown.txt

rem 假设本机日期格式为yyyy-mm-dd
set FileY=%date:~0,4%
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=DaysAgo
call :DaysToDate %PassDays% DstYear DstMonth DstDay

>"%ftpDir%" echo.%ftpUser%
>>"%ftpDir%" echo.%ftpPass%
>>"%ftpDir%" echo bin
>>"%ftpDir%" echo cd "%ftpFolder%"
>>"%ftpDir%" echo dir * "%temp%\FileList.txt"
>>"%ftpDir%" echo bye
start ftp -v -i -s:"%ftpDir%" %ftpIP%

rem 根据实际情况自行调节延迟时间
ping -n 10 127.1 >nul

findstr /i ":*\.SWM$" "%temp%\FileList.txt">"%temp%\FileDate.txt"
findstr /i ":*\.TWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"
findstr /i ":*\.XWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"

>"%ftpDown%" echo.%ftpUser%
>>"%ftpDown%" echo.%ftpPass%
>>"%ftpDown%" echo bin
>>"%ftpDown%" echo cd "%ftpFolder%"
(for /f "usebackq tokens=1-9 delims= " %%a in ("%temp%\FileDate.txt") do (
  setlocal enabledelayedexpansion
  if "%%f" equ "Jan" (
    set FileM=01
  ) else if "%%f" equ "Feb" (
    set FileM=02
  ) else if "%%f" equ "Mar" (
    set FileM=03
  ) else if "%%f" equ "Apr" (
    set FileM=04
  ) else if "%%f" equ "May" (
    set FileM=05
  ) else if "%%f" equ "Jun" (
    set FileM=06
  ) else if "%%f" equ "Jul" (
    set FileM=07
  ) else if "%%f" equ "Aug" (
    set FileM=08
  ) else if "%%f" equ "Sep" (
    set FileM=09
  ) else if "%%f" equ "Oct" (
    set FileM=10
  ) else if "%%f" equ "Nov" (
    set FileM=11
  ) else if "%%f" equ "Dec" (
    set FileM=12
  )
  set FileD=10%%g
  set FileD=!FileD:~-2!
  if "!FileM!" equ "%DstMonth%" (
    if "!FileD!" equ "%DstDay%" (
      echo get "%%i" "%DownFolder%\%%i"
    )
  )
  endlocal
))>>"%ftpDown%"
>>"%ftpDown%" echo bye
start ftp -v -i -s:"%ftpDown%" %ftpIP%
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

17楼

发表于 2009-4-8 12:01 | 显示全部帖子

回复 36楼的帖子

可以，随便设吧。

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

18楼

发表于 2009-4-8 13:26 | 显示全部帖子

回复 38楼的帖子

是的，设置临时文件。
用来在后面的ftp命令中实现“自动”下载。

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

19楼

发表于 2009-4-8 14:50 | 显示全部帖子

回复 40楼的帖子

1、检查"%temp%\FileList.txt"文件内容是否正确
2、set DaysAgo=1，只下载昨天的问题，检查FTP服务器上指定目录下是否有昨天的文件
3、学学怎么调试代码吧：
不要双击运行
把代码保存为C:\test.bat
把@echo off删除
在合适的地方加上pause
开始
运行
cmd
C:\test.bat
看看执行过程再好好想想到底是哪里出问题了

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

20楼

发表于 2009-4-8 16:43 | 显示全部帖子

回复 42楼的帖子

set ftpFolder=\export\home\PROD\ntcdata
>>"%ftpDir%" echo cd "%ftpFolder%"
>>"%ftpDir%" echo dir * "%temp%\FileList.txt"
自己试着改改这三句

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

21楼

发表于 2009-4-8 17:30 | 显示全部帖子

回复 44楼的帖子

你定义ftpFolder的时候咋写的？注意别把路径中的斜线和反斜线搞混淆了。

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

22楼

发表于 2009-4-8 17:37 | 显示全部帖子

回复 46楼的帖子

windows的路径是\
*nix的路径是/

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

23楼

发表于 2009-4-9 09:42 | 显示全部帖子

回复 48楼的帖子

%temp%\TempDown.txt
内容如何？

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

24楼

发表于 2009-4-9 09:52 | 显示全部帖子

"%temp%\FileDate.txt"
这个呢？

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

25楼

发表于 2009-4-9 10:13 | 显示全部帖子

回复 52楼的帖子

把代码保存为C:\test.bat
把@echo off删除
开始
运行
cmd
C:\test.bat
把完整的执行过程贴出来看看（尤其是生成"%temp%\FileDate.txt"那部分）

Q: 怎样把CMD窗口里的结果复制出来？
A: 右键单击CMD窗口的标题栏->"属性"->"选项"->勾选"快速编辑模式"->然后在CMD窗口用鼠标左键选中想要拷贝的内容->在选中的内容上单击鼠标右键->粘贴到文本文件中即可

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

26楼

发表于 2009-4-9 10:43 | 显示全部帖子

回复 54楼的帖子

"E:\DOCUME~1\eetc\LOCALS~1\Temp\FileList.txt"
内容贴出来看看

还有，你手工执行一下findstr命令，看看为什么"E:\DOCUME~1\eetc\LOCALS~1\Temp\FileDate.txt"内容为空。

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

27楼

发表于 2009-4-9 10:50 | 显示全部帖子

回复 55楼的帖子

FileList.txt中有1万多行数据，有可能是延迟不够。
你试试把延迟中的10改成20、30、40、50等，直到找到一个合适的延迟时间。

rem 根据实际情况自行调节延迟时间
ping -n 10 127.1 >nul

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

28楼

发表于 2009-4-9 11:52 | 显示全部帖子

回复 60楼的帖子

仔细看看35楼的代码：
echo get "%%i" "%DownFolder%\%%i"

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

29楼

发表于 2009-4-9 13:09 | 显示全部帖子

回复 62楼的帖子

你把现在最新的完整代码贴出来，我帮你加上这个功能。

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

30楼

发表于 2009-4-9 13:57 | 显示全部帖子

回复 64楼的帖子

两个思路：
1、先从FTP上面下载到一个文件夹中，下载完之后用xcopy复制到另一个文件夹。难点在于不容易判断下载操作什么时候能够完成。
2、从FTP上面下载两次。缺点在于下载时间会延长，会增加服务器的负担。代码如下：

@echo off
rem 指定FTP用户名
set ftpUser=asx
rem 指定FTP密码
set ftpPass=asx-asx
rem 指定FTP服务器地址
set ftpIP=172.19.103.7
rem 指定待下载的文件位于FTP服务器的什么位置
set ftpFolder=/export/home/PROD/ntcdata
rem 指定从FTP下载下来的文件存放到什么地方
set DownFolder=E:\Temp
set DownFolder2=E:\Temp2
rem 指定下载几天前的文件
set DaysAgo=1
set ftpDir=%temp%\TempDir.txt
set ftpDown=%temp%\TempDown.txt

rem 假设本机日期格式为yyyy-mm-dd
set FileY=%date:~0,4%
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=DaysAgo
call :DaysToDate %PassDays% DstYear DstMonth DstDay

>"%ftpDir%" echo.%ftpUser%
>>"%ftpDir%" echo.%ftpPass%
>>"%ftpDir%" echo bin
>>"%ftpDir%" echo cd "%ftpFolder%"
>>"%ftpDir%" echo dir * "%temp%\FileList.txt"
>>"%ftpDir%" echo bye
start ftp -v -i -s:"%ftpDir%" %ftpIP%

rem 根据实际情况自行调节延迟时间
ping -n 200 127.1 >nul

findstr /i ":*\.SWM$" "%temp%\FileList.txt">"%temp%\FileDate.txt"
findstr /i ":*\.TWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"
findstr /i ":*\.OWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"

>"%ftpDown%" echo.%ftpUser%
>>"%ftpDown%" echo.%ftpPass%
>>"%ftpDown%" echo bin
>>"%ftpDown%" echo cd "%ftpFolder%"
(for /f "usebackq tokens=1-9 delims= " %%a in ("%temp%\FileDate.txt") do (
  setlocal enabledelayedexpansion
  if "%%f" equ "Jan" (
    set FileM=01
  ) else if "%%f" equ "Feb" (
    set FileM=02
  ) else if "%%f" equ "Mar" (
    set FileM=03
  ) else if "%%f" equ "Apr" (
    set FileM=04
  ) else if "%%f" equ "May" (
    set FileM=05
  ) else if "%%f" equ "Jun" (
    set FileM=06
  ) else if "%%f" equ "Jul" (
    set FileM=07
  ) else if "%%f" equ "Aug" (
    set FileM=08
  ) else if "%%f" equ "Sep" (
    set FileM=09
  ) else if "%%f" equ "Oct" (
    set FileM=10
  ) else if "%%f" equ "Nov" (
    set FileM=11
  ) else if "%%f" equ "Dec" (
    set FileM=12
  )
  set FileD=10%%g
  set FileD=!FileD:~-2!
  if "!FileM!" equ "%DstMonth%" (
    if "!FileD!" equ "%DstDay%" (
     echo get "%%i" "%DownFolder%\%%i"
     echo get "%%i" "%DownFolder2%\%%i"
    )
  )
  endlocal
))>>"%ftpDown%"
>>"%ftpDown%" echo bye
start ftp -v -i -s:"%ftpDown%" %ftpIP%
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码