[网络连接] [已解决]求助批处理自动ping指定IP段写法

newgain

一堆IP地址需要不定期PING结果，IP地址为192.168.a.b 其中a为60，61，62……90，b为1，2，3……8
目前只会 for /f %%a in (60，1，90) do ping -n 1 192.168.%%a.1 | find "TTL">nul&&echo 192.168.%%a.1 >>ok.txt，这样写需要改数字运行8次。
有没有简单的方式一次性全部PING完，并输出到一个文件上.
求指点！！！感谢

Batcher

回复 1# newgain

@echo off
(for /l %%a in (60,1,90) do (
    for /l %%b in (1,1,8) do (
        ping -n 1 192.168.%%a.%%b | find "TTL" >nul && echo 192.168.%%a.%%b
    )
))>"ok.txt"
复制代码

Batcher

回复 1# newgain


参考for命令教程第15、16页
http://bbs.bathome.net/thread-31727-1-1.html

newgain

回复 3# Batcher


   谢谢

newgain

回复 4# newgain
已修改

(for /l %%a in (60,1,90) do (
    for /l %%b in (1,1,8) do (
        ping /n 1 192.168.%%a.%%b | find "TTL" >nul && echo 192.168.%%a.%%b >>ok.txt
    )
))
复制代码

newgain

原来写过一个测试全部存储主机的，跟这个类型差不多，代码繁琐，如下：

set f=140
set g=141
set h=144
set j=145
for /l %%i in (60,1,78) do ping /n 3 192.168.%%i.%f% | find "TTL" >nul&&echo 192.168.%%i.%f% >>%f%online.txt || echo 192.168.%%i.%f% >>%f%offlinetest.txt
ping /n 3 127.1 >nul
for /f %%p in (%f%offlinetest.txt) do ping /n 3 %%p | find "TTL" >nul&&echo %%p >>%f%online.txt || echo %%p >>%f%offline.txt
del /s /q %f%offlinetest.txt
::del /s /q %f%online.txt
ping /n 3 127.1>nul
for /l %%i in (60,1,78) do ping /n 3 192.168.%%i.%g% | find "TTL" >nul&&echo 192.168.%%i.%g% >>%g%online.txt || echo 192.168.%%i.%g% >>%g%offlinetest.txt
ping /n 3 127.1 >nul
for /f %%p in (%g%offlinetest.txt) do ping /n 3 %%p | find "TTL" >nul&&echo %%p >>%g%online.txt || echo %%p >>%g%offline.txt
del /s /q %g%offlinetest.txt
::del /s /q %g%online.txt
ping /n 3 127.1>nul
for /l %%i in (60,1,78) do ping /n 3 192.168.%%i.%h% | find "TTL" >nul&&echo 192.168.%%i.%h% >>%h%online.txt || echo 192.168.%%i.%h% >>%h%offlinetest.txt
ping /n 3 127.1 >nul
for /f %%p in (%h%offlinetest.txt) do ping /n 3 %%p | find "TTL" >nul&&echo %%p >>online.txt || echo %%p >>%h%offline.txt
del /s /q %h%offlinetest.txt
::del /s /q %h%online.txt
ping /n 3 127.1>nul
for /l %%i in (60,1,78) do ping /n 3 192.168.%%i.%j% | find "TTL" >nul&&echo 192.168.%%i.%j% >>%j%online.txt || echo 192.168.%%i.%j% >>%j%offlinetest.txt
ping /n 3 127.1 >nul
for /f %%p in (%j%offlinetest.txt) do ping /n 3 %%p | find "TTL" >nul&&echo %%p >>%j%online.txt || echo %%p >>%j%offline.txt
del /s /q %j%offlinetest.txt
::del /s /q %j%online.txt
复制代码

今天学习后新改代码：

del /s /q up.txt
del /s /q down.txt
(for /l %%a in (60,1,78) do (
    for %%b in (140,141,144,145) do (
        ping /n 1 192.168.%%a.%%b | find "TTL" >nul && echo 192.168.%%a.%%b >>up.txt || echo 192.168.%%a.%%b >>down.txt
    )
))
复制代码