[其他] [50条]不能说的秘密-CMD命令奇诡语法特性汇集

qzwqzw

　　谨以此文献给我生命中最重要的三个女人，在本文更新期间，是她们给了我很大的物质支持和精神鼓励，支持我最终将此文完成。同时感谢论坛管理层，尤其是批处理之家的namejm，他不仅给我提供了很多线索和建议，同时也在论坛管理上提供了很大的便利和支持。当然，也感谢所有参与讨论并给出建议的朋友们。他们分别是（按发帖时间排序）：
BATHOME：neorobin、hanyeguxing、yangfengoo、x9tiancmd、随风、x9tiancmd、Batcher、lxzzr
CN-DOS：qinchun36


声明：

• 本帖目前已完成初稿，现向全体会员开放阅读，大家可以选择在线阅读或者制作离线阅读版本；
• 我将不再主要负责本帖的更新，但仍然希望大家能继续跟帖讨论补充，同时麻烦管理层及时更新本帖；
• 本文代码的运行环境，凡是未明确声明的，均是在Windows XP SP2的CMD下；
• 此篇可以看做是《CMD/DOS下符号的作用参考》的姊妹篇，两者内容可能会有重叠；
• 本文作者不希望各位在此发表无内容的回复，如果只是支持可以选择评分，如果只是路过就请不要留下脚印；
• 本帖在CNDOS与BATHOME同步更新，互为备份，参考链接如下：

　　　　BATHOME：http://bbs.bathome.net/thread-7629-1-1.html
　　　　CNDOS：http://www.cn-dos.net/forum/viewthread.php?tid=50912

示例：
set varname=var1
set var1=value
call echo %varname%=%%%varname%%%
效果：输出var1=value，实现变量的二次扩展
注释：这种二次扩展的办法在纯DOS中比较常用，CMD下在不能使用变量延迟时也可以考虑

示例：cd.>test.txt
效果：产生一个零字节的文件test.txt
注释：零字节文件的创建，其实有更多的办法（具体见参考链接），但这种目前是最简单可靠的。
链接：http://bbs.bathome.net/thread-939-4-1.html#pid49298
http://www.cn-dos.net/forum/viewthread.php?tid=22336

示例：
md Test Sample
cd Test Sample
rd Test Sample
效果：md和rd命令正常执行，cd命令报错“系统找不到指定的路径。”
注释：md和rd命令隐含支持多个目录的创建和删除，所以把Test Sample理解成了Test和Sample两个目录，
        但cd命令只能是一个目录，而且隐含支持带空格不带引号的路径，所以将Test Sample理解成了一个目录,
        三个命令在认识上的不统一，导致了这个问题的出现。
        另外，不像command.com，cmd下的md和rd已经都支持多级目录的创建和删除了，这个在官方文档已提到。

示例：
cd.>test.html
dir /b *.htm
copy *.htm *.bak
效果：首先列出test.html文件，随后将其扩展名改为.bak
注释：文件名中有通配符且扩展名有3个字节时，无论其扩展名是否有通配符，都会对扩展名进行通配匹配，
        扩展名之后可以添加; , .等特殊字符，不影响通配匹配。
链接：http://www.cn-dos.net/forum/viewthread.php?tid=22336

示例：echo.%var%
效果：如果变量var 为空显示空行，如果不为空则显示其值
注释：echo. 官方文档解释为输出一个空行，用于文本的排版；
但更多的用于防止输出的变量为空时，echo语句出现语法错误；
. 也可以改为, + / : ; [ ] 等特殊字符
链接：http://bbs.bathome.net/thread-4482-1-1.html#pid28940

示例：
echo 文本1 ^
文本2 ^
文本3
效果：将三段文本合并到一行显示
注释：^ 将随后的行结束符取消转义，所以有其它语言中类似续行符的作用
其它命令中也可以这样使用，甚至可以用它截断命令名、文件名或者参数
只是别在引号对中这样使用

示例：set | findstr "\\\\"
效果：显示set命令输出中有一个\ 的行
注释：findstr中不论有没有开启正则，\ 都是元字符的转义字符，而且""对还会将\ 进行再次转义
链接：http://www.cn-dos.net/forum/viewthread.php?tid=21167

