czjt1234

WScript.Interactive
该属性的初始值为True

如果设为False，则禁用用户交互模式，即不执行输入输出语句

注意：禁用用户交互模式后，不能再启用
示例

Dim s

MsgBox WScript.Interactive     'True  (初始值)
MsgBox "秦时明月汉时关"          '正常执行
WScript.Interactive = False    '禁用用户交互模式
MsgBox "万里长征人未还"          '不执行
s = InputBox("请输入")          '不执行
WScript.Interactive = True     '禁用以后不能再启用
MsgBox "但使龙城飞将在"          '还是不执行
WScript.Echo "不教胡马度阴山"    '还是不执行
s = InputBox("请输入")          '还是不执行
复制代码

czjt1234

CreateObject()函数是vbs的内置函数，在.hta文件、office宏、IE等环境都可以使用
而这些环境不支持WScript对象，也就不可以使用WScript.CreateObject()方法

CreateObject()函数，其第二个参数用于在远程服务器上创建对象
WScript.CreateObject()方法，其第二个参数用于绑定对象的事件

czjt1234

一个批处理调用vbs，并读取vbs的返回码的示例

'vbs示例：用于批处理调用vbs，并获取vbs的返回码
WScript.Quit 20147578
复制代码

@echo off
D:\test.vbs
echo %errorlevel%
pause
复制代码

czjt1234

'要求已安装office - Word
'Word对象支持Quit()事件
Dim oWord

'创建对象，并绑定事件处理程序
Set oWord = WScript.CreateObject("Word.Application", "Word_")

'为对象取消事件处理程序
WScript.DisconnectObject(oWord)

oWord.Visible = True

WScript.Sleep 5000  '延时5秒
oWord.Quit()        '事件处理程序已取消关联，不会被执行

MsgBox "ok"

Sub Word_Quit()
    MsgBox "Quit()事件处理子程序", vbSystemModal
    WScript.Quit()
End Sub
复制代码

czjt1234

'要求已安装office - Word
'Word对象支持Quit()事件
Dim oWord

Set oWord = CreateObject("Word.Application")
WScript.ConnectObject oWord, "Word_"

oWord.Visible = True

Do
    WScript.Sleep 500    '等待用户关闭Word
Loop

Sub Word_Quit()
    MsgBox "Quit()事件处理子程序", vbSystemModal
    WScript.Quit()
End Sub
复制代码

建议在WScript.CreateObject方法创建对象时，直接指定事件处理程序
因为并非所有对象都可以用WScript.ConnectObject方法连接事件处理程序

比如InternetExplorer.Application对象就不支持WScript.ConnectObject方法
参考文档：Why does WScript.ConnectObject not always work?
https://blogs.msdn.microsoft.com ... ct-not-always-work/

czjt1234

获取已有的对象，只能用GetObject()函数

'GetObject()函数示例，不能用WScript.GetObject()方法
Dim obj

Set obj = GetObject("WinNT:")
MsgBox TypeName(obj)

Set obj = GetObject("Winmgmts:")
MsgBox TypeName(obj)
复制代码

某些应用程序可以只激活文件的一部分
格式是：在文件名的结尾处添加!，并在其后附加要激活部分的标识字符串
比如某.CAD文件包含3个图层，可以只打开其第三个图层，标识符Layer3

如果文件支持多个Automation对象，则同时指定文件和对象progid'示例 (本脚本未经验证)
'要求已安装AutoCAD软件和FIGMENT软件，假定相关文件和文件夹已存在

Dim oCAD, oDRW

Set oCAD = GetObject("D:\CAD\SCHEMA.CAD!Layer3")
MsgBox TypeName(oCAD)

Set oDRW = GetObject("D:\DRAWINGS\SAMPLE.DRW", "FIGMENT.DRAWING")
MsgBox TypeName(oDRW)
复制代码

czjt1234

回复 9# jyswjjgdwtdtj


   我发了个vbs中文手册0.3，都是直接复制的里面的内容啊

czjt1234

回复 13# jyswjjgdwtdtj


   就在vbs目录下