随风

【程序12】
题目：判断101-200之间有多少个素数，并输出所有素数。
1.程序分析：判断素数的方法：用一个数分别去除2到sqrt(这个数)，如果能被整除，
　　　　　　则表明此数不是素数，反之是素数。

:

@echo off&setlocal EnableDelayedExpansion
for /l %%a in (101 1 200) do (
  set /a n=%%a-1&set "flag="
  for /l %%b in (2 1 !n!) do (
    set /a m=%%a%%%%b
     if !m! equ 0 set flag=a
  )
  if not defined flag echo 素数 %%a
)
echo\&pause
复制代码

随风

水仙花数
原创作者： 梦想种子
:

@echo off&setlocal enabledelayedexpansion
:: 原创作者： 梦想种子
for /l %%i in (0 1 9) do set /a t%%i=%%i*%%i*%%i
for /l %%i in (1 1 10000) do (
  set "k=00000%%i"
  set a=!k:~-1!
  set b=!k:~-2,1!
  set c=!k:~-3,1!
  set d=!k:~-4,1!
  set e=!k:~-5,1!
  set /a n=t!a!+t!b!+t!c!+t!d!+t!e!
  if "!n!" == "%%i" echo %%i
)
pause
复制代码

随风

【程序23】
题目：打印出如下图案（菱形）
*
***
******
********
******
***
*

:

@echo off&setlocal enabledelayedexpansion
set "ko=                              "
for /l %%i in (1 2 13) do (
  if defined flag (set /a n-=2&set /a c-=1) else set /a n=%%i&set /a c+=1
  call set m=%%ko:~!c!%%
  set /p=!m!<nul
  for /l %%b in (1 1 !n!) do set /p=*<nul
  echo.
  if !n! geq 7 set flag=a
)
echo.&pause
复制代码

随风

打印杨辉三角
转一个，
原创作者：wudixin96
:

@echo off&setlocal enabledelayedexpansion
:top
::原创作者：wudixin96
::  in=行数：
set/a ab=1,var=30,in=10
set str=1
for /l %%i in (1,1,%in%) do (
   set "num="
   set /a num2=0
   for %%a in (!str!) do (
   set /a num2+=1
   if !num2!==1 set "str1="
   set /a num1=%%a+num
   set "str1=!str1! !num1!"
   set num=%%a
   )
   call :lis "!str1:~1!"
   set "str=!str1! 0"
)
pause>nul
exit
:lis
set max=%~1
for /l %%a in (0 1 300) do (
  if not "!max:~%%a,1!"=="" set /a ci+=1
)
set /a ki=var-ci/2
for /l %%a in (1 1 !ki!) do set "kg= !kg!"
echo !kg!!max!
set nam!ab!=!kg!!max!
set /a ab+=1
set ci=0&set "kg="
goto :eof
复制代码

随风

这么多题，在答题时，把题目一起贴出来好吗？

随风

【程序30】
题目：一个5位数，判断它是不是回文数。即12321是回文数，个位与万位相同，十位与千位相同。
指定5位数，是不是太容易了，来个可以是任意位数的。
:

@echo off&setlocal EnableDelayedExpansion
set /p nnn=请输入一个数 &cls
set mmm=%nnn%
:loop
set bbb=%mmm:~0,1%%bbb%
set mmm=%mmm:~1%
if not "%mmm%"=="" goto loop
if "%bbb%"=="%nnn%" (echo %nnn% 是回文数) else echo %nnn% 不是回文数
pause
复制代码