示例：
set/p= <nul>示例文字
findstr /a:f1 . 示例文字?
del 示例文字?
效果：显示白色背景黑色前景的“示例文字”
注释：可以多次利用此方法在一行内显示多种不同前景色和背景色的文字
在没有发现这个用途之前，findstr的开关/a可以说是“蛇足”，它在文档中虽有说明，
但语焉不详，更别说如此奇诡的用途；/a: 后的字符可以根据color /?的说明进行调整
链接：http://bbs.bathome.net/thread-1331-1-1.html#pid11864
http://groups.google.com/group/alt.msdos.batch.nt/browse_thread/thread/f819acd4582d5de3/
http://www.cn-dos.net/forum/viewthread.php?tid=35622
http://www.cn-dos.net/forum/viewthread.php?tid=38940

示例：
set/p=不含回车换行符的文本行<nul>test.txt
findstr "$" test.txt
type test.txt|findstr "$"
效果：第二句输出任何文本，第三句输出“不含回车换行符的文本行”
注释：findstr的正则与POSIX正则以及其他标准的正则都不太一样，是个简化版的正则。
        $ 在这里做为正则表达式元字符，匹配行尾的回车和换行符号，而不是真正的行尾。
        而因为测试文本没有回车符和换行符，所以第二句的findstr "$" 匹配失败。
        第三句成功匹配是因为CMD 的“后处理”为文本添加了回车换行并通过管道传给了findstr

示例：
echo 我 你 他>test.txt
findstr "我 你 他" test.txt
效果：没有输出任何文本
注释：finstr在匹配多个中文串时存在问题，使用开关/l或者/r可以得到正确的输出。

示例：
echo.>test.txt && attrib +h test.txt
echo.>test2.txt && attrib +s test2.txt
for %%i in (*.txt) do echo %%i
效果：显示结果不包含带有隐藏属性的test.txt，但包含带有系统属性的test2.txt
注释：不带/a开关的dir 是两者都不显示，for 显然对文件属性有自己的认识

示例：
md TestSample & cd TestSample & cd.>"test 1".txt
for %%f in (*.txt) do echo %%~sf
效果：在WindowsXP SP2环境下显示D:\TESTSA~1\TEST1~1.TXTt，多了一个字符t
注释：短名扩展是基于完整长名路径后的。当路径中既有长目录名，又有含空格的短文件名时，
        CMD的短名扩展不对原长名路径的长度进行修剪，导致短名路径尾部残留原长名路径的字符。
        Windows 2003以上系统无此问题。
链接：http://www.cn-dos.net/forum/viewthread.php?tid=27063

示例：
echo 1 > 1.txt & echo 2 > 2.txt
for %%f in (*.txt) do ren %%f f-%%f
效果：生成两个文件f-2.txt和f-f-1.txt ，1.txt 被改名后再次被改名
注释：在for 语句内使用ren 要谨慎，f-可以改为任意以字母开头的字符串
链接：http://bbs.bathome.net/thread-31727-1-1.html
《批处理BAT脚本中for命令的使用》第8页

示例：for /f "delims=" %%i in (test.txt) do echo %%i
效果：显示test.txt的所有行，除了空行
注释：for/f 的文本遍历会遇到空行时，替代变量%%i被赋值为空，不会执行do的语句块。
        显示空行文本的折中方案是，使用finstr或者find为文本的所有行包括空行添加一个前缀，
        待通过for/f的“防空”保护后，再用set或者tokens把这个前缀去除。如下：

示例：for /f "eol=
" %%i in (test.txt) do echo %%i
效果：显示test.txt的文本内容，忽略以
起始的行
注释：这个语法之所以称得上“奇诡”，主要是因为官方文档的中文化过程中，
        将“an end of line comment character”翻译成了“行尾字符”（ntcmds.chm）
        在命令行帮助中则是“行注释字符的结尾”，按字面意义理解都会理解成行尾的字符，
        因此误人不浅，实际上应该是“代表行结束的注释字符”，而且这个字符必须在行首。
        不指定eol时，for/f缺省使用分号;作为eol，所以会过滤掉文本中以分号起始的行，
        而"eol="会将双引号指定为eol，使用"eol= delims="则会将空格指定为eol。
        使用示例中的
可以近似显示所有的行，因为
是一个控制字符，不太可能出现在文本中。

