taofan712

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b /ad') do (
    set "fn=%%~a"
    set "fnw=!fn!"
    for /f "tokens=1-5 delims=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ.- " %%1 in ("%%~a") do (
        if not "%%1%%2%%3%%4%%5"=="%%~a" (
            call :change %%1 %%2 %%3 %%4 %%5 
        ) else (
            ren "!fn!" chunhanzi 2>nul || ren "!fn!" chunhanzi_1
        )
    )
)
echo;处理完毕&pause>nul&exit /b

:change
for %%b in (%1 %2 %3 %4 %5) do set "fnw=!fnw:%%b=!"
set "fnw=!fnw: =!"
ren "!fn!" "!fnw!" 2>nul ||ren "!fn!" "!fnw!_1"
goto :eof
复制代码

原以为不会太难，没想到在写的时候发现特殊情况会有很多，所以代码不是很完美。见谅。

taofan712

回复 3# 老刘1号
文件名设想成这种情况：

汉123字
汉字a2
汉2字汉  3字3
—  aa汉#字
汉字
123字
a  2字

taofan712

回复 7# 172043209


    在第六行，abcd那里，找个位置加上小数点就行。


但在以下情况会出现其他问题：
文件名本身就不含有汉字的文件夹数量在2个以上。
除汉字以外剩余的字母数字部分相同的文件夹数量在2个以上。
其他

taofan712

回复 11# 172043209


    第三行，dir /b /ad改为dir /b /ad /s

taofan712

回复 16# 172043209

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b /ad /s') do (
    set "fn=%%~nxa"
    set "fnw=%%~nxa"
    for /f "tokens=1-5 delims=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ.- " %%1 in ("%%~nxa") do (
        if not "%%1%%2%%3%%4%%5"=="%%~a" (
            call :change %%1 %%2 %%3 %%4 %%5 
        ) else (
            ren "!fn!" chunhanzi 2>nul || ren "!fn!" chunhanzi_1
        )
    )
)
echo;处理完毕&pause>nul&exit /b

:change
for %%b in (%1 %2 %3 %4 %5) do set "fnw=!fnw:%%b=!"
set "fnw=!fnw: =!"
ren "!fn!" "!fnw!" 2>nul ||ren "!fn!" "!fnw!_1"
goto :eof
复制代码

taofan712

@echo off
setlocal enabledelayedexpansion
echo;请将需要处理的文件夹拖放进本窗口
set /p folder=
for /f "delims=" %%i in ('dir /ad /s /b %folder%') do set/a n+=1&&set .!n!=%%~fi
(for /l %%n in (!n!,-1,1) do if defined .%%n echo;!.%%n!)>tmp.x
for /f "delims=" %%a in (tmp.x) do (
    cd /d "%%~fa"\..
    set "fn=%%~nxa"
    set "fnw=%%~nxa"
    for /f "tokens=1-5 delims=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ-." %%1 in ("%%~nxa") do (
        if not "%%1%%2%%3%%4%%5"=="%%~nxa" (
            call :change "%%1" "%%2" "%%3" "%%4" "%%5" 
        ) else (
            call :chun
        )
    )
)
cd /d "%~dp0"&del /f /q tmp.x
echo;处理完毕&pause>nul&exit /b

:change
for %%b in (%~1 %~2 %~3 %~4 %~5) do set "fnw=!fnw:%%b=!"
set "fnw=!fnw: =!"
set /a m=1
if exist !fnw! (
    :judge
    if exist !fnw!_!m! (  
        set /a m+=1
        goto judge
    )
ren "!fn!" "!fnw!_!m!" 
goto :eof
)
ren "!fn!" "!fnw!"
goto :eof

:chun
set /a m=1
if exist chunhanzi (
    :panduan
    if exist chunhanzi_!m! (
        set /a m+=1
        goto panduan
    )
ren "!fn!" chunhanzi_!m!
goto :eof
)
ren "!fn!" chunhanzi
goto :eof
复制代码