sjzong

@echo off
::有1、2、3、4个数字，能组成多少个互不相同且无重复数字的三位数？都是多少？
::原创：sjzong
setlocal enabledelayedexpansion
set num=0
for /l %%i in (1 1 4) do (
for /l %%j in (1 1 4) do (
  for /l %%k in (1 1 4) do (
   if %%i neq %%j if %%i neq %%k if %%k neq %%j (echo %%i%%j%%k & set /a num=!num!+1)
  )
)
)
echo !num!
pause
复制代码

[ 本帖最后由 sjzong 于 2009-4-3 12:40 编辑 ]

sjzong

@echo off
setlocal enabledelayedexpansion
::原创：sjzong
echo 请输入十个数字……
set str=
for /l %%a in (1 1 10) do (
set /p shuzi=请输入%%a个数:
set str=!str! !shuzi!
) 
set zimu=ABCDEFGHIJ
set ss=
for %%b in (!str!) do (
set count=0
for %%c in (!str!) do if %%b geq %%c set /a count=!count!+1
set /a count=!count!-1
set ss=!ss! !count!
)
for /l %%d in (0 1 9) do (
set cou=
for %%e in (!ss!) do if %%d==%%e set /a cou=!cou!+1
for /l %%f in (1 1 !cou!) do set num=!num! !zimu:~%%d,1!
)
for %%i in (!str!) do (
set count=0
for %%j in (!str!) do if %%i geq %%j set /a count=!count!+1
set /a count=!count!-1
if !count!==0 set num=!num:A=%%i!
if !count!==1 set num=!num:B=%%i!
if !count!==2 set num=!num:C=%%i!
if !count!==3 set num=!num:D=%%i!
if !count!==4 set num=!num:E=%%i!
if !count!==5 set num=!num:F=%%i!
if !count!==6 set num=!num:G=%%i!
if !count!==7 set num=!num:H=%%i!
if !count!==8 set num=!num:I=%%i!
if !count!==9 set num=!num:J=%%i!
)
echo 你输入的十个数字是：!str!
echo 排序后的十个数字是：!num!
pause
复制代码

[ 本帖最后由 sjzong 于 2009-4-3 12:42 编辑 ]

sjzong

@echo off
::打印杨辉三角
::原创：sjzong
setlocal enabledelayedexpansion
set str= 1
echo !str!
for /l %%a in (1 1 9) do (
::求出上一个数列的相邻两个数的和。
set num1=1
for %%b in (!str!) do ( 
::num1是用来控制是相邻两数的前一个数%%i；num2为后一个数%%j
set /a num1=!num1!+1
set /a shu=!num1!+1
set num2=1
for %%c in (!str!) do (
set /a num2=!num2!+1
if !num2!==!shu! set /a sum=%%b+%%c
)
set str1=!str1! !sum!
set sum=
)
::在求出每相邻两数之和后，在前后各加上1
set str=1!str1!1
::用来打印时在数字的前面加上空格
set /a a=10-%%a
set b=
for /l %%d in (0 1 !a!) do (set b= !b!)
set str=!b!!str!
set str1=
echo !str!
)
pause
复制代码

sjzong

【程序21】
题目：猴子吃桃问题：猴子第一天摘下若干个桃子，当即吃了一半，还不瘾，又多吃了一个
　　　第二天早上又将剩下的桃子吃掉一半，又多吃了一个。以后每天早上都吃了前一天剩下
　　　的一半零一个。到第10天早上想再吃时，见只剩下一个桃子了。求第一天共摘了多少。
1.程序分析：采取逆向思维的方法，从后往前推断。
答案：见32楼
注意：32楼那个是错误的！那是先吃一个再吃一半的，所以公式a=2*a+1；而本题是先吃一半后再多吃一个，所以公式为a=2*(a+1)。

@echo off&setlocal EnableDelayedExpansion
::程序分析： 注意是先吃一半再吃一个则公式是a=2*(a+1)
::原创：sjzong
set num=1
echo 第10天时有!num!个桃子
for /l %%i in (9 -1 1) do (
set /a num=!num!*2+2
echo 第 %%i天时有!num!个桃子)
pause
复制代码

[ 本帖最后由 sjzong 于 2009-4-5 14:44 编辑 ]

sjzong

【程序80】
题目：海滩上有一堆桃子，五只猴子来分。第一只猴子把这堆桃子凭据分为五份，多了一个，这只
　　　猴子把多的一个扔入海中，拿走了一份。第二只猴子把剩下的桃子又平均分成五份，又多了
　　　一个，它同样把多的一个扔入海中，拿走了一份，第三、第四、第五只猴子都是这样做的，
　　　问海滩上原来最少有多少个桃子？
答案：见44楼
44楼 这个程序也是错误的！正确的是如下：

