went

@echo off
REM exe folder
set "dir=C:\Users\lenovo\Desktop\0"
REM mklink
for /r "%dir%" %%i in ("*.exe") do mklink "%userprofile%\desktop\%%~ni" "%%~i"
pause&exit
复制代码

went

回复 3# 大地


    你要说明你的A文件夹根据什么特征去搜索,整个硬盘又不是只有一个A文件夹
    或者你搜索到A文件夹然后吧楼上的dir修改为你的A文件夹路径

went

回复 5# 大地


    你就只给一个文件夹名怎么去定位?
    搜索到多个同名文件夹怎么确定那个是你需要的

went

回复 7# 大地

drivers最好别添加系统盘符,不然查找起来很慢

@echo off
REM search drivers
set "drivers=D E F G H I J K L M N O P Q R S T U V W X Y Z"
REM exe foldername
set "folderName=TOOLS1112222"
REM start
for %%i in (%drivers%) do (
	cd /d "%%i:\" 2>nul && (
		echo search %%i: please wait...
		for /r /d %%a in ("*") do (
			if "%%~na" equ "%folderName%" (
				set "folder=%%~a"
				goto :done
			)
		)
	)
)
:done
if "%folder%"=="" echo %folderName% not found! & pause&exit
echo -------------
echo "folder=%folder%"
echo -------------
for /r "%folder%" %%i in ("*.exe") do (
	echo mklink: %%~i
	call set "exe=%%~i"
	call set "tag=%USERPROFILE%\desktop\%folderName%%%exe:%folder%=%%"
	call mkdir %%tag:%%~nxi=%% >nul 2>nul
	call mklink "%%tag:~0,-4%%" "%%~i" >nul
)
pause&exit
复制代码

went

回复 10# 大地

手机写未测试
第六行下面插入一行

for %%i in (%drivers%) do if exist "%%i:\%folderName%" set "folder=%%i:\%folderName%" && goto :done
复制代码

went

权限问题

@echo off
REM Admin
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","REM",,"runas",1)(window.close)&exit
REM search drivers
set "drivers=C D E F G H I J K L M N O P Q R S T U V W X Y Z"
REM exe foldername
set "exeFolderName=TOOLS1112222"
REM main foldername
set "linkFolderName=C:\ProgramData"
REM start
for %%i in (%drivers%) do if exist "%%i:\" ( 
	set /p="check:%%i:\%exeFolderName%   "<nul 
	if exist "%%i:\%exeFolderName%" (
		echo OK!
		set "folder=%%i:\%exeFolderName%" 
		goto :done
	) else echo not found!
)
echo -------------
for %%i in (%drivers%) do (
	cd /d "%%i:\" 2>nul && (
		echo search %%i: please wait...
		for /r /d %%a in ("*") do (
			if "%%~na" equ "%exeFolderName%" (
				set "folder=%%~a"
				goto :done
			)
		)
	)
)
:done
if "%folder%"=="" echo %exeFolderName% not found! & pause&exit
echo -------------
echo "folder=%folder%"
echo -------------
for /r "%folder%" %%i in ("*.exe") do (
	echo mklink: %%~i
	call set "exe=%%~i"
	call set "link=%linkFolderName%\%exeFolderName%\%%exe:%folder%\=%%"
	call mkdir "%%link:%%~nxi=%%" >nul 2>nul
	call mklink "%%link:~0,-4%%" "%%~i" >nul
)
pause&exit
复制代码

went

文件夹按照9-10行的格式添加
set "linkFolderName序号=路径"