示例：for /l %%i in (2147483635,1,2147483647) do echo %%i
效果：显示两个正数后，将从小到大显示负数，零，正数，负数，依次循环
注释：for /l使用加法，2147483647加一后变为负值，仍然满足循环条件，使之成为无限循环
链接：http://bbs.bathome.net/thread-7659-1-1.html

示例：for /r %f in (.) do @echo %f
效果：分行显示当前目录下所有子目录名，并在行尾添加\.
注释：括号中的句点还可以改为其它不含文件通配符（*,?）的字符或字符串

示例：for /r %f in (test.txt) do @echo.%f
效果：分行显示当前目录下所有子目录名，并在行尾添加\该文件名.当前目录\该文件名
注释：test.txt可以换成不含通配符的其他文件名或者字符串，echo后的.可以换成+、/等特殊字符
链接：http://bbs.bathome.net/viewthread.php?tid=3465&page=1#pid29165

示例：if "〇"=="" echo 〇为空
效果：显示结果为：〇为空
注释：在Windows XP下的936代码页下测试
链接：http://bbs.bathome.net/viewthread.php?tid=7513

示例：if "Z" leq "z" (echo "Z <= z") else echo "Z > z"
效果：显示结果表明Z大于z
注释：if的字符串比较不是按照ASCII或者Unicode码表，而是自有一套规则，详见
链接：http://bbs.bathome.net/thread-6851-1-1.html

示例：
if "e" leq "-" (echo "e <= -") else echo "e > -"
if "ef" leq "-f" (echo "ef <= -f") else echo "ef > -f"
效果：显示结果表明e大于-，而ef小于-f
注释：减号-也可以换成单引号'，它们在if的数值比较语句中充当一种另类的转义字符
链接：http://bbs.bathome.net/thread-6853-1-1.html

示例：if 3 gtr -2147483645 (echo 3＞-2147483645) else (echo 3＜＝-2147483645)
效果：显示结果表明3＜＝-2147483645
注释：if数值比较的核心是减法，依靠对两个数值的减法差值的正负判定大小
而差值变量是32位（DWORD）整型变量，存在-2^31~2^31-1的限定范围
而3- (-2147483645)的差值即超出此限，结果有正转负，判定也由大变小
链接：http://bbs.bathome.net/thread-7659-1-1.html

示例：if defined "test var" (echo pass) else (echo fail)
效果：不管之前有无定义变量test var，显示结果都为fail
注释：if defined判定的变量名包含空格时，不能直接使用 if defined test var echo pass
        此时，test被识别为变量名，var被识别为if的执行体语句块，如果存在变量test，则出现语法错；
        也不能如示例般使用引号对将变量名引起，否则if defined将引号看作变量名的一部分，执行else块
        此时可以使用两个方法使变量名中的空格躲过CMD预处理的词法切分逻辑，详见链接：
        1. for %%f in ("test var") do if defined %%~f (echo pass) else (echo fail)
        2. set varname=test var&if defined !varname! (echo pass) else (echo fail)
        方法2中的!varname!更改为%varname%无效，因为%的变量扩展逻辑在空格的词法切分逻辑之前
        而且变量!varname!不能使用!varname:~1,2!的引用形式，因为逗号影响了CMD预处理的词法切分逻辑
链接：http://bbs.bathome.net/viewthread.php?tid=2050

示例：
md testdir&if exist testdir\nul (echo Pass) else (echo Fail)
md "test dir"&if exist "test dir"\nul (echo Pass) else (echo Fail)
效果：第一句显示Pass，第二句显示Fail
注释：if exist通常用于判断一个路径是否存在，它不能直接分辨出目标路径究竟是目录还是文件。
        而如示例中所用的 if exist test\nul ...，则是从DOS 起广泛使用的判断目录存在的标准方案。
        它借助系统中所存在的aux con nul prn com1 lpt1等标准字符设备名判断目标路径是否指向目录，
        因为这些设备没有可以在任意目录下引用，所以“目录路径\nul”这样的引用被系统认为是有效的，
        但在CMD下，这种方法不适用于判定带引号的目录，这点与if defined "变量名" 的缺陷类似。
        此时，可以使用以下方案：if exist "test dir"\* echo Pass，通配符使

