[文本处理] 批处理每个文件夹随机选3张照片

3537589

从好多文件夹里面 随机选3张照片 放在单独一个文件夹里面  BAT如何实现

文件夹              
A      
B         
C        
D
E  
从文件夹 A B C D E 里面随机选3张照片 放在一个新文件夹里面。(文件夹数量随机的）
求大神帮忙，谢谢了

77七

@echo off
rem 批处理保存为ansi编码格式
md "随机"
for /d %%d in (*) do (
	if "%%d" neq "随机" (
		setlocal
		for %%a in ("%%d\*.jpg") do (
			call set _%%random%%=%%a
		)
		for /f "tokens=1* delims==" %%a in ('set _^|findstr /n .^|findstr /rbc:"[123]:"') do (
			copy "%%b" "随机"
		)
		endlocal
	)
)
pause
复制代码

qixiaobin0715

假设你的图片文件的扩展名是jpg，将随机选的图片放在D:\test目录中（代码会自动创建此目录）。将批处理文件放在与ABCDE文件夹同目录中运行：

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /s /b /a-d *.jpg') do (
    set /a n+=1
    set _!random!=%%a
)
set /a n-=3
md D:\test 2>nul
for /f "skip=%n% tokens=1* delims==" %%a in ('set _') do (
    copy "%%b" "D:\test"
)
pause
复制代码

Nsqs

#PowerShell 随机不重复复制
md new_jpg -Force|Out-Null
[System.Collections.Generic.Dictionary[string,string]]$list=@{}
dir *.jpg -Depth 1|%{$list[$_.Name]=$_.FullName}
dir new_jpg|%{$list.Remove($_.Name)}|Out-Null
$list.Keys|Get-Random -Count 3|%{copy $list[$_] "new_jpg" -Force}
复制代码

Five66

新文件夹放哪里？

3537589

文件夹数量和文件名是随机的。不固定