77七

因为安卓手机应用读取剪贴板，可能导致隐私泄露；应用内震动无法从应用内或者系统设置中关闭，特搜集了相关adb命令代码（代码比较基础，就不贴出处了），写成批处理自用，在此借楼分享一下给需要的朋友
本代码只写了 剪贴板、震动，可以自己尝试输入其它项目。因本人水平十分有限，疏忽、错误难免，代码仅供参考。

@echo off
rem 批处理保存为ansi编码格式
:1
adb devices |findstr /rec:"device" 1>nul
if errorlevel 1 (
        echo 请确保手机已经打开[允许USB调试] 并连接到电脑，按【回车键】再次尝试
        pause
        goto :1
) else (
        echo 连接成功！
)
echo=
echo 说明：
echo  1.项目举例，剪贴板【READ_CLIPBOARD】震动【VIBRATE】
echo  2.允许【allow】禁止【ignore】
echo  3.均区分大小写
echo=
setlocal
set /p c1=输入项目，如需要管理剪贴板权限，则输入READ_CLIPBOARD:
set /p c2=输入操作，如需要禁止权限，则输入ignore:

if "%c2%" equ "allow" (
        set c3=ignore
) else (
        set c3=allow
)

setlocal enabledelayedexpansion
call :2 "%c1%" "%c2%" "%c3%"
endlocal
endlocal
goto :1

        :2
        echo=
        echo 当前 "%~3" 权限app
        echo=
        for /f "delims=" %%a in ('adb shell cmd appops query-op --user 0 %~1 %~3') do (
                set /a n+=1001
                echo [!n:~-3!] %%a
                set #!n:~-3!=%%a
        )
        if not defined n (
                echo 无符合条件的app
                exit /b
        )
        echo=
        set /p c4=输入所有需要 "%~2" 的序号，以空格分隔：
        echo=
        for %%a in (%c4%) do (
                adb shell cmd appops set !#%%a! %~1 %~2
                rem 此命令成功失败无提示，请自行查看效果
                echo %~2 !#%%a! %~1 权限
        )
        echo=
        echo 操作完成
        echo=
        echo=
        exit /b
复制代码