[其他] 我准备写一个bitLocker解锁bat

Codebug

title 解除C盘BitLookerTools
@echo on
cls

:start
echo                       =========================请选择要执行的操作=============================
echo                       =------------------按1并回车，查询C盘是否被加密------------------------=
echo                       =------------------按2并回车，解除C盘加密------------------------------=
echo                       =------------------如果你是win11,按3查询如何解除----------------------=
echo                       =------------------按4并回车，退出此程序----------------------------------=
echo                       ========================================================================
echo.
echo 请选择要执行的操作
set /p num=

if "%num%"=="1" (
    echo --------------------------准备查询加密状态-------------------------------
    manage-bde -status F: | findstr "启用" >>1.txt
    if %errorlevel% equ 0 (
        echo 加密状态：已加密
    ) else (
        echo 加密状态：未加密
    )
    echo ----------------------------查询完毕--------------------------------
    pause
    cls
    goto :start
)

if "%num%"=="2" (
    echo ---------------------------准备解除加密状态-------------------------------
    manage-bde -off F: | findstr "正在解密" >>2.txt
    if %errorlevel% equ 0 (
        echo -------------------------正在解密……,请稍后查询加密状态---------------------
    ) else (
	  echo -------------------------解密失败，准备查询失败原因--------------------------------
          manage-bde -off F: | findstr "没有启用" >>3.txt
        if %errorlevel% equ 0 (
        echo ----------------------解密失败，您设备没有被加密--------------------------------
        ) 
    )
    pause
    cls
    goto :start
)

if "%num%"=="3" (
   echo 进入设置-隐私和安全性-设备加密开关，关闭即可；
   echo 如果没有，进入设置- 隐私和安全性-安全中心-打开windows安全中心-设备安全性-管理bitLocker驱动器加密，然后会到第一个，关闭即可
   echo 关闭开关，解除加密过程有点漫长。请耐心等待
   echo.
   pause
    cls
    goto :start

)

if "%num%"=="4" (
    exit
)
复制代码

如何优化，他判断不了，运行还有问题

Batcher

回复 1# Codebug


    "判断不了"是指第几行的结果和预期不一样？

Codebug

回复 2# Batcher 我判断不了他打印后的情况，

if "%num%"=="1" (
    echo --------------------------准备查询加密状态-------------------------------
    manage-bde -status F: | findstr /C:"启用" >nul
:: 这个判断是否包启用，但是我按了1后，显示显示已加密，然后才会显示未加密
    if %errorlevel% equ 0 (
        echo 加密状态：已加密
    ) else (
        echo 加密状态：未加密
    )
    echo ----------------------------查询完毕--------------------------------
    pause
    cls
    goto :start
)
复制代码

if "%num%"=="2" (
    echo ---------------------------准备解除加密状态-------------------------------
    manage-bde -off F: | findstr /C:"正在解密" >nul
:: 我输入2后因为是没加密的，然后应该显示解密失败往后的，他就这两个来回显示
    if %errorlevel% equ 0 (
        echo -------------------------正在解密……,请稍后查询加密状态---------------------
    ) else (
	  echo -------------------------解密失败，准备查询失败原因--------------------------------
          manage-bde -off F: | findstr /C:"没有启用" >nul
        if %errorlevel% equ 0 (
        echo ----------------------解密失败，您设备没有被加密--------------------------------
        ) 
    )
    pause
    cls
    goto :start
)
复制代码

Batcher

回复 3# Codebug

@echo off
title 解除C盘BitLookerTools
cls

:Loop
echo                       =========================请选择要执行的操作=============================
echo                       =------------------按1并回车，查询F盘是否被加密------------------------=
echo                       =------------------按2并回车，解除F盘加密------------------------------=
echo                       =------------------如果你是win11,按3查询如何解除----------------------=
echo                       =------------------按4并回车，退出此程序----------------------------------=
echo                       ========================================================================
echo,
echo 请选择要执行的操作
set /p "num="

if "%num%"=="1" (
    echo --------------------------准备查询加密状态-------------------------------
    manage-bde -status F: | findstr "启用" >>1.txt
    if errorlevel 1 (
        echo 加密状态：未加密
    ) else (
        echo 加密状态：已加密
    )
    echo ----------------------------查询完毕--------------------------------
    pause
    cls
    goto :Loop
) else if "%num%"=="2" (
    echo ---------------------------准备解除加密状态-------------------------------
    manage-bde -off F: | findstr "正在解密" >>2.txt
    if not errorlevel 1 (
        echo -------------------------正在解密……,请稍后查询加密状态---------------------
    ) else (
        echo -------------------------解密失败，准备查询失败原因--------------------------------
        manage-bde -off F: | findstr "没有启用" >>3.txt
        if not errorlevel 1 (
            echo ----------------------解密失败，您设备没有被加密--------------------------------
        ) 
    )
    pause
    cls
    goto :Loop
) else if "%num%"=="3" (
    echo 进入设置-隐私和安全性-设备加密开关，关闭即可；
    echo 如果没有，进入设置- 隐私和安全性-安全中心-打开windows安全中心-设备安全性-管理bitLocker驱动器加密，然后会到第一个，关闭即可
    echo 关闭开关，解除加密过程有点漫长。请耐心等待
    echo,
    pause
    cls
    goto :Loop

) else if "%num%"=="4" (
    exit /b
)
复制代码

iuiu7890

据我所知 不需要判断啊，直接解就行了 不管他有没有bitlock

少马石

这个正能解密？

Batcher

回复 6# 少马石


    前提是要有密钥