[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

[文件操作] 批处理文件删除操作 递归判断怎么搞?



如图所示,
文件夹嵌套,
现在需要把包含
未命名的文件夹里的
文件删除,然后把未命名的文件夹里的内容复制到上层文件夹里
同样,别的文本夹里也有未命名文件夹,如果 有就做同样的操作,如果没有就不操作,这个好弄吗

@echo off
set ccd=%cd%
for /r /d %%i in (未命名) do (
  if exist %%i (
  for %%j in (%%i\*.*) do move "%%j" "%ccd%\">nul)
)

pause

TOP

bat放在根目录

TOP

回复 3# Fit


    还要删除包含未命名文件夹

的文件夹
里的东西的

移动完了,再把未命名文件夹删除,
谢谢

TOP

@echo off
set ccd=%cd%
for /r /d %%i in (未命名) do (
  if exist %%i (
  for %%j in (%%i\*.*) do move "%%j" "%ccd%\">nul
  rd /q %%i)
)

pause
Fit Strong

TOP

回复 1# swanseabrian
你的需求是:
删除文件夹“一寸”中的6个jpg文件;
把文件夹“未命名”中的文件移动到文件夹“一寸”中;
最后删除文件夹“未命名”。
对吧?

TOP

如果是以上需求的话:
  1. @echo off
  2. for /r /d %%a in (未命名) do (
  3.     del "%%~dpa*.jpg"
  4.     move "%%a\*.*" "%%~dpa"
  5.     rd /a /f "%%a"
  6. )
  7. pause
复制代码

TOP

回复 7# qixiaobin0715


    对

TOP

回复 7# qixiaobin0715


     rd /a /f
这开关你是不是记错了
a,f 都无效
应该是 /s /q吧

TOP

回复 9# swanseabrian

for /r /d %%a in (未命名)
用上面 这个命令,为啥,不带未命名的出来了,我说怎么总出错,这是啥情况

    C:\Users\Administrator\Desktop\bat\7\A\
C:\Users\Administrator\Desktop\bat\7\A\1\
C:\Users\Administrator\Desktop\bat\7\A\1\5寸\
C:\Users\Administrator\Desktop\bat\7\A\1\6寸\
C:\Users\Administrator\Desktop\bat\7\A\1\7寸\
C:\Users\Administrator\Desktop\bat\7\A\A\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\未命名\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\未命名\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\未命名\未命名\未命名\

TOP

回复 1# swanseabrian
  1. @echo off
  2. cd /d "%~dp0"
  3. for /f "delims=" %%i in ('dir /b /s /ad 未命名') do (
  4.     del /f /q "%%i\..\*.*"
  5.     move "%%i\*.*" "%%i\.."
  6.     rd "%%i"
  7. )
复制代码
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

回复 5# Fit


1、路径加上双引号,避免空格或其它特殊字符导致代码出错或误删文件
2、move支持通配符,不需要第二层for循环逐个处理
  1. @echo off
  2. cd /d "%~dp0"
  3. for /r /d %%i in (未命名) do (
  4.     if exist "%%i" (
  5.         del /f /q "%%i\..\*.*"
  6.         move "%%i\*.*" "%%i\.."
  7.         rd /q "%%i"
  8.     )
  9. )
复制代码
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

回复 12# Batcher


   谢谢, 明白了
但是del 哪里没看懂 ..是啥
Fit Strong

TOP

回复 11# Batcher


    @echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /s /ad 未命名') do (
    del /f /q "%%i\..\*.*"
    move "%%i\*.*" "%%i\.."
    del /f /q "%%i\*.*"
    rd "%%i"
)
这样,要不然rd会提示目录不是空的,for /r /d 这个命令看来不能用啊,太不好用了

TOP

回复 13# Fit


    那是上级目录  /r /d还是不要用了,总出错,还是/f好用

TOP

返回列表