[其他] 【已解决】gawk第三方工具：如何赋予变量？

思想之翼

下列代码用于：删除文本右侧最小数值的行
http://www.bathome.net/thread-66798-1-1.html

gawk -v min="10000000000" "NR==FNR {min=min>$2?$2:min} NR>FNR && $2!=min" 1.txt 1.txt > 2.txt
复制代码

该代码用如下方式赋予变量，出现错误，如何解决？

@echo off
setlocal enabledelayedexpansion
for /l %%f in (1000001,1,1000002) do (
    set p=%%f
    gawk -v min="10000000000" "NR==FNR {min=min>$2?$2:min} NR>FNR && $2!=min" d:\JZ\!p:~1!\1.txt d:\JZ\!p:~1!\1.txt > d:\JZ\!p:~1!\2.txt
)
endlocal
pause
复制代码

出错显示：
gawk: cmd. 1ine:1: NR==FNR (min=min>$2?$2:min} NR>FNR && $2\JZ\000001\1.txt d:\JZ\000001\1.txt
gawk: cmd. 1ine:1: backslash not last character on line
gawk: cmd. 1ine:1: NR==FNR (min=min>$2?$2:min} NR>FNR && $2\JZ\000001\1.txt d:\JZ\000001\1.txt
gawk: cmd. 1ine:1: syntax error

77七

在gawk命令中 的 ”!“ 前加个 “^” 转义

gawk -v min="10000000000" "NR==FNR {min=min>$2?$2:min} NR>FNR && $2^!=min"
复制代码

WHY

顶楼脚本没有考虑其它特殊情况。
比如，如果 1.txt 包含有空行，min值为空，脚本会失效
如果必须考虑有空行的情况，可以这样：

gawk -v min=10000000000 "NR==FNR && $0!~/^$/ {min=min>$2?$2:min} NR>FNR && $2!=min" 1.txt 1.txt > 2.txt
复制代码

这个时候开启变量延迟，需要转义的特殊字符就比较多了（!^都要转义）
转义不仅麻烦，脚本变得也更不易读。

可以这样：

@echo off
for /l %%f in (1000001,1,1000002) do (
    setlocal enabledelayedexpansion
    set "p=%%f"
    for /f "delims=" %%i in ("d:\JZ\!p:~1!") do (
        endlocal
        gawk -v min=10000000000 "NR==FNR && $0!~/^$/ {min=min>$2?$2:min} NR>FNR && $2!=min" %%i\1.txt %%i\1.txt > %%i\2.txt
    )
)
pause
复制代码