77七

1楼的文本 时间后面紧跟着一个 tab，提供的压缩包内文本，时间后是空格。

77七

回复 4# 娜美
是我看错了，我这里显示的 tab 非常短

77七

@echo off
chcp 65001 >nul
rem 批处理保存为utf-8编码格式
set /a m=n=2
set /a "Jan=1,Feb=2,Mar=3,Apr=4,May=5,Jun=6,Jul=7,Aug=8,Sep=9,Oct=10,Nov=11,Dec=12"
for /f "delims=" %%x in ('dir /b /a-d *.txt') do (
	setlocal enabledelayedexpansion
	for /f "useback tokens=1-9* delims=,.	 " %%a in ("%%x") do (
		if %%h equ 1 (
			set t1=%%d-!%%b!-%%c %%e
			set t2=%%f
			set ss1=%%j
			set s2=
		) else if %%h equ 2 (
			if defined ss1 (
				set s2=1
			)
		) else if %%h equ 3 (
			if defined s2 (
				call :1 "!t1!" "%%d-!%%b!-%%c %%e"
				if "%%f" geq "!t2!" (
					set /a m=n-1
				)
				if !secs! leq !m! (
					if "!ss1!" neq "%%j" (
						if not defined _"%%x" (
							>>out.txt echo %%x
							set _"%%x"=1
						)
					)
				)
				set ss1=
				set s2=
			)
		) else (
			set ss1=
		)
	)
	endlocal
)
pause
exit

:1
::日期时间差 code by foxjl
set date1=%~1
set date2=%~2
for /f "tokens=1,2,3,4,5,6,7 delims=-/:. " %%i in ("%date1%") do ((set Y1=%%i) && (set M1=%%j) && (set D1=%%k) && (set H1=%%l) && (set F1=%%m) && (set S1=%%n) && (set MS1=%%o))
for /f "tokens=1,2,3,4,5,6,7 delims=-/:. " %%i in ("%date2%") do ((set Y2=%%i) && (set M2=%%j) && (set D2=%%k) && (set H2=%%l) && (set F2=%%m) && (set S2=%%n) && (set MS2=%%o))
set /a secs=((d2-32075+1461*(y2+4800+(m2-14)/12)/4+367*(m2-2-(m2-14)/12*12)/12-3*((y2+4900+(m2-14)/12)/100)/4)*86400+H2*3600+F2*60+S2)-((d1-32075+1461*(y1+4800+(m1-14)/12)/4+367*(m1-2-(m1-14)/12*12)/12-3*((y1+4900+(m1-14)/12)/100)/4)*86400+H1*3600+F1*60+S1)
exit /b
复制代码

不知道对不对

77七

回复 11# 娜美


   s1和子函数的s1变量冲突导致错误，已修改。

77七

回复 13# 娜美


   36行下添加一行

set s2=
复制代码

77七

回复 17# 娜美


  

call :1 "2023-6-10 08:39:01" "2023-6-10 08:39:09"
-1
复制代码

那个函数有问题，可能“过时了”，也可能是我使用方法有问题，难道要去0？
换了一个

@echo off
chcp 65001 >nul
rem 批处理保存为utf-8编码格式
set /a m=n=2
set /a "Jan=1,Feb=2,Mar=3,Apr=4,May=5,Jun=6,Jul=7,Aug=8,Sep=9,Oct=10,Nov=11,Dec=12"
for /f "delims=" %%x in ('dir /b /a-d *.txt') do (
	setlocal enabledelayedexpansion
	for /f "useback tokens=1-9* delims=,.	 " %%a in ("%%x") do (
		if %%h equ 1 (
			set t1=%%d-!%%b!-%%c %%e
			set t2=%%f
			set ss1=%%j
			set s2=
		) else if %%h equ 2 (
			if defined ss1 (
				set s2=1
			)
		) else if %%h equ 3 (
			if defined s2 (
				call :1 "!t1!" "%%d-!%%b!-%%c %%e"
				if "%%f" geq "!t2!" (
					set /a m=n-1
				)
				if !DiffSecs! leq !m! (
					if "!ss1!" neq "%%j" (
						if not defined _"%%x" (
							>>out.txt echo %%x
							set _"%%x"=1
						)
					)
				)
				set ss1=
				set s2=
			)
		) else (
			set ss1=
			set s2=
		)
	)
	endlocal
)
pause
exit

:1
rem http://bbs.bathome.net/redirect.php?goto=findpost&ptid=11128&pid=70814
set StartTime=%~1
set EndTime=%~2
set StartTime=%StartTime:-= %
set StartTime=%StartTime::= %
set EndTime=%EndTime:-= %
set EndTime=%EndTime::= %
call :DateToSecs %StartTime% StartSecs
call :DateToSecs %EndTime% EndSecs
set /a DiffSecs=EndSecs-StartSecs
set DiffSecs=%DiffSecs:-=%
goto :eof

:DateToSecs %yy% %mm% %dd% %hh% %nn% %ss% secs
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3&set hh=%4&set nn=%5&set ss=%6
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
if 1%hh% LSS 20 set hh=0%hh%
if {%nn:~2,1%} EQU {p} if "%hh%" NEQ "12" set hh=1%hh%&set/a hh-=88
if {%nn:~2,1%} EQU {a} if "%hh%" EQU "12" set hh=00
if {%nn:~2,1%} GEQ {a} set nn=%nn:~0,2%
set /a hh=100%hh%%%100,nn=100%nn%%%100,ss=100%ss%%%100
set /a j=j*86400+hh*3600+nn*60+ss
endlocal&set %7=%j%&goto :EOF
复制代码

77七

果然要去0才能准确调用。