yhcfsr

@echo off

for /f "tokens=1,2,3 delims=={,}" %%a in ('wmic NICCONFIG where "IPEnabled='TRUE'" get DefaultIPGateway^,DNSServerSearchOrder^,IPAddress^,IPSubnet /value^|findstr "={"') do (
	if "%%a"=="DefaultIPGateway" (set "Gate=%%~b"
	) else if "%%a"=="DNSServerSearchOrder" (set "DSN1=%%~b"&set "DSN2=%%~c"
	) else if "%%a"=="IPAddress" (set "IP=%%~b"
	) else if "%%a"=="IPSubnet" (set "Mask=%%~b")
	if defined Gate if defined Mask goto :show	
)
:show
	echo;I P 地址:	%IP%
	echo;子网掩码:	%Mask%
	echo;默认网关:	%Gate%
	echo;首选 DNS:	%DSN1%
	echo;备用 DNS:	%DSN2%
pause
复制代码

yhcfsr

回复 11# 窄口牛

@echo off

for /f "tokens=1,2,3 delims=={,}" %%a in ('wmic NICCONFIG where "IPEnabled='TRUE'" get Description^,MacAddress^,ServiceName^,DefaultIPGateway^,DNSServerSearchOrder^,IPAddress^,IPSubnet /value^|findstr "="') do (
	if "%%a"=="Description"	(set "Name=%%~b"
	) else if "%%a"=="DefaultIPGateway" (set "Gate=%%~b"
	) else if "%%a"=="DNSServerSearchOrder" (set "DSN1=%%~b"&set "DSN2=%%~c"
	) else if "%%a"=="IPAddress" (set "IP=%%~b"
	) else if "%%a"=="IPSubnet" (set "Mask=%%~b"
	) else if "%%a"=="MACAddress" (set "MAC=%%~b"
	) else if "%%a"=="ServiceName" (set "Chip=%%~b")
	if defined Gate if defined Chip goto :show

)

:show
	echo;网卡名称:	%Name%
	echo;MAC 地址:	%MAC%
	echo;网卡芯片:	%Chip%
	echo;I P 地址:	%IP%
	echo;子网掩码:	%Mask%
	echo;默认网关:	%Gate%
	echo;首选 DNS:	%DSN1%
	echo;备用 DNS:	%DSN2%
pause
复制代码