77七

执行代码前 手动创建一个空白页的pdf文件，命名为 空白页.pdf

@echo off
rem 批处理保存为ansi编码格式
rem 下载pdftk http://bcn.bathome.net/tool/PDFtk.rar
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d *.pdf ^|find /v /i "空白页.pdf"') do (
	pdftk "%%i" dump_data |findstr /rbec:"NumberOfPages:.*[13579]" 1>nul && (
		set str=!str! "%%i" 空白页.pdf
	) || (
		set str=!str! "%%i"
	)
)
set str=!str!$$
set "str=!str:空白页.pdf$$=!"
set "str=!str:$$=!"
for %%i in (.) do (
	echo 合并 !str!
	pdftk !str! cat output "%%~nxi.pdf"
)
endlocal
pause
复制代码

77七

回复 4# 暴雪英雄


  

@echo off
rem 批处理保存为ansi编码格式
rem 下载pdftk http://bcn.bathome.net/tool/PDFtk.rar

set "file=d:\空白页文件夹\空白页.pdf"
set "_pdftk=d:\pdftk\pdftk.exe"

cd /d "%~dp0"
setlocal enabledelayedexpansion
for %%a in (*.pdf) do (
	set /a n+=1
)
for /f "delims=" %%i in ('dir /b /a-d *.pdf') do (
	set /a m+=1
	if !m! neq !n! (
		"%_pdftk%" "%%i" dump_data |findstr /rbec:"NumberOfPages:.*[13579]" 1>nul && (
			set str=!str! "%%i" "%file%"
		) || (
			set str=!str! "%%i"
		)
	) else (
		set str=!str! "%%i"
	)
)
for %%i in (.) do (
	echo 合并 !str!
	"%_pdftk%" !str! cat output "%%~nxi.pdf"
)
endlocal
pause
复制代码

77七

回复 7# 暴雪英雄


   第25-28行，修改为：

for %%i in (.) do (
	echo 合并 !str!
	"%_pdftk%" !str! cat output "%%~nxi.pdf"
	if exist "%%~nxi.pdf" (
		for %%a in (*.pdf) do (
			if "%%a" neq "%%~nxi.pdf" (
				del "%%a"
			)
		)
	)
)
复制代码

77七

回复 11# 暴雪英雄


   当时这个代码，使用utf-8方便些，所以采用了utf-8编码。试着将5楼代码第16行 修改为

		"%_pdftk%" "%%i" dump_data_utf8 output |findstr /rbec:"NumberOfPages:.*[13579]" 1>nul && (
复制代码

并在批处理文件开头添加

chcp 65001 >nul
复制代码

批处理保存为utf-8编码格式

77七

回复 10# 暴雪英雄

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "delims=" %%i in ('dir /b /a-d *.pdf') do (
	pdftk "%%i" dump_data_utf8 output |find "BookmarkTitle:" 1>nul
	if errorlevel 1 (
		>report.txt (
			echo BookmarkBegin
			for /f "tokens=2 delims=（" %%x in ("%%~ni") do (
				for /f "tokens=1 delims=2" %%y in ("%%x") do (
					echo BookmarkTitle: %%y
				)
			)
			echo BookmarkLevel: 1
			echo BookmarkPageNumber: 1
		)
		pdftk "%%i" update_info_utf8 report.txt output $.pdf
		move $.pdf "%%i"
	)
)
del report.txt
复制代码

77七

回复 14# 暴雪英雄


  添加标签的代码，生成的报告

ansi
BookmarkTitle: &去掉#31532;&去掉#19968;&去掉#31456;
utf-8
BookmarkTitle: 第一章
复制代码

添加标签就是修改这个报告，改为ansi有点麻烦（其实我不会，可能需要其它脚本转换），可以参考12楼，把其它代码向 utf-8靠拢。