示例：
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('ipconfig^|findstr /i "Address"') do set var=%%a
set CarriageReturn=!var:~-1!
效果：变量CarriageReturn被赋值为一个回车符(0x0d,\r,Cr)
注释：源于 ipconfig 的输出每行行尾都有两个回车符，在被for /f截掉一个后还能剩一个；
        引用时需要用变量延迟的形式，否则就会在预处理中被当做行结束符而被过滤掉
链接：http://bbs.bathome.net/viewthread.php?tid=6692

示例：
reg add hkcu /v test /d "测试" /f
reg query hkcu /v test | find "test"
效果：输出的Test键值丢失了一个字，只余“测”
注释：XP SP3以及以上系统的reg query没有此Unicode带来的问题，解决方法见链接
链接：http://bbs.bathome.net/thread-2046-1-1.html
http://www.cn-dos.net/forum/viewthread.php?tid=21365#pid128521
http://www.cn-dos.net/forum/viewthread.php?tid=22202
http://www.cn-dos.net/forum/viewthread.php?tid=27279#pid182590

示例：
reg add hkcu\test\"quote\"folder /f
reg query hkcu\test\"quote\"folder
reg delete hkcu\test\"quote\"folder
效果：reg添加、查询和删除的注册表键支都是Test，而不是我们设想的Test"quote"folder
注释：XP SP2的reg在注册表键值出现引号" 时可以使用\ 转义，
比如 reg add hkcu /v test /d "\"value\"" /f
但是这个转义字符不能用在注册表键支中，因为它被视作键支层级的分隔符
解决办法是升级reg.exe 为更高版本系统下的reg.exe 外
链接：http://www.bathome.net/viewthread.php?tid=7004

示例：ren test1.txt *t2*
效果：test1.txt将改名为test1.txt2，而非test2.txt
注释：在ren 的任何文件名参数中均可以使用通配符（* 和 ?）。
        如果在 FileName2 中使用通配符，则通配符代表的字符与 FileName1 中的相应字符匹配。
        类似于正则表达式中的最远匹配，但只匹配通配符后的一个字符，其余字符都属于替换字符。
        另外，如果Filename1 含有通配符，那么在NTFS和FAT32下执行会略有差异，详见以下链接。
链接：http://www.cn-dos.net/forum/viewthread.php?tid=29538

示例：md test1 & ren test1 test2
效果：生成test2目录
注释：cmd的ren命令已经悄悄支持目录的改名了。当然，移动目录仍然需要使用move命令。

