77七

@echo off
rem 批处理保存为ansi编码格式
cd /d "%~dp0"

set t1=语文 数学 物理 化学 历史 政治 生物 地理 英语 道法
set t2=一 二 三 四 五 六 七 八 九 1 2 3 4 5 6 7 8 9
set /a 一=1,二=2,三=3,四=4,五=5,六=6,七=7,八=8,九=9
set t3=年上 第一学期 上学期 上册 上期
set t4=年下 第二学期 下学期 下册 下期

rem 排除关键字
set t5=二零一九 二零二零

for /f "delims=" %%i in ('dir /b /a-d ^|find /v "%~nx0"') do (
	set str=%%i
	set _str=%%i
	setlocal enabledelayedexpansion
	rem 排除关键字
	for /l %%l in (2000,1,2050) do (
		set "_str=!_str:%%l=!"
	)
	for /l %%l in (10,1,99) do (
		set "_str=!_str:%%l=!"
	)
	for %%a in (%t5%) do (
		set "_str=!_str:%%a=!"
	)

	for %%a in (%t1%) do (
		echo !_str!|find "%%a" 1>nul && set m1=%%a
	)
	for %%a in (%t2%) do (
		echo !_str!|find "%%a" 1>nul && (
			if defined %%a (
				set m2=!%%a!
			) else (
				set m2=%%a
			)
		)
	)
	for %%a in (%t3%) do (
		echo !_str!|find "%%a" 1>nul && set m3=A
	)
	for %%a in (%t4%) do (
		echo !_str!|find "%%a" 1>nul && set m3=B
	)
	echo ren "!str!" "【!m1!!m2!!m3!】!str!"
	ren "!str!" "【!m1!!m2!!m3!】!str!"
	endlocal
)
pause
复制代码

77七

2023年12月沈阳和平区九上历史期末试卷+答案

t3中没有 上 或者 九上 关键词，需要自己添加

@echo off
rem 批处理保存为ansi编码格式
cd /d "%~dp0"
for /f %%i in ('powershell -c "Get-Date -uformat '%%m%%d'"') do (
	set "Today=%%i"
)

set t1=语文 数学 物理 化学 历史 政治 生物 地理 英语 道法
set t2=一 二 三 四 五 六 七 八 九 1 2 3 4 5 6 7 8 9
set /a 一=1,二=2,三=3,四=4,五=5,六=6,七=7,八=8,九=9
set t3=年上 第一学期 上学期 上册 上期
set t4=年下 第二学期 下学期 下册 下期
set t6=中考 高考
set t7=*.doc *.pdf
rem 排除关键字
set t5=二零一九 二零二零

for /f "delims=" %%i in ('dir /b /a-d %t7% ^|findstr /rvbc:"【.*】【[0-9][0-9]*】"') do (
	set str=%%i
	set _str=%%i
	setlocal enabledelayedexpansion
	rem 排除关键字
	for /l %%l in (2000,1,2050) do (
		set "_str=!_str:%%l=!"
	)
	for /l %%l in (10,1,99) do (
		set "_str=!_str:%%l=!"
	)
	for %%a in (%t5%) do (
		set "_str=!_str:%%a=!"
	)

	for %%a in (%t1%) do (
		echo !_str!|find "%%a" 1>nul && set m1=%%a
	)
	for %%a in (%t6%) do (
		echo !_str!|find "%%a" 1>nul && (
			set m2=·
			set m3=%%a
		)
	)
	if not defined m2 (
		for %%a in (%t2%) do (
			echo !_str!|find "%%a" 1>nul && (
				if defined %%a (
					set m2=!%%a!
				) else (
					set m2=%%a
				)
			)
		)
	)
	if not defined m3 (
		for %%a in (%t3%) do (
			echo !_str!|find "%%a" 1>nul && set m3=A
		)
		if not defined m3 (
			for %%a in (%t4%) do (
				echo !_str!|find "%%a" 1>nul && set m3=B
			)
		)
	)
	echo ren "!str!" "【!m1!!m2!!m3!】【%Today%】!str!"
	ren "!str!" "【!m1!!m2!!m3!】【%Today%】!str!"
	endlocal
)
pause
复制代码

77七

回复 9# qd2024


   上 和 下 单独作为关键词，可能需要排除一些，不如直接列举一下 七上...

@echo off
rem 批处理保存为ansi编码格式
cd /d "%~dp0"
for /f %%i in ('powershell -c "Get-Date -uformat '%%m%%d'"') do (
	set "Today=%%i"
)

set t1=语文 数学 物理 化学 历史 政治 生物 地理 英语 道法
set t2=一 二 三 四 五 六 七 八 九 1 2 3 4 5 6 7 8 9
set /a 一=1,二=2,三=3,四=4,五=5,六=6,七=7,八=8,九=9
set t3=第一学期 上学期 上册 上期 七上 八上 九上
set t4=第二学期 下学期 下册 下期 七下 八下 九下
set t6=中考 一模 二模 三模
set t7=*.doc *.pdf
rem 排除关键字
set t5=期中考试 二零二四 二零二三 二零二三 二零二一 二零二零 二零一九 二零一八 二零一七 二零一六 二零一五 二零一四  二零一三 二零一二 二零一一 二零一零 01 02 03 04 05 06 07 08 09

for /f "delims=" %%i in ('dir /b /a-d %t7% ^|findstr /rvbc:"【.*】【[0-9][0-9]*】"') do (
	set str=%%i
	set _str=%%i
	setlocal enabledelayedexpansion
	rem 排除关键字
	for /l %%l in (2000,1,2050) do (
		set "_str=!_str:%%l=!"
	)
	for /l %%l in (10,1,99) do (
		set "_str=!_str:%%l=!"
	)
	for %%a in (%t5%) do (
		set "_str=!_str:%%a=!"
	)

	for %%a in (%t1%) do (
		echo !_str!|find "%%a" 1>nul && set m1=%%a
	)
	for %%a in (%t6%) do (
		echo !_str!|find "%%a" 1>nul && (
			set m2=9B·
			set m3=!m3!%%a
		)
	)
	if not defined m2 (
		for %%a in (%t2%) do (
			echo !_str!|find "%%a" 1>nul && (
				if defined %%a (
					set m2=!%%a!
				) else (
					set m2=%%a
				)
			)
		)
	)
	if not defined m3 (
		for %%a in (%t3%) do (
			echo !_str!|find "%%a" 1>nul && set m3=A
		)
		if not defined m3 (
			for %%a in (%t4%) do (
				echo !_str!|find "%%a" 1>nul && set m3=B
			)
		)
	)
	echo ren "!str!" "【!m1!!m2!!m3!】【%Today%】!str!"
	ren "!str!" "【!m1!!m2!!m3!】【%Today%】!str!"
	endlocal
)
pause
复制代码