qixiaobin0715

第一个for循环主要是排除不含Soul Crystal的xml文件。
变量延迟加在合适的位置即可：

@echo off
(for /f "delims=" %%i in ('findstr /m /c:"Soul Crystal" *.xml') do (
    for /f "tokens=1,3,4" %%a in ('type "%%i"') do (
        if "%%a"=="<item>" (
            set x=true
        ) else if "%%a"=="</item>" (
            set x=
            setlocal enabledelayedexpansion
            for /f "tokens=2 delims==" %%d in ("!str1!") do echo,!str2!,%%~d
            endlocal
        ) else if defined x (
            if "%%b%%c"=="SoulCrystal" (
                set y=true
            ) else if defined y (
                set y=
                for /f "tokens=2 delims==" %%d in ("%%b") do set str2=%%~d
            )
            set str1=%%b
        )
    )
))>out.csv
pause
复制代码

qixiaobin0715

受10楼代码启示，这样应当在逻辑上更容易理解些：
1.找出"Soul Crystal"和"</item>"所在的行数；
2.根据第1条找出数据所在行的行数，并随后对这些行进行处理，得到所需ID数值。

@echo off
(for /f "delims=" %%i in ('findstr /m /c:"Soul Crystal" *.xml') do (
    setlocal enabledelayedexpansion
    for /f "tokens=1,2 delims=:	 " %%j in ('findstr /ilnc:"Soul Crystal" /inc:"</item>" "%%i"') do (
        set n=%%j
        if "%%k"=="</item>" (
            set /a n-=1
            set _!n!=true
        ) else (
            set /a n+=1
            set #!n!=true
        )
    )
    for /f "tokens=1,4 delims=:	 " %%a in ('findstr /n .* "%%i"') do (
        if defined #%%a (
            for /f "tokens=2 delims==" %%c in ("%%b") do set "str=%%~c"
        ) else if defined _%%a (
            for /f "tokens=2 delims==" %%c in ("%%b") do echo,!str!,%%~c
        )
    )
    endlocal
))>out.csv
pause
复制代码