[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

[文件操作] [已解决]BAT批量去掉文件名中的括号和括号里的内容

本帖最后由 liziyunabcd 于 2020-5-19 22:31 编辑

文件夹里有很多个DOC文件。
文件名如下:
我是一个小白1(我是小白三42342号fwsffq)
我是一个小白2(我是小白三2342号erqrqer)
我是一个小白3(我是小白三rqr2号rfdsh)
我是一个小白4(我是小白三req号rweqrq)

请教大神:如何批量把括号里的内容和括号一起删除。
1

评分人数

    • Batcher: 感谢给帖子标题标注[已解决]字样PB + 2

本帖最后由 netdzb 于 2020-5-8 17:46 编辑

ren 我是一个小白?(*).doc 我是一个小白?.doc
这样可以吗?

TOP

得用这个工具,放入C:\Windows\System32
或者放入需要处理的DOC或DOCX文件夹里面
http://bcn.bathome.net/tool/ren2.exe
  1. @echo off
  2. @for /f "delims=" %%i in ('dir /b *.DOC *.DOCX') do (
  3. ren2 -f "(.*)\(.*\).*%%~xi" "$1%%~xi"
  4. )
  5. pause
复制代码
1

评分人数

TOP

  1. for /f "tokens=1* delims=(" %%i in ('dir /b "*(*).doc"') do rename "%%i(%%j" "%%i.doc"
复制代码
1

评分人数

TOP

回复 3# xp3000 感谢大佬,完全可行!!谢谢技术大佬

TOP

回复 4# went


    完美!!!谢谢大神!!!
太完美了!!

TOP

回复 4# went

改造一下,这样是否可以去除文件名任意位置的括号?
  1. for /f "tokens=1,2* delims=()" %%i in ('dir /b "*.doc"') do ren "%%i(%%j)%%k" "%%i%%k"
复制代码

TOP

括号在最前面好像也不行。

TOP

回复 8# qixiaobin0715

任意位置
  1. @echo off
  2. for /f "tokens=1* delims=(" %%i in ('dir /b "*(*)*.txt"') do (
  3. if "%%j"=="" ( set "a=%%i" & set "pre=" ) else ( set "a=%%j" & set "pre=%%i" )
  4. call set "txt=%%pre%%(%%a%%"
  5. call set "a=%%a:*)=%%"
  6. call echo rename "%%txt%%" "%%pre%%%%a%%"
  7. call rename "%%txt%%" "%%pre%%%%a%%"
  8. echo -----
  9. )
  10. pause&exit
复制代码

TOP

回复 9# went

很好用!!!

TOP

回复 1# liziyunabcd
  1. @echo off
  2. setlocal enabledelayedexpansion
  3. cd /d "%~dp0"
  4. for /f "delims=" %%i in ('dir /b /a-d "*(*)*.doc"') do (
  5.     set "str=%%~nxi"
  6.     set "str1=!str:(= (!"
  7.     set "str1=!str1:)=) !"
  8.     for %%j in (!str1!) do (
  9.         set "str2=%%j"
  10.         if "!str2:~,1!"=="(" (
  11.             set "str=!str:%%j=!"
  12.         )
  13.     )
  14.     ren "%%i" "!str!"
  15. )
复制代码
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

  1. @echo off
  2. setlocal enabledelayedexpansion
  3. cd /d "%~dp0"
  4. for /f "tokens=1* delims=(" %%i in ('dir /b /a-d "*(*)*.doc"') do (
  5. if "%%j"=="" (
  6.         set "FileRight=%%i"
  7.         set "FileLeft="
  8.     ) else (
  9.         set "FileRight=%%j"
  10.         set "FileLeft=%%i"
  11.     )
  12.     set "OldName=!FileLeft!(!FileRight!"
  13.     set "FileRight=!FileRight:*)=!"
  14.     set "NewName=!FileLeft!!FileRight!"
  15.     ren "!OldName!" "!NewName!"
  16. )
复制代码
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

返回列表