[其他] [分享]加密解密磁盘的批处理

zcrandlt

加解密我的磁盘的批处理

这段代码可以将批处理所在盘进行加密
让里面的文件夹变成回收站的样子
对U盘也有效
别人双击文件夹大开的就是回收站。
但不对文件中的东西进行操作，不改动文件中的资料和数据
这可以在一定程度上防止优盘丢失，里面的资料被他人利用
可惜的是不能防止优盘病毒的启动
而且用start命令打开里面的程序也是可行的

@echo OFF &setlocal enabledelayedexpansion
color fd
title U盘加/解密
mode con cols=40 lines=8
SET d=0
set p=■
set h=0
::↓以下代码为进度条的出现做准备
for /f "delims='" %%a in ('dir /a:d /b %~d0\') do (
set f=%%a
set /a g=!g!+1
)
set /a e=100/!g!
set /a wucha=100-!e!*!g!
::↑进度条相关代码

::↓设置一个标志文件，用来决定是进行加密还是解密工作
if exist "%~d0\%f%\ZCR.ZCR" (goto jiemi) else (goto jiami)

:jiemi
set b=0
:1
set m2=
::↓以下代码能建立一个文本，保存你输入密码的次数，以及进行一些准备工作
if exist "%userprofile%\zcr.txt" (for /f "usebackq" %%a in ("%userprofile%\zcr.txt") do (set b=%%a))
set /a c=3-!b!
if exist "%userprofile%\zcr.txt" (
for /f "usebackq" %%a in ("%userprofile%\zcr.txt") do (
if "%%a"=="3" (
exit
)
)
)
echo 你还有!c!次输入密码的机会，
echo !c!次都错误我将关闭计算机
echo ~-~
set /p a=请输入密码
set /a b+=1

echo !b! > "%userprofile%\zcr.txt"

::↓以下代码对输入的密码进行加密
for /l %%a in (0,1,9) do ( 
set m1=!a:~%%a,1!
set /a m1+=9-%%a
set /a m1=!m1!"^"1
set /a m1=!m1!"|"3
set /a m1=!m1!"^"2
set m2=!m2!!m1!
)

::↓对输入的密码和你原本的密码（已加密）进行比较，相同则解密，否则要求重新输入密码
if "!m2:~1,-1!"=="加密密码" (
::↓解密的主要代码
for /f %%a in ('dir /a:d /b %~d0\') do (
attrib -r -s "%~d0\%%a"
attrib -r -a -s -h "%~d0\%%a\desktop.ini"
DEL "%~d0\%%a\desktop.ini"
cls
echo.
echo 正在为你解密U盘
::↓效果代码，可删除
set /a h+=1
if !d!==0 (set z=1)
if !d!==9 (set z=-1)
SET /A d+=!z!
COLOR F!d!
set p=!p!%p%
echo !p!
echo  请稍等，解密!e!
if !h!==3 set e=!e!+!wucha!
set /a e=!e!+%e%
)
) else (
cls
echo 你的密码不对，请重新输入......
goto 1
)
::↓解密结束后删除解密标志，删除保存输入次数的文本
del "%~d0\%f%\ZCR.ZCR"
del "%userprofile%\zcr.txt"

goto end

::↓加密部分
:jiami
for /f %%a in ('dir /a:d /b %~d0\') do (

::↓加密的主要代码
echo [.ShellClassInfo]  >"%~d0\%%a\desktop.ini"
echo CLSID={645FF040-5081-101B-9F08-00AA002F954E} >> "%~d0\%%a\desktop.ini"
attrib +r +s "%~d0\%%a" 


cls
echo.
echo 正在加密U盘

::↓进度条及显示的一些效果
set /a h+=1
if !d!==0 (set z=1)
if !d!==9 (set z=-1)
SET /A d+=!z!
COLOR F!d!
::↓进度条效果
set p=!p!%p%
echo !p!
echo  请稍等，加密!e!
if !h!==3 set e=!e!+!wucha!
set /a e=!e!+%e%
)
::↓建立解密标志
echo 1> "%~d0\%f%\ZCR.ZCR"
:end
set a=
set b=
set c=
set d=
set e=
set g=
set f=
set h=
set p=
set m1=
set m2=
exit
复制代码

以下为获得加密密码的代码

]@echo OFF &setlocal enabledelayedexpansion
color fd
set /p a=请输入你要加密的密码
for /l %%a in (0,1,9) do ( 
set m1=!a:~%%a,1!
set /a m1+=9-%%a
set /a m1=!m1!"^"1
set /a m1=!m1!"|"3
set /a m1=!m1!"^"2
set m2=!m2!!m1!
)
echo !m2:~1,-1!>mima.txt
set a=
set m1=
set m2=
exit
复制代码

[ 本帖最后由 zcrandlt 于 2009-12-10 14:38 编辑 ]

vsbat

NO---NO---NO__________
C: 盘里被你变了一堆回收站---
是不是得注名在 u 盘下执行啊
-------------------------------------
最后把接密部分复制下来单独执行 回收站 变回来了

[ 本帖最后由 vsbat 于 2009-12-10 14:43 编辑 ]

zcrandlt

额，不好意思。我已经改了
第一次发帖，弄的不大好