[文件操作] 求助批处理把文件名最大的加1

单车少男

2024年01月19日 - 收集池清单v5.XLS
2024年01月19日 - 清单v5.XLS
2024年01月19日 - 收集池清单v4.XLS
2024年01月19日 - 清单v4.XLS
2024年01月19日 - 收集池清单v3.XLS
2024年01月19日 - 清单v3.XLS


运行批处理，V5（最大的数）自动加1，成V6

怎么处理？

77七

请多提供几个文件名
比如按规律填空
1 （？）
这怎么填

单车少男

回复 2# 77七


    不好意思，我的问题，没表达清楚，已经修改

77七

回复 3# 单车少男

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d "* - *v*.*"^|find /v "%~nx0"') do (
	for /f "tokens=1-3 delims=v- " %%a in ("%%~ni") do (
		set /a n=%%c+1000000,m=%%c+1
		set #"%%b"#"!n!"#"%%i"=%%a - %%bv!m!%%~xi
	)
)
for /f "tokens=1-4 delims=#=" %%a in ('set # ^|sort /r') do (
	if not defined _"%%~a" (
		ren "%%~c" "%%d"
		set _"%%~a"=1
	)
)
endlocal
pause
复制代码

单车少男

回复 4# 77七


    REN 改成 copy  可以了

新增后，打开呢，怎么搞

单车少男

回复 4# 77七


    后缀xlsx，换成docx 无法用吗

77七

回复 5# 单车少男


  

for /f "tokens=1-4 delims=#=" %%a in ('set # ^|sort /r') do (
	if not defined _"%%~a" (
		copy "%%~c" "%%d"
		"%%d"
		timeout 2 >nul
		set _"%%~a"=1
	)
)
复制代码

77七

回复 6# 单车少男


   应该不影响，不行把失败的docx文件名发出来看看

单车少男

回复 8# 77七


    物联截污V3.docx
    物联截污V4.docx

77七

回复 9# 单车少男


   所以说我在2楼让你多发几个文件名..代码应该重写了...

单车少男

回复 7# 77七


   

"%%d"

改成  start   "%%d"  怎么不能打开么

77七

回复 11# 单车少男


   start "" "%%d"

单车少男

回复 12# 77七


    出错的

77七

回复 13# 单车少男


   
文件类型没有关联软件吗？
start "" "软件完整路径" "文件名" 试试

77七

回复 9# 单车少男


  

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d "*v*.*"') do (
	set file=%%i
	for /f "delims=" %%a in ("!file:v=/!") do (
		set /a n=%%~na+1,m=1000000+%%~na
		set #"!file:v%%~nxa=!"#"!m!"=!file:%%~nxa=!!n!%%~xi
	)
)
for /f "tokens=1-3 delims=#=" %%a in ('set # ^|sort /r') do (
	if not defined _"%%~a" (
		set _"%%~a"=1
		cd.>"%%c"
		start "" "%%c"
		timeout 2
	)
)
endlocal
pause
复制代码