@echo off&setlocal EnableDelayedExpansion
::程序分析：这些桃子，每一只猴子来分的时候，把桃子的数量减一后必须是五的倍数！所以五只猴子来分，必须进行五次判断的！
::程序中的num是用来判断是否达到五次判断！
::原创：sjzong
for /l %%i in (1 1 10000) do (
set /a a=%%i
set /a num=0
for /l %%j in (1 1 5) do (
  set /a b=!a!-1
  set /a c=!b! %% 5
  if !c! == 0 (
  set /a a=!b!/5 
  set /a a=!a!*4
  set /a num=!num!+1)
)
if !num!==5 (echo 最少要%%i只桃子 & goto :end)
)
:end
pause
复制代码

[ 本帖最后由 sjzong 于 2009-4-5 14:44 编辑 ]

sjzong

题目：对10个数进行排序

@echo off
setlocal enabledelayedexpansion
::原创：sjzong
echo 请输入十个数字……
::读入10个数字，分别放在t1~t10内，并把数字合成一行，中间加个空格。
set str=
for /l %%a in (1 1 10) do (
set /p t%%a=请输入%%a个数:
set str=!str! !t%%a!
)
echo 排序前的数字序列是：!str!
::数字排序是采用冒泡排序的，每相邻的两个数进行比较，大的放在后面。
::要进行9趟比较，第1趟求出最大放在最后一个数…第9趟是剩下两个数进行比较
::其实t%%b代表相邻的前一个数，b代表相邻的后一个数，比较后进行交换
for /l %%a in (1 1 9) do (
set /a a=10-%%a
for /l %%b in (1 1 !a!) do (
  set /a c=%%b+1
  set /a b=t!c!
  if !t%%b! gtr !b! (
   set /a temp=t%%b
   set /a t%%b=t!c!
   set /a t!c!=!temp!
  )
)
)
::把排序后的数字排列出来
set str=
for /l %%a in (1 1 10) do (
set str=!str! !t%%a!
)
echo 排序后的数字序列是：!str!
pause
复制代码

[ 本帖最后由 sjzong 于 2009-4-7 00:59 编辑 ]

sjzong

题目：对10个数进行排序
1.程序分析：可以利用选择法，即从后9个比较过程中，选择一个最小的与第一个元素交换，
　　　　　　下次类推，即用第二个元素与后8个进行比较，并进行交换。

@echo off
setlocal enabledelayedexpansion
::原创：sjzong
echo 请输入十个数字……
::读入10个数字，分别放在t1~t10内，并把数字合成一行，中间加个空格。
set str=
for /l %%a in (1 1 10) do (
set /p t%%a=请输入%%a个数:
set str=!str! !t%%a!
)
echo 排序前的数字序列是：!str!
::数字排序是采用选择排序的，取第1个数跟后面的9个数进行比较，大的话进行交换。
::然后取第2个数跟后面的8个数进行比较，大的进行交换，以此类推。
for /l %%a in (1 1 9) do (
set /a a=%%a+1
for /l %%b in (!a! 1 10) do (
  if !t%%a! gtr !t%%b! (
   set /a temp=t%%a
   set /a t%%a=t%%b
   set /a t%%b=!temp!
  )
)
)
::把排序后的数字排列出来
set str=
for /l %%a in (1 1 10) do (
set str=!str! !t%%a!
)
echo 排序后的数字序列是：!str!
pause
复制代码

[ 本帖最后由 sjzong 于 2009-4-7 01:00 编辑 ]

sjzong

题目：有一分数序列：2/1，3/2，5/3，8/5，13/8，21/13...求出这个数列的前20项之和。
          1.程序分析：请抓住分子与分母的变化规律。

@echo off
setlocal enabledelayedexpansion
::原创：sjzong
::程序分析：每个数的分子是上一个数的分子与分母之和，分母为上一个数的分子
::fz为分子，fm为分母
set fz=1
set fm=1
set qiuji=1
set qiuhe=0
echo 正在输出这二十个数……
for /l %%i in (1 1 20) do (
set /a c=!fm!
set /a fm=!fz!
set /a fz=!fz!+!c!
echo !fz!^/!fm!
set /a qiuji=!qiuji!*!fz!/!fm!
set /a qiuhe=!qiuhe!+!fz!/!fm!
)
echo.
echo 这二十个数的积为：!qiuji!
echo 这二十个数的和为：!qiuhe!
echo.
pause
复制代码

[ 本帖最后由 sjzong 于 2009-4-7 00:56 编辑 ]

sjzong

