批处理文件删除操作递归判断怎么搞？

swanseabrian · 发表于 2021-9-20 15:59:02

、

如图所示，
文件夹嵌套，
现在需要把包含
未命名的文件夹里的
文件删除，然后把未命名的文件夹里的内容复制到上层文件夹里
同样，别的文本夹里也有未命名文件夹，如果有就做同样的操作，如果没有就不操作，这个好弄吗

Fit · 发表于 2021-9-20 16:30:42

@echo off
set ccd=%cd%
for /r /d %%i in (未命名) do (
if exist %%i (
for %%j in (%%i\*.*) do move "%%j" "%ccd%\">nul)
)

pause

Fit · 发表于 2021-9-20 16:31:19

bat放在根目录

swanseabrian · 发表于 2021-9-20 17:08:00

回复 3# Fit

还要删除包含未命名文件夹

的文件夹
里的东西的

移动完了，再把未命名文件夹删除，
谢谢

Fit · 发表于 2021-9-20 17:56:14

@echo off
set ccd=%cd%
for /r /d %%i in (未命名) do (
  if exist %%i (
  for %%j in (%%i\*.*) do move "%%j" "%ccd%\">nul
  rd /q %%i)
)

pause

qixiaobin0715 · 发表于 2021-9-20 18:27:38

回复 1# swanseabrian
你的需求是：
删除文件夹“一寸”中的6个jpg文件；
把文件夹“未命名”中的文件移动到文件夹“一寸”中；
最后删除文件夹“未命名”。
对吧？

qixiaobin0715 · 发表于 2021-9-20 19:10:24

如果是以上需求的话：

@echo off
for /r /d %%a in (未命名) do (
del "%%~dpa*.jpg"
move "%%a\*.*" "%%~dpa"
rd /a /f "%%a"
)
pause

复制代码

swanseabrian · 发表于 2021-9-20 20:12:16

回复 7# qixiaobin0715

对

swanseabrian · 发表于 2021-9-20 20:21:10

回复 7# qixiaobin0715

rd /a /f
这开关你是不是记错了
a,f 都无效
应该是 /s /q吧

swanseabrian · 发表于 2021-9-20 21:53:55

回复 9# swanseabrian

for /r /d %%a in (未命名)
用上面这个命令，为啥，不带未命名的出来了，我说怎么总出错，这是啥情况

C:\Users\Administrator\Desktop\bat\7\A\
C:\Users\Administrator\Desktop\bat\7\A\1\
C:\Users\Administrator\Desktop\bat\7\A\1\5寸\
C:\Users\Administrator\Desktop\bat\7\A\1\6寸\
C:\Users\Administrator\Desktop\bat\7\A\1\7寸\
C:\Users\Administrator\Desktop\bat\7\A\A\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\5寸\未命名\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\6寸\未命名\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\未命名\未命名\
C:\Users\Administrator\Desktop\bat\7\A\A\7寸\未命名\未命名\未命名\

Batcher · 发表于 2021-9-20 23:14:07

回复 1# swanseabrian

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /s /ad 未命名') do (
del /f /q "%%i\..\*.*"
move "%%i\*.*" "%%i\.."
rd "%%i"
)

复制代码

Batcher · 发表于 2021-9-20 23:19:28

回复 5# Fit

1、路径加上双引号，避免空格或其它特殊字符导致代码出错或误删文件
2、move支持通配符，不需要第二层for循环逐个处理

@echo off
cd /d "%~dp0"
for /r /d %%i in (未命名) do (
if exist "%%i" (
del /f /q "%%i\..\*.*"
move "%%i\*.*" "%%i\.."
rd /q "%%i"
)
)

复制代码

Fit · 发表于 2021-9-21 08:13:13

回复 12# Batcher

谢谢，明白了
但是del 哪里没看懂 ..是啥

swanseabrian · 发表于 2021-9-21 08:37:52

回复 11# Batcher

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /s /ad 未命名') do (
del /f /q "%%i\..\*.*"
move "%%i\*.*" "%%i\.."
del /f /q "%%i\*.*"
rd "%%i"
)
这样，要不然rd会提示目录不是空的，for /r /d 这个命令看来不能用啊，太不好用了

swanseabrian · 发表于 2021-9-21 08:42:54

回复 13# Fit

那是上级目录 /r /d还是不要用了，总出错，还是/f好用

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 批处理文件删除操作 递归判断怎么搞？

[文件操作] 批处理文件删除操作递归判断怎么搞？