示例：set/=value
效果：生成变量/，值为value
注释：set将分隔符识别为变量名的一部分，/可以改为( + , . : ; [ \ ] 等特殊字符

示例：
@echo off
set var=
echo.%errorlevel%
set var=value
echo.%errorlevel%
效果：此段代码保存为test.bat执行后分行显示“1 1”，保存为test.cmd执行后显示“1 0”
注释：第一个数字1表示：set试图删除一个不存在的变量var时发生内部错误，产生errorlevel为1
        第二个数字表示：set成功创建变量var后，.cmd文件会重置errorlevel为0，而.bat文件则不会
        也就是说，在.cmd文件中，set成功执行后会重置errorlevel为0，而在.bat文件不管errorlevel
链接：http://www.cn-dos.net/forum/viewthread.php?tid=30968&page=3#pid217157

示例：
set test 1=value
set test 2
效果：test 1的名值对
注释：set 识别单纯的变量名时会丢掉最后一个空格的字符串

示例：set "test=value > 3 "
效果：生成一个变量test，值为"value > 3 "（含空格不含引号）
注释：在变量值涉及特殊字符和尾部空格的时候，用引号对将变量名和变量值括起是个好办法
链接：http://www.cn-dos.net/forum/viewthread.php?tid=17785#pid105897

示例：set "
效果：显示所有的环境变量，其中有包括“=::=”、“=C:=”等变量名含有等号的隐含环境变量
注释：可以把双引号换成一个或多个逗号、双引号、分号或者其混合形式，双引号最好成对使用
        “=::”、“=C:”等变量其代表当前CMD会话曾访问过的各个驱动盘下的当前目录。
        因变量名中包含等号=，正常情况下，set无法对其显示和修改。
        也可能会出现变量“=ExitCode=”，代表CMD所调用外部程序的错误返回码（%Errorlevel%）
链接：http://bbs.bathome.net/thread-7696-1-1.html

        

示例：
set LineFeed=^


效果：变量LineFeed被赋值为一个换行符(0x0a,\n,Lf)
注释：注意set下的两个空行不可少，也就是^后需要三个换行符；
        第一个和第三个换行符被当做行结束标志，第二个被^转义成普通字符；
        引用时需要用变量延迟的形式，否则就会在预处理中被当做行结束符而被过滤掉
链接：http://bbs.bathome.net/viewthread.php?tid=6692

示例：set/a n=1,n=!n!+7
效果：显示n=7，而不是8
注释：!!对的变量延迟语法是针对语句块内的多条语句的，
        而set/a 的逗号表达式是一个语句，而不是语句块，自然不能实现延迟
        解决的办法就是让set/a 自己处理: set/a n=1,n=n+7

示例：
set /a var=_abc
set /a var2=1a
效果：第一句会将变量var赋值为0，第二句会报“无效数字”的语法错，且不会对变量var2赋值
注释：第一句set/a将_abc识别为变量名，因找不到对应变量，所以赋值结果为0；
        第二句set/a将1a识别为操作数，而它又不是一个合法数值，所以提示语法错误，并置errorlevel为9167。
        set/a的判断变量名和操作数的标准类似高级语言：字符串以数字起始是操作数，否则为变量名。
        此外，判断一个字符串是否是合法的十进制数值的方法如下：
        set /a _var=%var% 2>nul
        if "%_var%"=="%var%" echo %var%是合法的十进制数值

示例：set /p test=Text without CrLF(\r\n)<nul
效果：显示一串文本，不含回车换行符
注释：多次使用set /p可以将多串文本输出在一行中，也用在重定向输出过程中

示例：set /p test=<test.txt
效果：将变量test赋值为test.txt的第一行内容
注释：利用了set/p 的重定向输入特性，文本中的回车换行符被cmd理解为语句结束符
        因此可以利用这点切分出文本首行，进而在循环中结合findstr切分出文本的每一行。
        提示：set/p最多可以获取1024个字节作为变量，而环境变量长度限制为8192字节。
链接：https://mp.weixin.qq.com/s/95FNcguB_j22Kfm-l_I-4Q

示例：for /l %%i in (1,1,33) do setlocal
效果：显示“已经达到最大的 setlocal 递归层。”
注释：“使用 setlocal 和 endlocal 命令，可以在 Cmd.exe 的实例中（或在脚本中）进一步将更改局部化。
        Setlocal 创建局部作用范围，而 endlocal 终止局部作用范围。在 setlocal 和 endlocal 作用范围
        内所做的更改将会被放弃，从而保持原始环境不变。这两个命令的嵌套最高可达到 32 级。”
        此段描述引用自官方文档（ntcmds.chm::/ntcmds_shelloverview.htm）
        setlocal意味着重新复制一份环境变量到新的内存地址，而系统只预留了32份地址空间，
        所以环境变量复制份数不能超过32份，也就意味着setlocal的递归次数不能超过32级。
        因此，适时使用endlocal回收不再使用的地址空间不仅是严谨的，也是必要的。

示例：subst ~: C:\Windows & ~:
效果：创建虚拟驱动器~，并跳转到该驱动器下
注释：subst 用于创建、显示和删除虚拟驱动器，该驱动器将指向其它真实或虚拟驱动器文件夹的路径，
        虚拟驱动器的盘符可以是字母、数字以及一些特殊字符，但非字母的盘符不会出现在subst的显示列表中。

示例：type *.txt *.log
效果：显示当前目录下所有文本文件和日志文件的内容
注释：在COMMAND下type是不支持文件通配符的，在CMD下悄悄的支持了

示例：
cd >nul 3>nul
echo Test1
cd >con 4>con
echo Test2
效果：第一句后不再显示以后命令的输出Test1，第二句后恢复显示以后命令的输出Test2
注释：源于重定向后句柄的备份机制，两句中的第一个NUL和CON可以换成其他文件名或者设备名，详见
链接：http://www.cn-dos.net/forum/viewthread.php?tid=16942
http://bbs.bathome.net/viewthread.php?tid=2579

示例：
(
    echo 第一行
    echo 第二行
    echo 第三行
)> test.txt
效果：将圆括号中的所有echo输出重定向到指定的文件test.txt
注释：语句块的重定向使文件句柄的创建或销毁次数减少，因此可以提升执行效率，书写上也更加简单
链接：http://www.cn-dos.net/forum/viewthread.php?tid=46717

示例：
(echo test)|findstr /c:" "
效果：显示test，findstr认为前面的命令输出含有空格
注释：CMD的预处理在分析语句时，会在)和|这些有特殊意义的转义字符前后插入空格，同时剪除多余的空格。
        而当)和|一同出现时，CMD的预处理没有把这些空格从命令行中全部过滤掉，而会遗漏一个空格到echo命令中。
        而echo命令则把这个空格连通之前文本一同输出到管道后命令findstr中，所以导致findstr匹配出含空格行。
