批处理如何批量修改日期为前缀的文件名？

sbynkidt · 发表于 2012-5-3 15:19:11

各位高手，求助：

文件名规律
201201 文字一.xls
201201 文字二.xls
201201 文字三.xls
批量修改为
201202 文字一.xls
201202 文字一.xls
201202 文字一.xls
如前面为201212，修改为201301
中间以空格隔开，前面是年月组合，后面是长度不定的文字。

谢谢。

sbynkidt · 发表于 2012-5-3 16:02:28

高手，学习了

gawk · 发表于 2012-5-3 16:15:16

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1* delims= " %%a in ('dir /b *.xls') do (
set stamp=%%a
set year=!stamp:~0,4!
set month=1!stamp:~4,2!
if !month! equ 112 (
set month=101
set /a year+=1
) else (
set /a month+=1
)
ren "%%a %%b" "!year!!month:~-2! %%b"
)

复制代码

apang · 发表于 2012-5-3 17:07:09

本帖最后由 apang 于 2012-5-3 17:44 编辑

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /a-d /b *.xls') do (
set "str=%%a"
set "str1=!str:~,6!"
if "!str1:~4,2!"=="12" (set/a str1+=89
) else set/a str1+=1
ren "%%a" "!str1!!str:~6!"
)

复制代码

sbynkidt · 发表于 2012-5-3 17:35:37

感谢高手，谢谢

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[日期时间] 批处理如何批量修改日期为前缀的文件名？