[网络连接] [新人求助]一键设定IP如何写批处理代码？

chming

我在网上找到这样的一段代码：

 
@echo off
cls

:ipw
cls
echo. IP:
set /p IP=   请输入 IP:
echo. 掩码：
set /p MASK=    请输入 掩码：
echo.  网关：
set /p GATEWAY=  请输入 网关：
echo.
echo        开始设置IP、掩码、网关地址
netsh interface ip set address "本地连接" static %IP% %Mask% %GATEWAY% 1
echo.    设置完成，任意键其他操作。
pause>nul
goto ipw
复制代码

这个是手动设置，我要的用的两个不同的IP段，但用1台电脑来设置设备，这样手动就很麻烦和费时间了

我想要的功能是能够一键设定指定IP，下面我做了功能选项，希望高手帮我编写功能代码，谢谢

 
@echo off
cls
:start
cls
echo.
echo.     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo.     ┋  ─────────────────────────  ┋
echo.     ┋    【A】IP:192.168.1.10      【B】IP:10.192.16.10    ┋
echo.     ┋  ─────────────────────────  ┋
echo.     ┋  ─────────────────────────  ┋
echo.     ┋    【C】查看IP设置           【Z】退出程序           ┋
echo.     ┋  ─────────────────────────  ┋
echo.     ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
set choice=
set /p choice=              请输入选项（Enter确认）:
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
if /i "%choice%"=="A" goto ipw1
if /i "%choice%"=="B" goto ipw2
if /i "%choice%"=="C" goto ck
if /i "%choice%"=="Z" goto end
复制代码

ipw1实现一键设置成IP：192.168.1.10，掩码：255.255.255.0，网关：192.168.1.1
ipw2实现一键设置成IP：10.192.16.10，掩码：255.255.255.0，网关：10.192.16.10

谢谢帮忙

chming

顺便再问下，要想设置能自动获取IP，代码又如何写？再次感谢

switchling

@echo off
cls
:start
cls
echo.
echo.     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo.     ┋  ─────────────────────────  ┋
echo.     ┋    【A】IP:192.168.1.10      【B】IP:10.192.16.10    ┋
echo.     ┋  ─────────────────────────  ┋
echo.     ┋  ─────────────────────────  ┋
echo.     ┋                【D】设置自动获取IP                          ┋
echo.     ┋  ─────────────────────────  ┋
echo.     ┋    【C】查看IP设置           【Z】退出程序           ┋
echo.     ┋  ─────────────────────────  ┋
echo.     ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
set choice=
set /p choice=              请输入选项（Enter确认）:
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
if /i "%choice%"=="A" goto ipw1
if /i "%choice%"=="B" goto ipw2
if /i "%choice%"=="C" goto ck
if /i "%choice%"=="Z" goto end
if /i "%choice%"=="D" goto dhcp

:ipw1
netsh interface ip set address "本地连接" static 192.168.1.10 255.255.255.0 192.168.1.1 1
echo.
echo.    设置完成，任意键其他操作。
pause >nul
goto start

:ipw2
netsh interface ip set address "本地连接" static 10.192.16.10 255.255.255.0 10.192.16.10 1
echo.
echo.    设置完成，任意键其他操作。
pause >nul
goto start

:ck
@ipconfig /all
pause >nul
goto start

:dhcp
netsh interface ip set address "本地连接"  dhcp >nul
echo.
echo.    设置完成，任意键其他操作。
pause >nul
goto start

:end
exit



你看这个成吗？

chming

自己顶起，寻求帮助，希望能见到大侠，呵呵

keen

你觉得三楼的代码不行吗？你有没有试用一下3楼的代码？