链接：http://www.bathome.net/viewthread.php?tid=7629&page=3#pid50356
        http://www.bathome.net/viewthread.php?tid=1480&page=4#pid28166

示例：
>>test.txt echo 行 1
echo>>test.txt 行 2
echo 行>>test.txt 3
效果：将三行输出分别输出到test.txt中
注释：重定向符号可以出现语句中的很多地方，前提是不影响输入输出的正常语法；
        在上面提到语句块的重定向特性出现之前，在纯DOS的环境中行1 的用法更多的被使用，
        因为它使输出语句看起来更加整齐，另外在CMD下也可以避免在行尾出现单独的数字时，
        这个数字可能与重定向符号被一起理解为某个句柄的重定向，而出现意想不到的输出。

示例：
echo.>time.com
time.com
效果：显示COMMAND中TIME命令的输出，并等待用户输入
注释：time可以换成其它COMMAND支持的内部命令名。
对于.COM和没有PE标记的.EXE，Windows都将其认为16位DOS程序，会自动调用其
16位MS-DOS子系统(NTVDM.EXE)解释执行该程序，如果它与COMMAND的内部命令同名，
则优先调用该命令。

示例：
set var=value
:: %var:*=%
效果：显示错误信息“此时不应有 =%”
注释：::虽然被当作注释符号在使用，但是请别忘记它本质上仍然是批处理标签语句，
        cmd在解释执行时也是需要预处理的，虽然只是少量的，但出错也是会提示的。
链接：http://www.cn-dos.net/forum/viewthread.php?tid=40242

示例：
cmd /u /c echo Unicode Text> test.txt & type test.txt
cmd /u /c echo Unicode Text|findstr ".*"
cmd /u /c echo Unicode Text|find /v ""
cmd /u /c echo Unicode Text|more
cmd /u /c echo Unicode Text|sort
效果：前两行命令输出“  n i c o d e   T e x t”的文本，三四行命令将逐字分行输出
        测试文本，并在尾部附五个空行，第五条命令将显示“Unicode”原文。       
注释：cmd /u用于使命令输出或管道中的文本成为Unicode编码，对于纯英文文本，其Unicode
        编码只使用一个高字节，另外一个字节以0x00填补。对于此编码各文本命令支持有很多差异。
        type命令虽然支持显示Unicode文本，但需要文本前缀包含有Unicode的“FFFE”的BOM标记，
        对于cmd /u /c输出的无BOM的Unicode文本将按照ANSI标准输出，字符间的00字节不做转换。
        findstr的特性与type类似，但需要注意的是，它将无法处理重定向输入的Unicode文本。
        而这段文本通过管道送到more和find命令之后，它们会将0x00理解为行结束而输出一个换行符。
        文本后的五个空行，分别是从文本中的回车符、换行符以及它们之间的两个0x00字符转换而来，
        最后一个则是CMD 的“后处理”为文本自动添加的。
        而sort则会将Unicode文本转换为ANSI文本，所以会显示正确的文本，即使其中不包含BOM标记。

示例：mem
效果：首次在CMD窗口中执行会清空窗口，并显示十一个空行，提示符中的长名路径切换为短名；
        第二次执行不会清空窗口，但仍会显示十一个空行；以后执行均只显示一个空行。
        如果在CMD的全屏窗口中执行时，则会正常显示输出结果。
