77七

回复 5# 惆怅而又凄凉


   在代码的开头加一句

setlocal enabledelayedexpansion
复制代码

文件名含 感叹号就在 for语句内加

cd /d "%~dp0"
for %%a in (*.jpg) do (
    echo 正在处理文件：%%a
    set "FN=%%a"
    setlocal enabledelayedexpansion
    set "FNR=!FN:*-=!"
    call set "FNL=%%FN:-!FNR!=%%"
    echo name = %%a
    echo fn = !FN!
    echo fnr = !FNR!
    echo fnl = !FNL!
    endlocal
    pause
)
复制代码

惆怅而又凄凉

回复  惆怅而又凄凉
Batcher 发表于 2023-3-8 09:23

    非常感谢解答！真的是醍醐灌顶。。。

看是看懂了，但不知道为啥出错，然后我做了中断和echo，结果是空的

cd /d "%~dp0"
for %%a in (*.jpg) do (
    echo 正在处理文件：%%a
    set "FN=%%a"
    set "FNR=!FN:*-=!"
    call set "FNL=%%FN:-!FNR!=%%"
    echo name = %%a
    echo fn = %FN%
    echo fnr = %FNR%
    echo fnl = %FNL%
pause
)
复制代码

正在处理文件：a-123456.jpg
name = a-123456.jpg
fn =
fnr =
fnl =
请按任意键继续. . .
复制代码

Batcher

回复 3# 惆怅而又凄凉

@echo off
cd /d "%~dp0"
for %%a in (*.zip) do (
    echo 正在处理文件：%%a
    set "FileName=%%a"
    set "NameRight=!FileName:*-=!"
    call set "NameLeft=%%FileName:-!NameRight!=%%"
    if not exist "!NameLeft!" (
        md "!NameLeft!"
    )
    move "%%a" "!NameLeft!\"
)
复制代码

惆怅而又凄凉

回复 2# Batcher


    感谢解答，我的主要问题是：
假设文件名是32132-aadjoig.zip

我本来考虑的是
1、遍历文件名，将文件名写入变量。
2、将变量字符串从“-”前面截取。
3、在指定位置建立文件夹为变量。
4、将该文件移至该文件夹。

但我没找到字符串按关键字截取的命令，还望再指教一二，谢谢！

Batcher

回复 1# 惆怅而又凄凉


请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

@echo off
cd /d "%~dp0"
for /f "tokens=1* delims=-" %%a in ('dir /b /a-d *.zip') do (
    echo 正在处理文件：%%a
    if not exist "%%a" (
        md "%%a"
    )
    move "%%a-%%b" "%%a\"
)
复制代码