@echo off
REM Admin
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","REM",,"runas",1)(window.close)&exit
REM search drivers
set "drivers=C D E F G H I J K L M N O P Q R S T U V W X Y Z"
REM exe foldername
set "exeFolderName=TOOLS1112222"
REM main foldername
set "linkFolderName1=C:\Users\lenovo\Desktop\1"
set "linkFolderName2=C:\Users\lenovo\Desktop\2"
REM start
for %%i in (%drivers%) do if exist "%%i:\" ( 
	set /p="check:%%i:\%exeFolderName%   "<nul 
	if exist "%%i:\%exeFolderName%" (
		echo OK!
		set "folder=%%i:\%exeFolderName%" 
		goto :done
	) else echo not found!
)
echo -------------
for %%i in (%drivers%) do (
	cd /d "%%i:\" 2>nul && (
		echo search %%i: please wait...
		for /r /d %%a in ("*") do (
			if "%%~na" equ "%exeFolderName%" (
				set "folder=%%~a"
				goto :done
			)
		)
	)
)
:done
if "%folder%"=="" echo %exeFolderName% not found! & pause&exit
echo -------------
echo "folder=%folder%"
echo -------------
for /r "%folder%" %%i in ("*.exe") do (
	echo mklink: %%~i
	call set "exe=%%~i"
	for /f "tokens=2 delims==" %%a in ('set linkFolderName') do (
		call set "link=%%a\%exeFolderName%\%%exe:%folder%\=%%"
		call mkdir "%%link:%%~nxi=%%" >nul 2>nul
		call mklink "%%link:~0,-4%%" "%%~i" >nul
	)
)
pause&exit
复制代码

went

回复 18# 大地
16楼代码
10行下面加上以下代码,这是特殊exe的相对路径,?分隔

REM esp exe
set "espExe=\分区工具\DG.exe?\截图工具\nap.exe?\其它\QQ.exe?\新建文件夹\handle64.exe?\新建文件夹\CPU-V.exe"
复制代码

39行下面加上以下代码

call echo %espExe% | call findstr /i /C:"%%exe:%folder%\=%%" >nul 2>nul && (
		call echo add %userprofile%\desktop
		mklink "%userprofile%\desktop\%%~ni" "%%~i" >nul
	)
复制代码

ANSI保存

went

回复 20# 大地


    ANSI编码

went

ANSI保存,再不行我也没招了

@echo off
REM Admin
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","REM",,"runas",1)(window.close)&exit
REM search drivers
set "drivers=C D E F G H I J K L M N O P Q R S T U V W X Y Z"
REM exe foldername
set "exeFolderName=TOOLS1112222"
REM main foldername
set "linkFolderName1=C:\Users\lenovo\Desktop\1"
set "linkFolderName2=C:\Users\lenovo\Desktop\2"
REM esp exe
set "espExe=\分区工具\DG.exe?\截图工具\nap.exe?\其它\QQ.exe"
REM start
for %%i in (%drivers%) do if exist "%%i:\" ( 
	set /p="check:%%i:\%exeFolderName%   "<nul 
	if exist "%%i:\%exeFolderName%" (
		echo OK!
		set "folder=%%i:\%exeFolderName%" 
		goto :done
	) else echo not found!
)
echo -------------
for %%i in (%drivers%) do (
	cd /d "%%i:\" 2>nul && (
		echo search %%i: please wait...
		for /r /d %%a in ("*") do (
			if "%%~na" equ "%exeFolderName%" (
				set "folder=%%~a"
				goto :done
			)
		)
	)
)
:done
if "%folder%"=="" echo %exeFolderName% not found! & pause&exit
echo -------------
echo "folder=%folder%"
echo -------------
for /r "%folder%" %%i in ("*.exe") do (
	echo mklink: %%~i
	call set "exe=%%~i"
	call echo %espExe% | call findstr /i /C:"%%exe:%folder%\=%%" >nul 2>nul && (
		call echo add %userprofile%\desktop
		mklink "%userprofile%\desktop\%%~ni" "%%~i" >nul
	)
	for /f "tokens=2 delims==" %%a in ('set linkFolderName') do (
		call set "link=%%a\%exeFolderName%\%%exe:%folder%\=%%"
		call mkdir "%%link:%%~nxi=%%" >nul 2>nul
		call mklink "%%link:~0,-4%%" "%%~i" >nul
	)
)
pause&exit
复制代码

went

回复 24# 大地

这是第三方工具,具体没用过