注释：mem.exe是16位DOS 程序，在CMD中调用之前会启用Windows的16位MS-DOS子系统(NTVDM/WOW)，
        模拟mem.exe程序类似MSDOS的运行环境，因此导致CMD窗口的输入或输出机制均发生较大的变化，
        首先这个模拟子系统的键盘布局缺省只支持“美式英语的美式键盘”，而大多定制的中文系统已将
        该键盘布局从“文字服务和输入语言”中删除，所以会报“Invalid keyboard code specified”，
        并自动切换回该缺省方案。其次，模拟子系统缺省只支持美式英语的代码页（437），而中文系统下
        的CMD是简体中文的代码页（936），所以会将CMD的活动代码页切换为437，并切换屏幕显示字体，
        因此导致清屏动作，因为以上两个动作是快速发生，所以用户一般不会观察到键盘布局错误的显示。
        如果使用mem>c:\mem.txt重定向命令的输出，则会在输出文本的第一行发现该错误信息。
        在CONFIG.NT中使用COUNTRY命令可以更改模拟DOS环境的国家代码和字符集代码页。
        在AUTOEXEC.NT中使用KB16命令可以更改模拟DOS环境的键盘方案，但不支持中文键盘方案的代码。
链接：http://www.cn-dos.net/forum/viewthread.php?tid=9452

Zhanggli

华山论剑，高手过招够精彩

LJY4.0

回复 1# qzwqzw
帮助很大

网上邻居

太多深奥的东西了，诡异的预处理，甚至微软本身的一些奇怪逻辑，批处理是个大坑。

2013haohaoma123

md .\%input%是什么意思

hanyeguxing

@echo off
set "r=D:\rec\abc.txt"
for %%a in (0 1) do call:han %r% %%a
set "r=abc.txt"
for %%a in (0 2) do call:han %r% %%a
pause&exit
:han
if %~2==1 cd.>D:\rec\ABC.txt
if %~2==2 cd.>ABC.txt
echo.参数%1和%~nx1与%~f1
for %%i in (%~1) do echo.变量%%i和%%~nxi与%%~fi
复制代码

写了个脚本测试，发现参数和变量的替换扩展确实如是按如此规律此显示的。
　　%%i 的大小写由 (set) 直接控制，但 %%~nxi 则受 for 能否在扩展中找到文件的控制。如果扩展不到该文件，则按 %%i 即 (set) 中的赋值大小写为准；如果能够扩展到该文件，则按实际文件的大小写为准。 %%~i 例外，原因是 %%~i 直接删除 %%i 的前后引号 ("") ，而不扩展寻找文件。

　　参数的增强扩展同样如此。

[ 本帖最后由 hanyeguxing 于 2010-5-6 20:49 编辑 ]

qzwqzw

这是可以理解的

%%i是dir的原样输出
所以受到dir/l的控制
而%%~nxi是扩展输出
是受到变量扩展逻辑控制的

dir/s/b将给出文件的完整路径
而在%%~nxi扩展时能根据路径找到文件
自然会把变量当作文件名处理
所以是文件自身的大小写状态

没有/s将只给出文件名
而如果当前路径不是dir的路径
则%%~nxi没有办法找到对应文件
自然只有按“当前路径+替代变量“的形式扩展
所以是替代变量%%i原来的大小写状态

hanyeguxing

1，dir的 /l 参数是按小写字母显示未排序的目录名和文件名。/l 不会将扩展字符转换为小写字符。
2，dir的 /s 参数是列出指定目录及所有子目录中出现的每个指定的文件名。
3，%%~nxi是扩展%%i的文件名和扩展名的。（%%~ni、%%~fi等也是这样）
当这三个复合到一起，就诡异了：

@echo off
for /f "delims=" %%i in ('dir /s/l/b/a "D:\rec\测试"')  do echo.%%i和%%~nxi
pause
复制代码

%%i是小写的，%%~nxi却是原始的大小写
而当不使用 /s 时，%%~nx和%%i一样，都转成小写。

[ 本帖最后由 hanyeguxing 于 2010-5-6 13:57 编辑 ]

qzwqzw

早就习惯了变量的这种扩展形式
忘了这也是不符合大多数人的认知习惯的
其实关于增强的变量扩展方面
负值的使用也在挑战大多数人的认知