题目：将一个正整数分解质因数。例如：输入90,打印出90=2*3*3*5。
程序分析：分解质因数实际就是把这数除以素数列（2 3 5 7 11 13……），从2开始除，不整除的话，换下一个素数；整除的话，就记下该数字，并求出商；若商不为1，则再把商去除素数列；商为1，就停止，表明分解结束。
由于素数列第一个数为2，后面为奇数组，所以进行判断时，等于2时就加1，不等于2时就加2，这里面有个问题就是多进行无用循环，如9 15等！还有结果是，例如：输入90,打印出90=1*2*3*3*5。

 
@echo off&setlocal EnableDelayedExpansion
set /p num=请输入要因数分解的数：
set str=!num!=1
:a
set /a n=2
:b
set /a aa=!num! %% !n!
::这if语句是能整除的语句，求出商，并记下那个质数n
if !aa! equ 0 (
  set /a num=!num!/!n!
  set str=!str!*!n!
::等于1，分解结束，跳到c，不等于1，继续把商除以素数列，跳到a
  if !num! neq 1 (goto :a) else (goto :c)
)
::这if语句是不能整除的，换下一个素数，并跳到b
if !aa! neq 0 (
::若等于2时n+1，不等于2时n+2
  if !n! equ 2 (set /a n=!n!+1) else (set /a n=!n!+2)
  goto :b
)
:c
echo 分解完是：!str!
pause
复制代码

[ 本帖最后由 sjzong 于 2009-4-9 00:53 编辑 ]

sjzong

程序分析：这个偶数应该是大于3的偶数，但是大于3的偶数中4是比较特殊的，可拆为两个2的和；其他的偶数一定要拆成两个奇数的和，然后分别判断这两个数是否为素数即可。

 
@echo off
setlocal enabledelayedexpansion
::原创：sjzong
set /p num=请输入大于3的偶数：
set /a aa=!num! %% 2
rem 判断输入的数字是否为偶数
if !aa! neq 0 (
cls
echo 你输入的数字不是偶数！
set /p num=请再次输入大于3的偶数：
)
rem 判断输入的数字是否小于等于3
if !num! leq 3 (
cls
echo 你输入的数字小于4！
set /p num=请再次输入大于3的偶数：
)
rem 判断输入的偶数是否为4，是的话直接拆分为两个2的和，不是的话进行两个奇数的拆分。
if !num!==4 (echo 偶数 !num! 是素数 2 与 2 的和。) else (
set /a yiban=!num!/2
rem 拆分偶数时只需从3到该偶数的一半即可
for /l %%a in (3 2 !yiban!) do (
  set /a shu=!num!-%%a
  set /a a1=0
  set /a a2=0
  call :test %%a
  if !flag!==1 set /a a1=1
  call :test !shu!
  if !flag!==1 set /a a2=1
  if !a1!==1 if !a2!==1 echo 偶数 !num! 是素数 %%a 与 !shu! 的和。
)
)
pause
goto :eof
rem 判断该数是否为素数时，只需计算从1到该数的一半能被该数整除的次数
rem 次数为1时表示为素数，次数大于1时表示不是素数
:test
  set /a flag=1
  set /a b=%1/2
  set /a count=0
  for /l %%a in (1 1 !b!) do (
   set /a yushu=%1 %% %%a
   if !yushu! equ 0 set /a count=!count!+1
   if !count! gtr 1 (set /a flag=0 & goto :eof)
  )
复制代码

[ 本帖最后由 sjzong 于 2009-4-10 10:01 编辑 ]

sjzong

【程序69】
题目：有n个人围成一圈，顺序排号。从第一个人开始报数（从1到3报数），凡报到3的人退出圈子，问最后留下的是原来第几号的那位。
改一下：设有ｎ个人依次围成一圈，从第１个人开始报数，数到第ｍ个人出列，然后从出列的下一个人开始报数，数到第ｍ个人又出列，…，如此反复到所有的人全部出列为止。设ｎ个人的编号分别为1，2，…，n，打印出出列的顺序。

@echo off&setlocal enabledelayedexpansion
:n
cls
set /p n=请输入人数n:
echo.%n%|findstr "^[1-9][0-9]*$">nul||goto n
:m
set /p m=请输入报数m:
echo.%m%|findstr "^[1-9][0-9]*$">nul||goto m
for /l %%a in (1 1 %n%) do (if %%a lss 10 (set str=!str! 0%%a) else (set str=!str! %%a))
set/a b=3*!m!-3
set/a c=3*!m!
:loop
if "!str:~%b%,3!" equ "" (set s1= 空) else (set s1=!s1!!str:~%b%,3!)
if "!str:~%c%,3!" equ "" (set str=!str:~0,%b%!) else (set str=!str:~%c%!!str:~0,%b%!)
set/a n-=1
if not !n! lss !m! goto loop
echo 出列的数据是：!s1:~1!&set s1=
if !m! equ 1 (echo 剩下的数据是：空&set str=) else (echo 剩下的数据是：!str:~1!&set str=)
pause>nul&goto n
复制代码