cutebe

使用前备份原文件及测试！

set id=87654321
sed -i "s/\(COUNTER_NO=\).*$/\1%id%/" "d:\mis.ini"
复制代码

本论坛下载三方工具sed.exe

cutebe

各台机子单独运行？还是服务器分发？
若各机运行是靠什么区分，是IP还是MAC？
若服务器分发是直接分发ini，还是分发bat后各机自动运行？

::根据IP更改配置文件中ID
@echo off
setlocal enableDelayedExpansion

set ip1=192.168.1.20
set ip2=192.168.1.19
set ip3=192.168.1.18
set ip4=192.168.1.17
set ip5=192.168.1.16
set ip6=192.168.1.15
set ip7=192.168.1.14
set ip8=192.168.1.13
set ip9=192.168.1.12
set ip10=192.168.1.11
set "id1=12863768"
set "id2=12863767"
set "id3=12863766"
set "id4=12863765"
set "id5=12863764"
set "id6=12863763"
set "id7=12863762"
set "id8=12863761"
set "id9=12863760"
set "id10=12863759"

::识别IP
call :getIP pcip
::set "pcip=192.168.1.18"	::假设

::更改ID
for /l %%i in (1,1,10)do (
	if "%pcip%"=="!ip%%i!" (
		sed -i "s/\(COUNTER_NO=\).*$/\1!id%%i!/" "d:\mis.ini"
		goto :outfor
	)
)
:outfor

pause
goto :eof

:getIP gip	获取IP
请搜索相应“获取IP”代码
goto :eof
复制代码

cutebe

如果有ftp服务器可考虑：
-----------------------------------------------------------
条件：一、ftp服务器、客户机用固定ip；
二、下载三方sed/wget到系统目录，如%windir%！

步骤：一、ip-id对应表文件保存在ftp服务器上；
二、下载sed.exe和wget.exe两个三方程序，存入%windir%；
三、（先测试，正常后加到启动项里）每台机子上添加bat开机启动；
四、客户机开机运行bat，下载对应表。自动识别ip，根据ip修改id。

cutebe

mis-id.ini　　//ip-id对照表，存放在ftp服务器上。路径、名称均可修改，但更改后bat中下载处相应也要更改。

#IP		ID
#-----------------------
192.168.1.11	12863768
192.168.1.12    12863767
192.168.1.13	12863766
192.168.1.14	12863765
192.168.1.15	12863764
192.168.1.16	12863763
192.168.1.17	12863762
192.168.1.18	12863761
192.168.1.19	12863760
192.168.1.20	12863759
#=======================
复制代码

内容调整：IP、ID均按实际情况填入。IP在第一列，ID在第二列！

ip-id.bat

::根据IP更改配置文件中ID	//用到三方sed.exe;wget.exe
::先得到本机IP，再从ftp服务器上取得IP-ID对照表，后修改配置文件中ID。
@echo off
cd/d%~dp0

::识别本机IP
call :getIP pcip
echo [%pcip%]
::pause

::从服务器ftp获取ip-id对应表
wget -q -N "ftp://user:password@192.168.1.200/mis-id.ini"
::pause

::更改ID
for /f "tokens=1,2" %%c in ('findstr /c:"%pcip%" mis-id.ini')do (
	if "%%c"=="%pcip%" sed -i "s/\(COUNTER_NO=\).*$/\1%%d/" "d:\mis.ini"
)
::pause
goto :eof
::====完====

:getIP gip	获取本地IP
setlocal
for /f "tokens=3-6" %%a in ('"netsh interface dump|findstr /i "mask""')do (
	for %%i in ("%%a" "%%b" "%%c" "%%d")do if "%%~i" neq "" set %%i
)
if defined address set "ip=%address%"
if defined addr set "ip=%addr%"
endlocal&set "%1=%ip%"
goto :eof
复制代码

代码修改：wget -q -N "ftp://user:password@192.168.1.200/mis-id.ini"
user                                //ftp账户名
password                        //ftp密码
192.168.1.200                //ftp服务器IP
如果ip-id对照表文件mis-id.ini也改了名或路径，这里相应也要修改！

测试步骤：一、先测获取ip是否正常；
二、测试下载mis-id.ini是否成功；
三、最后看看配置文件D:\mis.ini中ID是否更换到位。