使用正值就是起始的偏移量+长度
使用负值却不是起始的反向偏移量+反向长度
而是起始的反向偏移量+终止的反向偏移量

我最初在理解set的这句说明了
也还纳闷了老半天
为什么呢？

这大概说明了
增强的变量扩展在对正值和负值的处理上
采用了完全不同的两种处理逻辑
所以正值超出后为空
而负值超出后为首字符地址的逻辑
也就不难理解了

Batcher

我举得例子是针对楼主的这句：

finstr在匹配多个中文串时存在问题，使用开关/l或者/r可以得到正确的输出。

楼主在这里没有提到/i啊

namejm

原帖由 Batcher 于 2010-4-27 17:54 发表
顶楼内容里面的findstr /l不一定能够解决汉字“或”的问题，测试环境：XP SP3 Pro CS，测试结果：

C:\Test>type a.txt
我们
他们
123

C:\Test>findstr /l "我们 他们" a.txt

C:\Test>findstr /r "我们 他们" a.txt
我们
他们

C:\Test>findstr "我们.* 他们" a.txt
我们
他们

请注意，你这里使用的是 /l 而不是 /i，前者是按字符搜索的意思，后者是不区分大小写的意思。

hanyeguxing

@echo off
set m=1234567890
echo.测试1:%m:~1,1%
echo.测试2:%m:~20,1%
echo.测试3:%m:~20%
echo.测试4:%m:~8,-5%
echo.测试5:%m:~0,1%
echo.测试6:%m:~-0,1%
echo.测试7:%m:~-20,1%
echo.测试8:%m:~-5%
echo.测试9:%m:~-20%
pause
复制代码

在 XP SP3 Pro 下，显示结果：
测试1:2
测试2:
测试3:
测试4:
测试5:1
测试6:1
测试7:1
测试8:67890
测试9:1234567890
测试1、测试5、测试6、测试8，都是显示正常。
测试2、测试3，因为超出了范围，所以为空。
字符串都是从左向右截取的，所以测试4为空。
当数值为负，且超出范围时，是否也为空呢？从测试7和测试9中可以看出，显然不是。
形如%m:~-20,1%，超出范围时，依然截取并获取了最左边的字符。
形如%m:~-20%，超出范围时，总是截取并获取整个字符串。
所以：在截取字符串时，即使负的数值超出范围，依然是从最左边的字符开始截取。

[ 本帖最后由 hanyeguxing 于 2010-5-2 02:13 编辑 ]

qzwqzw

findstr 匹配多个中文串的问题比较棘手
目前找不到问题的实质原因
所以我在顶楼也只是含糊其辞
如果有更多的测试和证据
足以让人判断其问题的源头
那么我可以考虑更新一下

Batcher

顶楼内容里面的findstr /l不一定能够解决汉字“或”的问题，测试环境：XP SP3 Pro CS，测试结果：

C:\Test>type a.txt
我们
他们
123

C:\Test>findstr /l "我们 他们" a.txt

C:\Test>findstr /r "我们 他们" a.txt
我们
他们

C:\Test>findstr "我们.* 他们" a.txt
我们
他们

qzwqzw

多余空格的问题已基本确认
应该是CMD预处理括号对()和管道符时插入的
请看以下示例

D:\>(echo.abc) > 1.txt

D:\>echo.abc|more>2.txt

D:\>(echo.abc)|more>3.txt

只有3.txt有空格
而1.txt，2.txt都没有
这说明CMD的预处理在做语句的词法切分时
为了方便以后的预处理识别)和|这些转义字符
而特意在这些字符前后插入一个空格
同时也会把多余的空格去除

这种增减空格的现象
在不含echo off的批处理中可以看到很多

比如以下的用法

(echo test)
(echo.test)
echo test|more
echo.test|more
(echo test)> a.txt
(echo.test) > a.txt
echo.test|more>b.txt
(echo.test)|more>c.txt
复制代码

D:\>(echo test )
test

D:\>(echo.test)
test

D:\>echo test  | more
test


D:\>echo.test | more
test


D:\>(echo test ) 1>a.txt

D:\>(echo.test) 1>a.txt

D:\>echo.test | more1>b.txt

D:\>(echo.test)  | more1>c.txt

[ 本帖最后由 qzwqzw 于 2010-4-21 10:39 编辑 ]