[已解决]批处理如何读取出ini文件中的指定节点及其下键值对

aries215 · 发表于 2012-4-8 02:20:06

本帖最后由 pcl_test 于 2016-9-8 22:34 编辑

=== 本贴解决了两个处理INI文件的问题! ===

最近要整理一些INI配置文件, 想通过批处理实现高效作业.

要求:
1, 获取各 [...] 标签的名字并赋值, 并分别输出下面相关的行;
2, 忽略以";"开头的行, 也无需保留空行;
3, 无临时文件, 速度快.

......
[FILE]
; 系统启动文件
%SystemDriver%\autoexec.bat
%SystemDriver%\config.sys
%SystemDriver%\io.sys
%SystemDriver%\msdos.sys
%SystemDriver%\ntldr
[FOLDER]
%ProgramFiles%\Internet Explorer
......

复制代码

不知道标签名, 想要读取出标签名 "FILE"和"FOLDER", 并分别输出该标签内的所有行, 如何实现?

拜托了!

gawk · 发表于 2012-4-8 13:35:07

chenall那个你看懂了没？
如果能看懂的话，略加修改就会变成你要的了吧。

fatcat · 发表于 2012-4-8 13:43:44

@echo off & setlocal enabledelayedexpansion
> b.txt (
for /f "delims=" %%a in ('findstr /b /v ";" a.txt') do (
set lin=%%a
if "!lin:~0,1!"=="[" (set print=0
if /i "!lin:~0,6!"=="[intel" set print=1
) else if "!print!"=="1" echo %%a
)
)

复制代码

从 a.txt 输出到 b.txt

aries215 · 发表于 2012-4-8 13:45:01

没看懂啊, 太复杂了.

我想实现这样的批处理命令:
1, 跳至"INTEL"所在行, 输出下面的行;
2, 忽略以";"开头的行;
3, 遇到"["开头的行则终止.

啊~~~

aries215 · 发表于 2012-4-8 13:51:27

回复 3# fatcat
结果是, 连"AMD"标签的内容也全部出来了...

fatcat · 发表于 2012-4-8 13:55:48

回复 5# aries215

我测试过, 没有那样, 你把代码修改过了没有

aries215 · 发表于 2012-4-8 14:06:24

回复 6# fatcat
哦, 是我搞错了.
抱歉!

aries215 · 发表于 2012-4-8 14:35:20

本帖最后由 aries215 于 2012-4-8 14:40 编辑

回复 3# fatcat
为什么是 >b.txt 在最前面呢?
有什么特殊含义?

gawk · 发表于 2012-4-8 14:36:07

回复 8# aries215

你希望放在后面也无所谓，没啥。

apang · 发表于 2012-4-8 14:38:24

@echo off
for /f "delims=[] skip=2" %%i in ('find /i /n "[INTEL" a.txt') do set n=%%i
for /f "eol=; skip=%n% delims=" %%i in ('type a.txt') do (
set "str=%%i"
setlocal EnableDelayedExpansion
if "!str:~0,1!"=="[" pause&goto :eof
endlocal
echo %%i
)
pause

复制代码

aries215 · 发表于 2012-4-8 14:45:47

本帖最后由 aries215 于 2012-4-8 14:51 编辑

回复 10# apang
大哥, 这代码还能精简一些吗?
6行能实现吗?

aries215 · 发表于 2012-4-8 14:51:03

本帖最后由 aries215 于 2012-4-8 14:53 编辑

回复 9# gawk
如果放在后面, 能直接输出减少一层括号吗?
如果不是把结果输出到文本, 能否帮忙再改一下吧~

apang · 发表于 2012-4-8 14:55:14

回复 11# aries215

要精简就不能考虑特殊字符了。。。

@echo off&setlocal EnableDelayedExpansion
for /f "delims=[] skip=2" %%i in ('find /i /n "[INTEL" a.txt') do set n=%%i
(for /f "eol=; skip=%n% delims=" %%i in ('type a.txt') do (
set "str=%%i"&(if not "!str:~0,1!"=="[" (echo !str!) else goto :eof)
))>b.txt

复制代码

aries215 · 发表于 2012-4-8 14:58:41

本帖最后由 aries215 于 2012-4-8 15:05 编辑

回复 13# apang
你太强悍了! 真的是5行...
为什么要 skip=2 ? 实际是任意行啊.
eol=; 是可以省略的吧.

如果不是要输出到文件呢, 我要把结果作为一个值用到一组命令中...

gawk · 发表于 2012-4-8 15:08:41

回复 14# aries215

3行，有意思吗？

@echo off&setlocal EnableDelayedExpansion
for /f "delims=[] skip=2" %%i in ('find /i /n "[INTEL" a.txt') do set n=%%i
(for /f "eol=; skip=%n% delims=" %%i in ('type a.txt') do (set "str=%%i"&(if not "!str:~0,1!"=="[" (echo !str!) else goto :eof)))>b.txt

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理如何读取出ini文件中的指定节点及其下键值对