xczxczxcz

把注册表文件等拖入双击运行后的窗口中。

@echo off
cd/d "%~dp0"
setlocal EnableDelayedExpansion
echo 把注册表文件拖到窗口中
set /p var=
for /f "delims=" %%a in ('type %var%') do (
	set "str=%%a"
	if "!str:~0,1!"=="[" echo;>>NewReg.reg
	SET "str=!str:HKEY_LOCAL_MACHINE\SYSTEM=HKEY_LOCAL_MACHINE\PE-SYS!"
	SET "str=!str:HKEY_LOCAL_MACHINE\SOFTWARE=HKEY_LOCAL_MACHINE\PE-SOF!"
	SET "str=!str:HKEY_USERS\.DEFAULT=HKEY_LOCAL_MACHINE\PE-DEF!"
	SET "str=!str:HKEY_CLASSES_ROOT\Directory=HKEY_LOCAL_MACHINE\PE-SOF\Classes\Directory!"
	set "str=!str:HKEY_CURRENT_USER\SOFTWARE=HKEY_LOCAL_MACHINE\PE-DEF\SOFTWARE!"
	ECHO !str!>>NewReg.reg
)
echo 按任意键导入注册表 & pause >nul & regedit /s NewReg.reg
pause & exit
复制代码

============================

xczxczxcz

回复 7# wchong

参考 http://www.bathome.net/thread-49107-1-1.html
在批的@echo off 的末尾回车再加上

>nul 2>&1 "%windir%\system32\cacls.exe" "%windir%\system32\config\system" 
if '%errorlevel%' NEQ '0' (  echo UAC... & goto UACPrompt ) else goto gotAdmin
:UACPrompt 
 echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs" 
 echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs" 
 "%temp%\getadmin.vbs" 
 exit /B 
:gotAdmin 
 if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
复制代码

其它的批也加上。
win7 + 的系统都可以用。